Base Korrektur mit Hilfe eines Laser Sensors

Hallo,

Mein Problem:
Ein KUKA Roboter greift über eine im Boden integrierte Dehnfuge die sich bis zu 15 mm verändert. Das heißt er kann das Werkstück oft nicht mehr exakt greifen.

Meine Lösung:
Der Roboter bekommt an den Greifer einen Laser Abstands-Sensor, der jeden Tag einen Klotz auf der anderen Seite der Dehnfuge abmisst. Dabei nimmt er jeweils zwei Punkte auf drei verschiedenen Seiten des Klotzes auf (siehe rote Punkte im Anhang) und errechnet sich anhand dieser eine neue Base, bzw. versieht die vorhandene Base mit einem Korrekturwert. Bisher bin ich soweit, das der Sensor einen schnellen Eingang am Roboter, beim Erreichen der eingestellten Entfernungen, gibt und der Roboter sich die 6 Positionen speichert.

Meine Frage:
Hat sich einer mit so etwas schon mal beschäftigt? Bzw. gibts bereits Lösungen?
Wie kann ich die sechs gemessenen Punkte zu einer Base verrechnen?

Im Voraus schon mal ein Danke!
Grüße
eli

Zur Verständlichung:
Ich fahre mit der LIN-Funktion auf einer Achse (X,Y,Z) im Tool-Koordinaten-System auf den Messklotz zu. Bei 20 cm Abstand zum Messklotz kommt ein digitales Signal vom Sensor. Dieser geht direkt auf den schnellen Eingang am Roboter. Durch die logische 1 wird ein Interrupt aufgerufen, der dann die aktuelle Position des Roboters speichert.
Stimmt, es ist oversized, aber wenn ich das Problem schon angehe, würde ich auch gern alle 6 Achsen abgleichen um alle möglichen Verschiebungen auszugleichen.
Das Suchen des Würfels würde ich ausschließen, indem ich die Messpunkte beim ersten Vermessen im Abstand von 15 mm zum Rand aufnehme.
Mein Problem liegt eigentlich darin, anhand den 6 vermessenen Koordinaten ein Koordinatensytem aufzuspannen, mit dem ich dann die "alten" Base-Koordinaten korrigieren kann.
Aber danke schon mal für eure Anregungen!
Gruß
ELi

Bin mittlerweile soweit:
_______________________________

DEF main1( )

;wenn schneller Messeingang kommt, Unterprogramm posspeicher abarbeiten
INTERRUPT DECL 1 WHEN $MEAS_PULSE[1] DO posspeicher()
INTERRUPT ON

;Hilfspunkt
P2[1]=BASE_DATA[2]

;Messpunkte = 0 setzen
;X-Achse
P1[1]={X 0.0,Y 0.0,Z 0.0,A 0.0,B 0.0,C 0.0}
;B-Winkel
P1[2]={X 0.0,Y 0.0,Z 0.0,A 0.0,B 0.0,C 0.0}
;Y-Achse
P1[3]={X 0.0,Y 0.0,Z 0.0,A 0.0,B 0.0,C 0.0}
;A-Winkel
P1[4]={X 0.0,Y 0.0,Z 0.0,A 0.0,B 0.0,C 0.0}
;Z-Achse
P1[5]={X 0.0,Y 0.0,Z 0.0,A 0.0,B 0.0,C 0.0}
;C-Winkel
P1[6]={X 0.0,Y 0.0,Z 0.0,A 0.0,B 0.0,C 0.0}

ZAEHL = 0

…Positionen werden abgefahren...
__________________________________________________________
DEF posspeicher( )

;in nächste Speichervariable springen
ZAEHL = ZAEHL + 1

;Sensor schaltet -> aktuelle Pos. speichern
P1[ZAEHL]= $POS_INT

IF ZAEHL == 6 THEN
berechnen()
ENDIF

END
__________________________________________________________
DEF berechnen()

BASE_CORR.X = P1[1].X - P2[1].X
BASE_CORR.Y = P1[3].Y - P2[1].Y
BASE_CORR.Z = P1[5].Z - P2[1].Z

END
__________________________________

Ich gleich aber jetzt erstmal die X-,Y- und Z-Achse ab.
Mein Frage allerdings:
Kann ich den BASE_CORR.X einfach so mit einem Wert belegen, den der Roboter dann automatisch berechnet?

Grüße
Eli

zur Info:
Der Abgleich der X, Y und Z Achse funktioniert bereits. Bin gerade dabei die Rotatorischen Achsen noch irgendwie mit ins Programm zu nehmen.

Mein Programm zum Abgleich der X,Y und Z Achsen:

DEF haupt( )

DECL MSG_T EMPTY_MSG


;FOLD INI
  ;FOLD BASISTECH INI
    GLOBAL INTERRUPT DECL 3 WHEN $STOPMESS==TRUE DO IR_STOPM ( )
    INTERRUPT ON 3 
    BAS (#INITMOV,0 )
  ;ENDFOLD (BASISTECH INI)
  ;FOLD USER INI
    ;Make your modifications here
 
  ;ENDFOLD (USER INI)
;ENDFOLD (INI)


               


;FOLD PTP HOME  Vel= 100 % DEFAULT;%{PE}%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:HOME, 3:, 5:100, 7:DEFAULT
$BWDSTART = FALSE
PDAT_ACT=PDEFAULT
FDAT_ACT=FHOME




BAS (#PTP_PARAMS,100 )
$H_POS=XHOME
PTP  XHOME
;ENDFOLD








;Abfrage
EMPTY_MSG = {MSG_T: VALID FALSE, RELEASE FALSE, TYP #DIALOG, MODUL[] " ", KEY[] " ", PARAM_TYP #VALUE, PARAM[] " ", DLG_FORMAT[] " ", ANSWER 0}
$MSG_T=EMPTY_MSG
$MSG_T.MODUL[]="User"
$MSG_T.KEY[]="Referenzfahrt - Abgleichsfahrt" 
$MSG_T.PARAM_TYP=#VALUE
$MSG_T.TYP=#DIALOG
$MSG_T.DLG_FORMAT[]="Referenz|Abgleich"
$MSG_T.VALID=true
WHILE $MSG_T.VALID
   WAIT SEC 0.05
ENDWHILE
WAIT SEC 0.2
ANTWORT=$MSG_T.ANSWER




SWITCH ANTWORT


;Referenzfahrt angewählt 
CASE 1
;Fragen ob die Base bereits neu vermessen ist	
base_vermessen()


;neue Base speichern in Korr_Punkt
Hilfs_Base[1]=BASE_DATA[1]


;wenn schneller Messeingang kommt, Unterprogramm mess abarbeiten
INTERRUPT DECL 1 WHEN $MEAS_PULSE[1] DO mess()
 
;Abgleichsfahrt angewählt
CASE 2
;wenn schneller Messeingang kommt, Unterprogramm abgleich abarbeiten
INTERRUPT DECL 2 WHEN $MEAS_PULSE[1] DO abgleich()


DEFAULT 
ENDSWITCH




;FOLD PTP X_Vermessung_VP1 CONT Vel=100 % PDAT Tool[1]:sensor Base[0];%{PE}%R 5.5.32,%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:X_Vermessung_VP1, 3:C_PTP, 5:100, 7:PDAT
$BWDSTART=FALSE
PDAT_ACT=PPDAT
FDAT_ACT=FX_Vermessung_VP1
BAS(#PTP_PARAMS,100)
PTP XX_Vermessung_VP1 C_PTP
;ENDFOLD


;FOLD PTP X_Vermessung_VP2 Vel=100 % PDAT Tool[1]:sensor Base[0];%{PE}%R 5.5.32,%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:X_Vermessung_VP2, 3:, 5:100, 7:PDAT
$BWDSTART=FALSE
PDAT_ACT=PPDAT
FDAT_ACT=FX_Vermessung_VP2
BAS(#PTP_PARAMS,100)
PTP XX_Vermessung_VP2 
;ENDFOLD


IF (ANTWORT==1) THEN
	TRIGGER WHEN DISTANCE=0 DELAY=0 DO INTERRUPT_mess_ON () PRIO=-1
ELSE
	TRIGGER WHEN DISTANCE=0 DELAY=0 DO INTERRUPT_abgleich_ON () PRIO=-1
ENDIF
TRIGGER WHEN DISTANCE=0 DELAY=0 DO ACHSE=1 


;FOLD LIN X_Vermessung_MP Vel=0.05 m/s CPDAT Tool[1]:sensor Base[0];%{PE}%R 5.5.32,%MKUKATPBASIS,%CMOVE,%VLIN,%P 1:LIN, 2:X_Vermessung_MP, 3:, 5:0.05, 7:CPDAT
$BWDSTART=FALSE
LDAT_ACT=LCPDAT
FDAT_ACT=FX_Vermessung_MP
BAS(#CP_PARAMS,0.05)
LIN XX_Vermessung_MP 
;ENDFOLD


;FOLD PTP X_Vermessung_FP1 CONT Vel=100 % PDAT Tool[1]:sensor Base[0];%{PE}%R 5.5.32,%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:X_Vermessung_FP1, 3:C_PTP, 5:100, 7:PDAT
$BWDSTART=FALSE
PDAT_ACT=PPDAT
FDAT_ACT=FX_Vermessung_FP1
BAS(#PTP_PARAMS,100)
PTP XX_Vermessung_FP1 C_PTP
;ENDFOLD
 
...mit Y und Z wird genauso verfahren...

DEF mess( )

INTERRUPT OFF 1


SWITCH ACHSE
 
CASE 1


X_Referenz[1]= $POS_INT




CASE 2


Y_Referenz[1]= $POS_INT




CASE 3


Z_Referenz[1]= $POS_INT




DEFAULT
ENDSWITCH






END

DEF abgleich( )

INTERRUPT OFF 2
 
SWITCH ACHSE
 
CASE 1


X_ISTWERT[1]= $POS_INT


X_Korr[1].X = X_Istwert[1].X - X_Referenz[1].X 


BASE_DATA[1].X = Hilfs_BASE[1].X + X_Korr[1].X




CASE 2


Y_ISTWERT[1]= $POS_INT


Y_Korr[1].Y = Y_Istwert[1].Y - Y_Referenz[1].Y 


BASE_DATA[1].Y = Hilfs_BASE[1].Y + Y_Korr[1].Y




CASE 3


Z_ISTWERT[1]= $POS_INT


Z_Korr[1].Z = Z_Istwert[1].Z - Z_Referenz[1].Z


BASE_DATA[1].Z = Hilfs_BASE[1].Z + Z_Korr[1].Z




DEFAULT 
ENDSWITCH 






END

Hallo,

es hat sich mittlerweile wieder ein Problem aufgetan. Ich bin gerade dabei den Winkel A zu korriegieren. Dabei habe ich in A_Korr[1].A den Offset der auf die Hilfs_BASE addiert werden muss. Schaut folgendermaßen aus:

BASE_DATA[1].A = Hilfs_BASE[1].A + A_Korr[1].A

Allerdings kann scheinbar der Roboter keinen Winkel mit einem + Operator verändern. Lieg ich da richtig? Und wie kann ich das Problem lösen?
Ich habs auch schon mit:

BASE_DATA[1] = Hilfs_BASE[1] : A_Korr[1]

versucht. Allerdings hab ich die X, Y und Z Daten in der Base_DATA schon mit einem Offset versehen und will diese nicht wieder mit den X, Y und Z Daten von der Hilfs_BASE überschreiben.

Danke schon mal im voraus

Gruß
Eli

Hi,

yes, keine Orientierungen mit + oder -, nur : Operator geht!

Stimmt allerdings!

Um das Problem zu beseitigen fällt mir diese Lösung ein: Ich vermesse jeweils zwei Punkte auf jeder Seite des Würfels, berechne daraus die Drehungen und korrigiere die A,B und C Werte der BASE_DATA.
Danach fahr ich dann erneut auf der jeweiligen bereits korrigierte Achse in Stoßrichtung auf den zu messenden Würfel zu und korrigiere dann erst die X, Y und Z Werte der Base.

Wäre das möglich?

Gruß
Eli

Hallo,

komplett neuer Plan, da der alte mit ziemlicher Sicherheit nicht funktioniert.

Ich nehme auf 3 unterschiedlichen Seiten des Messklotzes jeweils 3 Messpunkte auf (insgesamt 9 Messpunkte). Aus den jeweils 3 Messpunkten auf den 3 Seiten spann ich 3 Ebenen auf. Wenn ich jeweils 2 Ebenen miteinander schneide, bekomme ich eine Gerade im Raum als Ergebniss. Somit bekomme ich 3 Geraden im Raum. Zugleich kann ich einen Nullpunkt bestimmen, indem ich die 3 Ebenen schneide.
Damit ich die Veränderung zur eigentlich Basis feststellen kann, wird zuerst eine Referenzfahrt (nach der 3-Punkte-Basisvermessung) angefahren. Bei einer Veränderung wird dann ein Abgleichprogramm aufgerufen, bei dem ebenfalls ein Nullpunkt und durch die Verschiebung der Geraden zu den Referenzgeraden ein Winkel berechnet wird.

Was meint ihr? Ist das umsetzbar?

Grüße
Eli

Hallo,
Ich hab jetzt die Lösung:

-> 9 Punkte vermessen -> 3 Ebenen aufspannen
-> jeweils 2 Ebenen schneiden -> Schnittgeraden berechnen -> Winkel aus den Schnittgeraden berechnen
-> alle 3 Ebenen schneiden -> Nullpunkt berechnen

Dieser Vorgang wird zum 1. mal nach der 3-Punkte-Base-Vermessung als Referenzfahrt durchgeführt.
Danach wird dann eine Ablgeichsfahrt angewählt, die dann die verschobenen Punkte mit den Referenzpunkten vergleicht und in der Base korrigiert!

Im Anhang die Berechnung im Programm (ist vielleicht noch etwas umständlich geschrieben, aber es funktioniert!)

funktioniert fast - verdammt!

Irgendwo in meinen Berechnungen steckt noch ein Denkfehler.
Ich glaube auch zu wissen wo: Ein Nullpunkt vom Referenz-Würfel wird berechnet. Dieser ist aber nicht gleich dem Ursprung der Base. Das heißt, wenn sich der Wüfel um seinen Nullpunkt dreht (A,B,C-Winkel) verändert sich zwar der Nullpunkt und die X,Y und Z Position des Würfels NICHT, aber die Koordinaten des Ursprung der Base.

Hat jemand einen Lösungsvorschlag?

Gruß
Eli

Das war auch meine Idee, den Würfel einfach als Base verwenden. Allerdings ist das in der Praxis wahrscheinlich nicht umsetzbar, weil die zu vermessende Base vorgegeben wird und der Würfel irgendwo anderst in der Base befestigt wird.
Allerdings gibt es eine Lösung auf das Problem (wurde von einem Kollegen gelöst)!
Der letzte Teil des Programms wurde von:

...
ELSE

BASE_DATA[1].X = Referenz_BASE[1].X - (Referenz_Daten[1].X - Schnittpunkt_x[1])


BASE_DATA[1].Y = Referenz_BASE[1].Y - (Referenz_Daten[1].Y - Schnittpunkt_y[1])


BASE_DATA[1].Z = Referenz_BASE[1].Z - (Referenz_Daten[1].Z - Schnittpunkt_z[1])


BASE_DATA[1].A = Referenz_BASE[1].A - (Referenz_Daten[1].A - Winkel_A[1])


BASE_DATA[1].B = Referenz_BASE[1].B - (Referenz_Daten[1].B - Winkel_B[1]) 


BASE_DATA[1].C = Referenz_BASE[1].C - (Referenz_Daten[1].C - Winkel_C[1])


ENDIF


END

auf diese weise geändert:

...
ELSE


Umrechnungs_BASE[1]=Inv_Pos(Referenz_Daten[1]):Referenz_BASE[1]


Vektor.x=Schnittpunkt_x[1]
Vektor.y=Schnittpunkt_y[1]
Vektor.z=Schnittpunkt_z[1]
Vektor.a=Winkel_A[1]
Vektor.b=Winkel_B[1]
Vektor.c=Winkel_C[1]


BASE_DATA[1]=Vektor:Umrechnungs_BASE[1]


ENDIF


END

Und jetzt funktioniert auch die ganze Sache!!!!

Danke für eure Hilfe!

Grüße
Eli