Werkstück um Offest Wert drehen [HILFE benötigt]

Achse 6 drehen wird dir nicht helfen. Ich würde wahrscheinlich das Tool oder die Base verschieben. Dazu nutzt man den geometrischen Operator.
Kleines Beispiel Tool-Verschiebung:

DEFFCT FRAME  MOVETOOL(SRCTOOLNO:IN, X:IN, Y:IN, Z:IN, A:IN, B:IN, C:IN)
;gibt einen FRAME zurueck ausgehend von TOOL_DATA[SRCTOOLNO]
;mi Offsetkoordinaten X,Y,Z,A,B,C
INT SRCTOOL ;Nummer des Ursprungstools
REAL X,Y,Z,A,B,C ;Offsets
FRAME OFFSET
OFFSET.X=X
OFFSET.Y=Y
OFFSET.Z=Z
OFFSET.A=A
OFFSET.B=B
OFFSET.C=C
RETURN TOOL_DATA[SRCTOOLNO]:OFFSET
ENDFCT

Programm Aufruf:

DEF MAIN()
INI
PTP HOME 100% DEFAULT


LOOP
Bla...bla..
mach irgendwas interessantes
...
;Werte von Kamera (CAM_Z, CAM_A - irgendwo in Config  deklariert oder wie auch immer) zu Tool 1 hinzurechnen und in Tool 2 schreiben 
TOOL_DATA[2]=MOVETOOL(1, 0, 0, CAM_Z ,CAM_A ,0 ,0)
;mach wieder voll was geiles...
...
...
ENDLOOP


PTP HOME 100% DEFAULT
END

Zitat von KAKA

...
- Roboter soll Punkt manipulieren oder Achse 6 drehen, vielleicht auch um Achse "A" drehen und senkrecht in "Z" ablegen (vertikal)

Hoho, 'oder' und 'vielleicht', das schreit nach Fuzzy Logic. Aber davon hört man schon lange nichts mehr, dürfte wohl so ziemlich out sein.

Spaß beiseite:
Ich würde da eher auf einen verschobenen Punkt fahren. Im Prinzip so ähnlich wie der IrrePolterer, nur eben nicht das Tool, sondern den Zielpunkt verschieben.
Aber das kann jeder halten wie er will. Kommt auch darauf an worauf der Offset der Kamera bezogen ist, und wie das ganze kalibriert / eingerichtet wird.
Mit Base verrechnen würde ich nicht, sobald Verdrehungen im Spiel sind gibt das meist seltsame Überraschungen, weil sich die Verdrehung dann nicht auf das Bauteil bezieht, da muss das Base dann schon recht speziell eingerichtet werden.

Zitat von KAKA

Sieht ganz schön kompliziert aus!
Wieso ist "Offset X="alles andere?
Ich hatte überlegt, den Base Ursprung mit einem Teachpunkt zu überschreiben und die ganze Base zu drehen, geht das?
Dreht eine Base immer um den Ursprung?

1. Ist nicht so kompliziert.
2.Weil ich bei Copy/Paste vergessen habe, es anzupassen. :laugh: Korrigiere ich gleich.

Sicher kannst du genauso die Base drehen. Allerdings immer daran denken auch hier den geometrischen Operator zu nehmen, dann verdrehst/verschiebst du die Base immer um sich selbst.

Hier ein wenig einfacher. Mit Base:

DEF MOVEBASE()
;Kopiert Base 1 mit Offset in Base 11
FRAME OFFSET
OFFSET=$NULLFRAME ;Offset mit allen Koordinaten auf 0.0 initialisieren
OFFSET.Z=CAM_Z ;Offset.Z mit Z-Wert von Kamera überschreiben
OFFSET.A=CAM_A ;Offset.A mit A-Wert von Kamera überschreiben
BASE_DATA[11]=BASE_DATA[1]:OFFSET
ENDFCT

Zitat von KAKA

Also dreht sich die Base um X=0? Und nicht um $POS_ACT oder TCP?

Hääh?
Wenn du eine Base vermessen hast und per geometrischem Operator nur A drehst, dann wird um die Z-Achse des Base-Nullpunktes gedreht. Kleines Beispiel:

Wenn Du eine $POS_ACT auf's Tool draufrechnest (wie in Deinem Vorschlag), geht es ziemlich sicher schief. Bei Tool hast Du eher Erfolg mit

OFFSET=$NULLFRAME
OFFSET.A=CAM_OFFSET * (-1)
RETURN TOOL_DATA[1]:OFFSET

Das "*(-1)" natürlich nur, wenn das Vorzeichen falsch ist. Obiges bedingt, dass die Z-Achse des TOOLS exakt parallel zur Kamera-Sichtachse steht. Generell wäre Tool m. E. die richtige Variante.
Generell: Achtung bei solchen Sachen. Wenn man solche automatischen Verdrehungen aus irgendwelchen Kamerasystemen ohne weitere Überprüfung übernimmt, kriegt man schnell ein Problem mit den Achskonfigurationen. Oder der Roboter überlegt sich, dass es mit _diesem_ Tool doch viel kürzer wäre, andersherum zu schwenken. Und Kameras neigen bei symmetrischen Bildern dazu, Verdrehungen von 179° auszugeben statt -1°....

Grüße,
Michael

Außerdem hast du meinen Fehler "OFFSET.X" schön übernommen...

DEFFCT FRAME MOVETOOL()
FRAME OFFSET
OFFSET.X=$POS_ACT.X
OFFSET.X=$POS_ACT.Y
OFFSET.X=$POS_ACT.Z
OFFSET.X=$POS_ACT.A + CAM_OFFSET
OFFSET.X=$POS_ACT.B
OFFSET.X=$POS_ACT.C
RETURN TOOL_DATA[1]:OFFSET
ENDFCT

Was tust du, wenn in $POS_ACT.C z.B. 180.0, also nicht 0.0 drinsteht? Dann rechnest du diesen Winkel mit ein!
Das Ganze hängt also stark von deinem bisherigen Programmaufbau ab, und wonach sich die Offsetdaten berechnen, auf was sie sich beziehen und viele andere Faktoren...

Offtopic:

Zitat

DEFFCT FRAME MOVETOOL()
FRAME OFFSET
OFFSET = $POS_ACT
OFFSET.X = $POS_ACT.A + CAM_OFFSET
RETURN TOOL_DATA[1]:OFFSET
ENDFCT

Alles anzeigen

Macht's bissl kompakter

Zitat von d4nuu8

Macht's bissl kompakter

Dreht aber auch alle Werte mit, die gerade in $POS_ACT stehen. Wenn schon mit POS_ACT, dann sollte man auch nur die Werte nutzen, de benötigt werden.

Zitat von IrrerPolterer

Dreht aber auch alle Werte mit, die gerade in $POS_ACT stehen. Wenn schon mit POS_ACT, dann sollte man auch nur die Werte nutzen, de benötigt werden.

Alles was halt in einen Frame so rein passt. Also nichts anderes als zuvor auch schon...

Zitat von d4nuu8

Alles was halt in einen Frame so rein passt. Also nichts anderes als zuvor auch schon...

Das Kompakte hatte Programmiersklave schon geschrieben. Und dort eben auch mit $NULLFRAME, was für mich die einzige sinnvolle Lösung ist. Denn:
Wenn man das Bauteil nur in A drehen möchte und in $POS_ACT folgendes drinsteht: {...., a. 45.0, b 0.0, c 180.0....} dann dreht man z.B. auch noch C mit. Dürfte nicht so der Brüller sein.
Die Funktion in meinem Beispiel ist eine etwas abgespeckte Version eine Funktion aus meiner eigene Bibliothek, die ich immer auf jeder Steuerung nutze. Heißt da etwas anders:

GLOBAL DEFFCT FRAME MOVEFRAME(F_SOURCE:IN, X:IN,Y:IN,Z:IN, A:IN,B:IN,C:IN)
FRAME F_SOURCE, F_TEMP
REAL X, Y, Z, A ,B, C
F_TEMP.X=X
F_TEMP.Y=Y
F_TEMP.Z=Z
F_TEMP.A=A
F_TEMP.B=B
F_TEMP.C=C
RETURN F_SOURCE:F_TEMP
ENDFCT

Damit lässt sich also jeder Frame mit x-beliebigen Koordinaten verschieben. Egal ob Tool-, Basedata oder sonstige Frames.

Gar nix. Das ist doch alles nur rumraterei, solange man nicht die genauen Voraussetzungen kennt.
Um den Polterer zu zitieren:
"Das Ganze hängt also stark von deinem bisherigen Programmaufbau ab, und wonach sich die Offsetdaten berechnen, auf was sie sich beziehen und viele andere Faktoren...", hatte ich auch schon mal kurz angedeutet.
Die Spielerei mit dem $advance kann man sich auch getrost sparen. Das ist vollkommen unnötig.

Die Rückgabe der Funktion ist entscheidend. Es soll nichts in der Funktion bleiben, sondern die Funktion gibt einen Wert zurück, den du dann verwendest. Der Rückgabewert wird mit RETURN angegeben. Und der wird dann an der Stelle (unten im Beispiel im Main-Programm) verwendet, wo du ihn brauchst. Mal mit der auf deinen Anwendungsfall angepassten Funktion vom Polterer:

Funktion:

DEFFCT FRAME MOVETOOL() <--- Funktionsname für die Verwendung
FRAME OFFSET
OFFSET.X=$POS_ACT.X
OFFSET.X=$POS_ACT.Y
OFFSET.X=$POS_ACT.Z
OFFSET.X=$POS_ACT.A + CAM_OFFSET
OFFSET.X=$POS_ACT.B
OFFSET.X=$POS_ACT.C
RETURN TOOL_DATA[1]:OFFSET <----- Rückgabe
ENDFCT

Programmaufruf:

DEF MAIN()
INI
PTP HOME 100% DEFAULT


LOOP
Bla...bla..
mach irgendwas interessantes
...


TOOL_DATA[2]=MOVETOOL() <----- Verwendung


;mach wieder voll was geiles...
...
...
ENDLOOP


PTP HOME 100% DEFAULT
END

Alle Klarheiten beseitigt?
Wie du es verwendest (Tool oder Base) musst du dann selber gucken.

Gruß,
M.