Externe Kinematik: Drehachse Offset

Tobi · 1. März 2014

Hallo zusammen,

ich hab eine für mich knifflige Frage.

Mit einem KR60 (KRC4) und gekoppeltem Dreh-Kipp-Positionierer DKP400 möchte ich ein rotationssymetrisches Bauteil bearbeiten. Das Bauteil ist auf dem DKP fixiert und der Roboter führt das Werkzeug.
Ich habe ein Programm für die Bearbeitung eines Segmentes des Bauteiles. Bei der Bearbeitung wird synchron die Drehachse E2 (endlos) vom DKP verfahren. Nach der Bearbeitung des ersten Segments soll der DKP das Bauteil weiterdrehen und das Bearbeitungs-Programm erneut ablaufen. Und somit Segment für Segment mit einem einzelnen Bearbeitungs-Programm das Bauteil bearbeiten.

Mein Problem besteht darin, für die Bearbeitung des nächsten Segmentes ein Offset zwischen tatsächlicher Drehachsposition E2 und der gekoppelten Basis zu bekommen.

Verändere ich das Offset bei der Basis EK(...) im Programm, wird natürlich Bauteil UND Bearbeitungs-Bahn entsprechend gedreht. Und die Bearbeitung würde an der selben Stelle am Bauteil erfolgen, nur eben an einer anderen Arbeitsposition auf dem DKP.

Meine Frage: Wie und wo kann ich das benötigte Offset für die Drehachse E2 programmtechnisch realisieren?

Freue mich über Vorschläge.

Schöne Grüße
Tobias

SJX · 2. März 2014

Hallo Tobi,

definitiv knifflige Frage.

Was gehen würde ist, meiner Meinung nach aber nicht optimal, ist,
wenn Du nach der Bearbeitung des Segmentes E2 auf 0 Grad plus Versatz zum nächsten Segment fährst,
und dann E2 aus Programm heraus justierst.

Sonst müsste man ja in den Positionen den e2 wert verändern und den Offsetversatz im gekoppelten Base schieben.
Wie hast Du dies exakt probiert?
Ist immer einfacher was zu Schreiben, wenn man exakt sieht, was Du schon probiert hast.
Programmiert sind die Positionen des Ablaufes danach mit ILF's oder in KRL?

Gruss SJX

Tobi · 3. März 2014

Hallo SJX,

Danke für die Antwort.

An die Neujustage habe ich auch bereits gedacht.
Das Bearbeitungs-Programm ist in KRL Syntax verfasst. Schön wäre eine Variable mit der Justagewert der Achse E2 ein temoräreres Offset zugewiesen werden könnte, bevor die eigentliche Bearbeitung gestartet wird.

Ich habe probehalber ein Programm mit zwei Segmenten generiert. Die 'gleichen' Postionen der Segmente unterscheiden sich nicht nur im Wert für E2, sondern die Drehung spiegelt sich auch in den einzelnen Positionen wieder. Ein statisches Offset mittels der Programm-Basis erscheint mir daher nicht machbar.

Schöne Grüße
Tobias

WolfHenk · 3. März 2014

hmm... wärs net einfacher, einfach mit der Doppelpunktfunktion die base passend zu rotieren und e2 anzupassen?

Chili1886 · 3. März 2014

Hallo Tobi,

habe so etwas mal mit einer KRC1 gemacht (also schon ne weile her). Roboter mit nathematisch gekoppeltem DKP.
Bei mir war es so das der Drehpunkt des Bauteils der Drehpunkt des DKP war (also die A-Achse)
ich habe damals nur in der EX_AX_DATA[n] den Offset von A angepasst und dann nochmal ein INIT durchlaufen, dann gings.

Ob das bei der KRC4 immernoch so ist kann ich leider nicht sagen, aber vielleicht ist es ja ein Anhaltspunkt.

Gruß Chili1886

soma · 4. März 2014

Zitat von Tobi

Schön wäre eine Variable mit der Justagewert der Achse E2 ein temoräreres Offset zugewiesen werden könnte, bevor die eigentliche Bearbeitung gestartet wird.

Code

$ASYNC_EX_AX_DECOUPLE=7;
$AXIS_ACT.E1=$AXIS_ACT.E1+25;
$ASYNC_EX_AX_DECOUPLE=0;

Gehts nicht auch so?
Ist abba nur KRC2 bewährt

Tobi · 6. März 2014

Vielen Dank für Eure Antworten.
Habe heute am Roboter verschiedene Vorgehensweisen testen können.

Die Anpassung des Offsets des DKP in den Daten der Externen Kinematik bewirkt zwar ein Rotieren der Bearbeitung zum DKP. Allerdings wandert die Bearbeitung dann aus Roboter-Sicht um den Tisch.

Das Auskoppeln der Achse habe ich ebenfalls probiert. Da hakt es an der Fehlermeldung "Einzelbremsensteuerung für Zusatzachsen nicht aktiv". Die Zeilen habe ich wie folgt in einem kurzen Test-Programm eingebunden:

Code

&ACCESS RVP
&REL 20
&COMMENT GENERATED BY ROBOTMASTER
&PARAM TEMPLATE = C:\KRC\Roboter\Template\vorgabe
&PARAM EDITMASK = *
DEF ROT_TEST()
 
EXT BAS (BAS_COMMAND :IN,REAL :IN )
 
INT I


BAS (#INITMOV,0 )
 
;******SETTINGS FOR PTP MOTION***********************
;FOLD
;SET PTP $VEL_AXIS AND $ACC_AXIS
FOR I=1 TO 6
   $VEL_AXIS[I]=50
   $ACC_AXIS[I]=50
ENDFOR
;ENDFOLD (SET PTP $VEL_AXIS AND $ACC_AXIS)
 
;******SETTINGS FOR LIN AND ARC MOTION***************
;FOLD
;SET LIN AND ARC MOTION VARIABLES
$VEL.CP=0.02
$VEL.ORI1=200
$VEL.ORI2=200
$ACC.ORI1=100
$ACC.ORI2=100
;ENDFOLD (SET LIN AND ARC MOTION VARIABLES)
 
;******SETTINGS FOR POSITIONING CRITERIA*************
;FOLD
;SET POSITIONING CRITERIA
  $APO.CPTP = 10.0000
  $APO.CDIS = 0.5000
;ENDFOLD (SET POSITIONING CRITERIA)
$BASE=EK(MACHINE_DEF[2].ROOT,MACHINE_DEF[2].MECH_TYPE,BASE_DATA[17])
$TOOL={X 252.5000,Y 0.0023,Z 171.2100,A 0.0000,B -90.0000,C 180.0000}
 
$ADVANCE = 5
PTP  {A1 0.0000,A2 -90.0000,A3 90.0000,A4 0.0000,A5 0.0000,A6 0.0000,E1 0.0000,E2 0.0000,E3 0.0,E4 0.0,E5 0.0,E6 0.0}


$ASYNC_EX_AX_DECOUPLE='B0010';
$AXIS_ACT.E2=$AXIS_ACT.E2+30;
$ASYNC_EX_AX_DECOUPLE='B0000';


PTP  {X -100.0000,Y -100.0000,Z 200.0000,A 0.0000,B 0.0000,C 180.0000,E1 0.0000,E2 30.0000,E3 0.0,E4 0.0,E5 0.0,E6 0.0,S 6,T 50}
$VEL.CP=0.035
LIN  {X -100.0000,Y -100.0000,Z 150.0000,A 0.0000,B 0.0000,C 180.0000,E1 0.0000,E2 20.0000,E3 0.0,E4 0.0,E5 0.0,E6 0.0}
LIN  {X -250.0000,Y -100.0000,Z 150.0000,A 0.0000,B 0.0000,C 180.0000,E1 0.0000,E2 30.0000,E3 0.0,E4 0.0,E5 0.0,E6 0.0}
HALT


PTP  {A1 0.0000,A2 -90.0000,A3 90.0000,A4 0.0000,A5 0.0000,A6 0.0000,E1 0.0000,E2 0.0000,E3 0.0,E4 0.0,E5 0.0,E6 0.0}
 
END

Alles anzeigen

Freue mich über weitere Unterstützung.

Schöne Grüße
Tobias

SJX · 6. März 2014

Hallo Tobi,

vermute, dass die externe Achse nicht als abkoppelbar definiert ist.
Schau mal im WoV in der externen Achsen Konfiguration, ob der Haken gesetzt ist.

Gruss SJX

Tobi · 10. März 2014

Hallo Zusammen,

die externen Achsen habe ich nun als abkoppelbar in den Einstellungen zu den 'Externen Achsen' definiert. Bzw. den Haken bei 'Abkoppelbar' gesetzt.
Den Bremsmodus in der mada entsprechend auf 'B1101' geändert.

Nun kommt beim Programmablauf die Fehlermeldung: "Fehler beim Ab-/Ankoppeln".

Irgendeine Kleinigkeit fehlt da wohl noch...

Sonnige Grüße
Tobias

SJX · 10. März 2014

Hallo Tobi,

probiere es mal so.

REAL ISTPOS

$ADVANCE=0
$BASE=$WORLD
ISTPOS=$AXIS_ACT.E2
$ASYNC_AXIS='B0010'
$ASYNC_EX_AX_DECOUPLE='B0010'

$AXIS_ACT.E2=ISTPOS + 30.0

$ASYNC_EX_AX_DECOUPLE=0
$ASYNC_AXIS=0
BAS(#EX_BASE,1)
$ADVANCE=3

Gruss SJX

Tobi · 11. März 2014

Hallo,

es hat mit dem vorhergehenden Befehlen funktioniert.

Nur die Position nach der Zeile mit der gekoppelten (synchrone) Base[17] war nicht korrekt. Bei aktiver synchroner Base ist kein Asynchron-schalten möglich.
Nachdem ich die Befehle vor die Base-Zeile verschoben habe, hat es funktioniert.

Am Ende des Programmes wähle ich nun eine andere Base ohne Kopplung. Und nehme dann anschließend die anfängliche Änderung wieder zurück, damit der Justagewert abschließend wieder stimmt.

Code

&ACCESS RVP
&REL 20
&COMMENT GENERATED BY ROBOTMASTER
&PARAM TEMPLATE = C:\KRC\Roboter\Template\vorgabe
&PARAM EDITMASK = *
DEF ROT_TEST()
 
EXT BAS (BAS_COMMAND :IN,REAL :IN )
 
INT I


BAS (#INITMOV,0 )
 
;******SETTINGS FOR PTP MOTION***********************
;FOLD
;SET PTP $VEL_AXIS AND $ACC_AXIS
FOR I=1 TO 6
   $VEL_AXIS[I]=50
   $ACC_AXIS[I]=50
ENDFOR
;ENDFOLD (SET PTP $VEL_AXIS AND $ACC_AXIS)
 
;******SETTINGS FOR LIN AND ARC MOTION***************
;FOLD
;SET LIN AND ARC MOTION VARIABLES
$VEL.CP=0.02
$VEL.ORI1=200
$VEL.ORI2=200
$ACC.ORI1=100
$ACC.ORI2=100
;ENDFOLD (SET LIN AND ARC MOTION VARIABLES)
 
;******SETTINGS FOR POSITIONING CRITERIA*************
;FOLD
;SET POSITIONING CRITERIA
  $APO.CPTP = 10.0000
  $APO.CDIS = 0.5000
;ENDFOLD (SET POSITIONING CRITERIA)


$ASYNC_EX_AX_DECOUPLE='B0010';
$AXIS_ACT.E2=$AXIS_ACT.E2+30; 
$ASYNC_EX_AX_DECOUPLE='B0000';


$BASE=EK(MACHINE_DEF[2].ROOT,MACHINE_DEF[2].MECH_TYPE,BASE_DATA[17])
$TOOL={X 252.5000,Y 0.0023,Z 171.2100,A 0.0000,B -90.0000,C 180.0000}
 
$ADVANCE = 5
PTP  {A1 0.0000,A2 -90.0000,A3 90.0000,A4 0.0000,A5 0.0000,A6 0.0000,E1 0.0000,E2 0.0000,E3 0.0,E4 0.0,E5 0.0,E6 0.0}
PTP  {X -100.0000,Y -100.0000,Z 200.0000,A 0.0000,B 0.0000,C 180.0000,E1 0.0000,E2 30.0000,E3 0.0,E4 0.0,E5 0.0,E6 0.0,S 6,T 50}
$VEL.CP=0.035
LIN  {X -100.0000,Y -100.0000,Z 150.0000,A 0.0000,B 0.0000,C 180.0000,E1 0.0000,E2 20.0000,E3 0.0,E4 0.0,E5 0.0,E6 0.0}
LIN  {X -250.0000,Y -100.0000,Z 150.0000,A 0.0000,B 0.0000,C 180.0000,E1 0.0000,E2 30.0000,E3 0.0,E4 0.0,E5 0.0,E6 0.0}
HALT


PTP  {A1 0.0000,A2 -90.0000,A3 90.0000,A4 0.0000,A5 0.0000,A6 0.0000,E1 0.0000,E2 0.0000,E3 0.0,E4 0.0,E5 0.0,E6 0.0}


$BASE={X 0.0,Y 0.0,Z 0.0,A 0.0,B 0.0,C 0.0,E1 0.0,E2 0.0,E3 0.0,E4 0.0,E5 0.0,E6 0.0}


$ASYNC_EX_AX_DECOUPLE='B0010';
$AXIS_ACT.E2=$AXIS_ACT.E2-30;       
$ASYNC_EX_AX_DECOUPLE='B0000';


PTP  {A1 0.0000,A2 -90.0000,A3 90.0000,A4 0.0000,A5 0.0000,A6 0.0000,E1 0.0000,E2 0.0000,E3 0.0,E4 0.0,E5 0.0,E6 0.0}
END

Alles anzeigen

Vielen Dank für eure Unterstützung.

Sonnige Grüße
Tobias

Externe Kinematik: Drehachse Offset

Erstelle ein Benutzerkonto oder melde dich an um zu kommentieren

Gebrauchtroboter kaufen - Was ist zu beachten. Die Checkliste zum kauf von gebrauchten Robotern

Was macht ein Roboterprogrammierer genau und was verdient er?

Vernetzen, referenzieren, kollaborieren: Das B2B Portal für die Produktionsautomatisierung

Sie wollen Ihr Stellenangebot im Roboterforum schalten? Ab 149€

Werde Roboterprogrammierer bei ROBTEC GmbH in Mainburg / Bayern

Teilen

Tags

Wieviele Mitglieder waren heute eingeloggt?