Interrupt Problem, Resume Fehlermeldung unzulässige Programmstrucktur

frank23 · 7. September 2020

Moin Roboter Experten,

ich bin seit längerem mal wieder im VW user unterwegs, an einer 5.4.7er Version und bekomme meine Bewegung einfach nicht so abgebrochen wie ich es mir Vorstelle.

Unterlagen und hier im Forum habe ich jetzt zu genüge gelesen, komme aber einfach nicht weiter.

Problem:

Roboter soll in bestimmten Fällen (durch Eingang 353) seine Bewegung "zielpunkt" unterbrechen und zurück auf "ausgangspunkt".

Mein Probelm ist das der Roboter nach dem auslösen genau an die Stelle zurück fährt wo der Fehler festgestellt wird (auf dem weg "zielpunkt") das soll er nicht.

Deswegen habe ich gedacht ich baue den Befehl Resume mit ein. Nun bekomme ich aber an der Stelle die Fehlermeldung: unzulässige Programmstrucktur.

Dann habe ich einen zweiten weg versucht und habe gedacht wenn ich den Rob nicht gestoppt bekomme schreibe ich die Position einfach um. Das funktioniert aber auch nicht, irgendwie merkt sich der Roboter wo er hin wollte und fährt zum zielpunkt.

Ich hoffe auf eure Mithilfe, vielen Dank im vorraus.

Code

startpunkt=$pos_act

zielpunkt=$pos_act

ausgangspunkt=$pos_act



$advance=0



Interrupt DECL 10 when $IN[353]==false do up()



IF $FLAG[901]==true then

IF $FLAG[902]==false then

startpunkt.z=startpunkt.z-PAR1

zielpunkt.z=zielpunkt.z-PAR2-PAR1



$vel.cp=0.1

$acc.cp=5

$APO.CVEL=0



Interrupt 10 ON

Interrupt Enable 10



LIN startpunkt

speed=PAR3*0.001



wait sec 0.5



If $FLAG[903]==false then

sel_RES=select (#Makro,50,true,,,,,FALSE)

endif



LIN zielpunkt



If $FLAG[903]==false then

sel_RES=select (#Makro,50,true,,,,,FALSE)

endif

endif

endif

Interrupt off 10



$vel.cp=0.1

LIN ausgangspunkt



$advance=1

END



***********************************************************

def up()

Interrupt off 10

brake

wait sec 0.5

resume

end



************************************************************

auch schon versucht:



def up()

Interrupt off 10

brake

wait sec 0.5

zielpunkt=ausgangspunkt

wait sec 0.5

end

Alles anzeigen

Team Rosario · 7. September 2020

Hallo Frank32,

da wo der Interrupt deklariert wird darfst du nicht den Interrupt Auslösen du must eine Ebene tiefer stehen wie die Deklaration.

Dann bekommst du auch keine Fehlermeldung.

frank23 · 8. September 2020

Hallo Team Rosario,

vielen dank für den Tip, hab das jetzt so ausprobiert wie ich es verstanden habe und den Interrupt Aufruf direkt unter meinen Deklarationsteil geschrieben. Das sieht jetzt so aus:

Code

real speed

Interrupt DECL 10 when $IN[353]==false do up()

wait sec 0.5



startpunkt=$pos_act

zielpunkt=$pos_act

ausgangspunkt=$pos_act



$advance=0



IF $FLAG[901]==true then

IF $FLAG[902]==false then

startpunkt.z=startpunkt.z-PAR1

zielpunkt.z=zielpunkt.z-PAR2-PAR1



$vel.cp=0.1

$acc.cp=5

$APO.CVEL=0



Interrupt 10 ON

Interrupt Enable 10



LIN startpunkt

speed=PAR3*0.001



wait sec 0.5



If $FLAG[903]==false then

sel_RES=select (#Makro,50,true,,,,,FALSE)

endif



LIN zielpunkt



If $FLAG[903]==false then

sel_RES=select (#Makro,51,true,,,,,FALSE)

endif

endif

endif

Interrupt off 10



$vel.cp=0.1

LIN ausgangspunkt



$advance=1

END





def up()

Interrupt off 10

brake

wait sec 0.5

resume

end

Alles anzeigen

Die Frames für startpunkt, zielpunkt und ausgangspunkt habe ich in die config geschrieben, die wollte ich aus versuchsgründen global haben.

Leider immer noch beim Ablauf die selbe Fehlermeldung: Unzulässige Programmstruktur für RESUME

Team Rosario · 8. September 2020

Hallo Frank32,

Probiere es mal so:

Du musst eine Ebene tiefer wo du den Interrupt deklariert hast ihn auslösen. Also hier im Suchen ()

Du machst deine Fahrt zum Zielpunkt im Programm Suchen das du dann mit dem $IN[353] = False abrichst und du dein up() startest mit dem Resume

Springt er dann zurück in dein Main () wo du den Interrupt deklariert hast. Kann sein das ich ein END falsch gestellt habe aber so muss es gehen.

Code

DEF Main ()



real speed

Interrupt DECL 10 when $IN[353]==false do up()

wait sec 0.5



Suchen ()

Hier kommst du nach dem Resume wieder raus.

Interrupt off 10 der off ist nicht zwingend nötig da du ihn in deinem UP() schon OFF geschaltet hast



$vel.cp=0.1

LIN ausgangspunkt



$advance=1



END





DEF Suchen ()

startpunkt=$pos_act

zielpunkt=$pos_act

ausgangspunkt=$pos_act



$advance=0



IF $FLAG[901]==true then

IF $FLAG[902]==false then

startpunkt.z=startpunkt.z-PAR1

zielpunkt.z=zielpunkt.z-PAR2-PAR1



$vel.cp=0.1

$acc.cp=5

$APO.CVEL=0



Interrupt 10 ON

Interrupt Enable 10



LIN startpunkt

speed=PAR3*0.001



wait sec 0.5



If $FLAG[903]==false then

sel_RES=select (#Makro,50,true,,,,,FALSE)

endif



LIN zielpunkt



If $FLAG[903]==false then

sel_RES=select (#Makro,51,true,,,,,FALSE)

endif

endif

endif



END



def up()

Interrupt off 10

brake

wait sec 0.5

resume

end

Alles anzeigen

JonasX · 8. September 2020

Hallo Frank,

wie Team Rosario bereits geschrieben hat darf der Interrupt nicht auf der Deklarationsebene eingeschalten werden. D.h. du muss den Interrupt in einem Unterprogramm einschalten.

Ggf. kannst du deine Anfahrt auf den Zielpunkt (ab z.B. Zeile: "$advance=0" bis Zeile: "Interrupt off 10") komplett in ein Unterprogram auslagern und dieses Unterprogramm aus deinem Hauptprogramm aufrufen.

Eine weitere Möglichkeit wäre das Interrupt Handling komplett auszulagern. Z.b. in eine gesonderte Interrupt.scr

Code

GLOBAL DEF IR_1_ON( )

    INTERRUPT ON 1

END

; ################################################

GLOBAL DEF IR_1_OFF( )

    INTERRUPT OFF 1

END

; ################################################

GLOBAL DEF IR_1( )

    INTERRUPT OFF 1

    BRAKE

    ; Quellcode Interrupt

    RESUME

END

Alles anzeigen

In deinem Quellcode rufst du dann die Funktionen aus der Interrupt.src auf.

Wenn ich das richtig verstanden habe möchtest du die Bewegung zum "Zielpunkt" überwachen? Solltest du den Interrupt dann nicht erst nach erreichen des "Startpunkt" einschalten bzw. vor der Bewegung zum "Zielpunkt"?

Hermann · 8. September 2020

Auf die Gefahr hin, dass ich mich wieder in die Nesseln setze:

das Problem wurde schon mehrfach behandelt, mit dem Suchbegriff RESUME findest Du da sicherlich jede Menge Infos.

frank23 · 8. September 2020

Moin miteinander,

danke für den Tipp Hermann, wie ich allerdings eingangs bereits geschrieben habe, bin ich damit nicht weiter gekommen.

Team Rosario und JonasX Top, ich habe meinen Fehler jetzt verstanden, vielen Dank für die Hilfe.

Bei mir "hing" es an dem Verständnis für die Aufteilung der Struktur des Interrupts. Ich dachte ich müsse einfach nur alles in entsprechendem Schema von oben nach unten im User eintragen. Erst jetzt habe ich begriffen was es mit den einzelnen UP´s innerhalb des Users zu tun hat.

Einmal das ganze neu aufgeteilt und es lief.

Ich werde morgen mal den Code anhängen um das Thema sauber abzuschließen.

frank23 · 9. September 2020

wie gestern noch geschrieben, hier das funktionierende Programm. Die Deklaration der Variablen sind in die config gewandert.

Vielen Dank nochmal für die Unterstützung

Code

INTERRUPT DECL 10 WHEN $IN[353]==false DO kollision()

startpunkt=$pos_act

zielpunkt=$pos_act

ausgangspunkt=$pos_act



IF $FLAG[901]==true then

IF $FLAG[902]==false then

startpunkt.z=startpunkt.z-PAR1

zielpunkt.z=zielpunkt.z-PAR2-PAR1



$vel.cp=0.1

$acc.cp=5

$APO.CVEL=0

LIN startpunkt

wait sec 0.5

schweissen()

interrupt off 10

$vel.cp=0.1

lin ausgangspunkt

endif

endif

end



def schweissen()

INTERRUPT ON 10

INTERRUPT ENABLE 10

IF $FLAG[903]==false then

sel_RES=SELECT (#Makro,50,TRUE,,,,,FALSE)

endif

speed=PAR3*0.001

$vel.cp=speed

LIN zielpunkt

IF $FLAG[903]==false then

sel_RES=SELECT (#Makro,51,TRUE,,,,,FALSE)

endif



$vel.cp=0.1

LIN ausgangspunkt

$FLAG[901]=false

END

def kollision()

INTERRUPT OFF 10

brake

sel_RES=SELECT (#Makro,51,TRUE,,,,,FALSE)

$out[190]=true

wait for $in[190]

$out[190]=false

wait sec 0.1

resume

end

Alles anzeigen

Interrupt Problem, Resume Fehlermeldung unzulässige Programmstrucktur

Zum Hilfreichsten Beitrag springen

Erstelle ein Benutzerkonto oder melde dich an um zu kommentieren

Gebrauchtroboter kaufen - Was ist zu beachten. Die Checkliste zum kauf von gebrauchten Robotern

Was macht ein Roboterprogrammierer genau und was verdient er?

Vernetzen, referenzieren, kollaborieren: Das B2B Portal für die Produktionsautomatisierung

Sie wollen Ihr Stellenangebot im Roboterforum schalten? Ab 149€

Werde Roboterprogrammierer bei ROBTEC GmbH in Mainburg / Bayern

Teilen

Wieviele Mitglieder waren heute eingeloggt?