Target-Punkte eines Pfades verschieben

Maritn · 25. September 2019

Servus Zusammen,

ich möchte jeden Punkt eines Pfades mit "Offs" verschieben. Gibt es eine Möglichkeit, mit der ich nicht jeden Punkt einzeln mit Offs verschieben muss?

Stand jetzt sieht das ganze so aus:

_________________________________________________________________________________________________________________________________________

pAktuellePosition:=Target_25700;

MoveL Offs(pAktuellePosition,0,-30,0),v1000,z100,tCentralfeeder\WObj:=wTischMitBohrungen;

MoveL Offs(pAktuellePosition,0,30,0),v1000,z100,tCentralfeeder\WObj:=wTischMitBohrungen;

pAktuellePosition:=Target_25710;

MoveL Offs(pAktuellePosition,0,30,0),v1000,z100,tCentralfeeder\WObj:=wTischMitBohrungen;

MoveL Offs(pAktuellePosition,0,-30,0),v1000,z100,tCentralfeeder\WObj:=wTischMitBohrungen;

pAktuellePosition:=Target_25720;

MoveL Offs(pAktuellePosition,0,-30,0),v1000,z100,tCentralfeeder\WObj:=wTischMitBohrungen;

MoveL Offs(pAktuellePosition,0,30,0),v1000,z100,tCentralfeeder\WObj:=wTischMitBohrungen;

pAktuellePosition:=Target_25730;

MoveL Offs(pAktuellePosition,0,30,0),v1000,z100,tCentralfeeder\WObj:=wTischMitBohrungen;

MoveL Offs(pAktuellePosition,0,-30,0),v1000,z100,tCentralfeeder\WObj:=wTischMitBohrungen;

…

_________________________________________________________________________________________________________________________________________

Meine Idee war es anfangs, das ganze in eine schleife zu packen, was irgendwie so ausehen sollte:

_________________________________________________________________________________________________________________________________________

FOR j FROM 25700 TO 28910 DO

MoveL Offs(pAktuellePositionGNK,0,-30,0),v1000,z100,tCentralfeeder\WObj:=wTischMitBohrungen;

MoveL Offs(pAktuellePositionGNK,0,30,0),v1000,z100,tCentralfeeder\WObj:=wTischMitBohrungen;

pAktuellePositionGNK:= 1. Target-Punkt;

MoveL Offs(pAktuellePositionGNK,0,30,0),v1000,z100,tCentralfeeder\WObj:=wTischMitBohrungen;

MoveL Offs(pAktuellePositionGNK,0,-30,0),v1000,z100,tCentralfeeder\WObj:=wTischMitBohrungen;

pAktuellePositionGNK:=2. Targetpunkt;

ENDFOR

_________________________________________________________________________________________________________________________________________

Allerdings weiß ich bei einer Schleife nicht, wie man das ganze mit einem Platzhalter weiter führt, der Durchgang für Durchgang auf den nächsten Targetpunkt

weiter springt.

Mir ist eigentlich jede Lösung recht die schneller ist als meine 1. Vorgehensweise

Danke schon mal

Sven Weyer · 25. September 2019

Hallo Martin,

pack doch deine Positionen in ein Datenfeld

PERS robtarget pAktuellePositionGNK{10} = Datenfeld eindimensional

FOR i FROM x TO Y

MoveL Offs(pAktuellePositionGNK{i},0,30,0),v1000,z100,tCentralfeeder\WObj:=wTischMitBohrungen;

MoveL Offs(pAktuellePositionGNK{i},0,-30,0),v1000,z100,tCentralfeeder\WObj:=wTischMitBohrungen;

ENDFOR

So oder ähnlich, keine gewähr auf den Syntax, prüf es einfach im Roboter. Sollte als Idee gehen.

Gruß

padostms · 25. September 2019

Zitat von padostms

Hallo Martin

Brauchst nicht alle positionen mit offset definieren sondern musst du die anfangspunkt anlegen X,Y,Z koordinaten eingeben Fertig.Habe bei dir gesehen dass du immer mit -30 mm verschiebst.Bei mir ist so eine NIO ablage.7x4 Plätze.Funktioniert einwandfrei.

Micky · 25. September 2019

Hallo,

Du könntest deine Bahn mit der Instruktion "PDispSet" bzw. "PDispOn" im Programm verschieben. Dabei musst Du darauf achten, dass die Verschiebung nach der Bewegung wieder mit "PDsipOff" deaktiviert wird.

Alternativ könntest Du auch den Oframe Deines Werkobjektes anpassen.

Gruß

Micky

Z750 · 25. September 2019

Hallo Maritn,

wie Sven Weyer schon geschrieben hat, könntest du ein Robtarget-Array erstellen.

Wenn du deine Robtargets aber nicht "anfassen" möchtest kannst du auch einfach über GetDataVal deine bisherigen Robtargets verwenden. Wie immer führen viele Wege nach Rom.

Code

VAR robtarget tmpTarget;

FOR j FROM 25700 TO 28910 STEP 10 DO
    GetDataVal "Target_"+ValToStr(j),tmpTarget;
    MoveL Offs(tmpTarget,0,-30,0),v1000,z100,tCentralfeeder\WObj:=wTischMitBohrungen;
    MoveL Offs(tmpTarget,0,30,0),v1000,z100,tCentralfeeder\WObj:=wTischMitBohrungen;
ENDFOR

Gruß Z

Sven Weyer · 26. September 2019

Hallo Z750,

danke für die Info, man lernt nie aus.

Finde die Idee sehr gut!

Gruß

padostms · 26. September 2019

Hi

Bei mir ist so mit Offset und bool kombination.

Funktioniert auch ganz gut.

Code

MODULE NIOABLEGEN
    
LOCAL CONST robtarget Abl_VP:=[[1098.66,850.75,550.62],[0.0358566,0.0147645,0.998972,-0.0234724],[0,-1,0,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]];
LOCAL CONST robtarget Abl_NP:=[[1008.66,700.75,400.62],[0.0358566,0.0147645,0.998972,-0.0234724],[0,-1,0,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]];
LOCAL CONST robtarget Abl_referenz:=[[1068.66,780.75,496.62],[0.0358566,0.0147645,0.998972,-0.0234724],[0,-1,0,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]];
LOCAL PERS  robtarget Abl:=[[1168.66,1280.75,496.62],[0.0358566,0.0147645,0.998972,-0.0234724],[0,-1,0,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]];
!                                x   0     1     2     3     4     5     6     7    8      9    
LOCAL PERS  bool Ablage{4,7}:=[[TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE], 
                              [TRUE,TRUE,TRUE,TRUE,TRUE,FALSE,FALSE], 
                              [FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE], 
                              [FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE]];
!
LOCAL PERS num NrX:=2;
LOCAL PERS num NrY:=6;
LOCAL PERS num NrZ:=1;
!
LOCAL PERS pos Abstand:=[100,100,25];

LOCAL var num i:=0;
LOCAL var num i2:=0;
!
!  ____->X________
! |R              |
! |               |Y
! |               ||
! |_______________|

PROC Ablegeroutine()

!Leeren Platz suchen!!!
FOR i FROM 1 TO DIM(Ablage,1) DO
    FOR i2 FROM 1 TO DIM(Ablage,2) DO
        IF Ablage{i,i2}=false THEN
            NrX:=i;
            NrY:=i2;
            NrZ:=1;
            GOTO lblPlatzGefunden;
        endif
    ENDFOR        
ENDFOR
 Grundstellung;
UIMsgBox   \Header:="NIO Box Voll","NIO Box entleeren"
                        \MsgLine2:="----------------"
                        \MsgLine3:="OK drücken wenn Fertig"
                        \MsgLine4:=""
                        \MsgLine5:="----------------"
                        \Buttons:=btnOK
                        \Icon:=iconWarning;
                        Stop;
!Plätze löschen
!und Startwert setzen
FOR i FROM 1 TO DIM(Ablage,1) DO
    FOR i2 FROM 1 TO DIM(Ablage,2) DO
        Ablage{i,i2}:=FALSE;
    ENDFOR        
ENDFOR
NrX:=1;
NrY:=1;
NrY:=1;
lblPlatzGefunden:
Startmove;
MoveJ Abl_VP, v3000, z1, tool0;
!
!
!Position berechnen

Abl:=Offs(Abl_referenz,(NrX-1)*Abstand.x,(NrY-1)*Abstand.y,(NrZ-1)*Abstand.z);
!
MoveL Offs(Abl,0,0,5), v3000, z1, tool0;
MoveL Abl, v3000, fine, tool0;
!
IF FALSE MoveL Abl_referenz, v7000, z1, tool0;
!GREIFER öffnen!!!!!
!In Speicher schreiben
Ablage{NrX,NrY}:=TRUE;
!
!
MoveL Offs(Abl,0,0,5), v3000, z1, tool0;
!
MoveJ  Offs(Abl_NP,50,50,50), v3000, z5, tool0;
ENDPROC

Alles anzeigen

Maritn · 26. September 2019

Vielen dank für die schnellen Antworten ich werde alles einmal ausprobieren.

Hatte leider gestern ein wenig Zeitdruck und hab das ganze jetzt auf eine andere Weiße gelöst.

Unterprogramm1 Target_25700,nSpeed,tPistoleDummy,nBreite;

Habe für meine Targetpunkte ein kleines Unterprogramm gebastelt Rot markiert der Aufruf des Programmes und blau markiert die Infos, die das Unterprogramm benötigt.

PROC

Unterprogramm1 (robtarget pTargetpunkt, num nSpeed, tooldata Werkzeug, num nBreite)

tPistoleDummy:=Werkzeug;

vflex.v_tcp:=nSpeed;

MoveL Offs(pTargetpunkt,0,-nBreite-30,0),vFlex,z0,tPistoleDummy\WObj:=wTischMitBohrungen;

MoveL Offs(pTargetpunkt,0,-nBreite-25,0),v50,z50,tPistoleDummy\WObj:=wTischMitBohrungen;

MoveL Offs(pTargetpunkt,0,-nBreite-20,0),v200,z50,tPistoleDummy\WObj:=wTischMitBohrungen;

MoveL Offs(pTargetpunkt,0,-nBreite-15,0),v300,z50,tPistoleDummy\WObj:=wTischMitBohrungen;

MoveL Offs(pTargetpunkt,0,15,0),vFlex,z0,tPistoleDummy\WObj:=wTischMitBohrungen;

MoveL Offs(pTargetpunkt,0,20,0),v300,z50,tPistoleDummy\WObj:=wTischMitBohrungen;

MoveL Offs(pTargetpunkt,0,25,0),v100,z50,tPistoleDummy\WObj:=wTischMitBohrungen;

MoveL Offs(pTargetpunkt,0,30,0),v50,z50,tPistoleDummy\WObj:=wTischMitBohrungen;

ENDPROC

Ich musste es zwar bei allen Punkten ändern aber dafür gibt es ja die Funktion "Suchen/Ersetzen"

Target-Punkte eines Pfades verschieben

Zum Hilfreichsten Beitrag springen

Erstelle ein Benutzerkonto oder melde dich an um zu kommentieren

Gebrauchtroboter kaufen - Was ist zu beachten. Die Checkliste zum kauf von gebrauchten Robotern

Was macht ein Roboterprogrammierer genau und was verdient er?

Vernetzen, referenzieren, kollaborieren: Das B2B Portal für die Produktionsautomatisierung

Sie wollen Ihr Stellenangebot im Roboterforum schalten? Ab 149€

Werde Roboterprogrammierer bei ROBTEC GmbH in Mainburg / Bayern

Teilen

Wieviele Mitglieder waren heute eingeloggt?