Schrauben-/Helixbewegung

Suche nutzen:
https://www.roboterforum.de/ro…gung-programmieren/13456/

Circ ist nur auf den ersten Blick naheliegend, bei genauerer Betrachtung aber Humbug, da Kreise immer schlechter in die "Röhre" passen, je größer die Steigung ist. Freilich ergibt sich durch die Auflösung in Teilstrecken oder Kreissegmente eine beliebig gute Annäherung, lenkt aber vom eigentlichen Thema ab: dass man die Schraube selbst berechnen muss. LIN mit entsprechenden Überschleifparametern tut es dann vielleicht auch, wenn nicht sogar besser. Kommt drauf an, was man machen will, für's Fräsen liegt die Latte sicher etwas höher, und bei großen Durchmessern sind mehr Stützpunkte vielleicht auch eine gute Idee..

Ich hab für einen "ich-zentrier-dich-beim-Reinfahren"-Fall folgende Routine in Verwendung, deren Drehrichtung, Auflösung (12) und natürlich Ebene (BASE-z ist Stoßrichtung, also minus ist runter) hart codiert sind, deren Bewegungseinstellungen modal aus der Vorgeschichte übernommen werden und die als Start immer die aktuelle Istposition (als Zentrum) benutzt (kann man natürlich alles auch generalisieren). Funktionierte stets flüssig und brauchbar:

GLOBAL DEF spiraleXYY(radius:in, tiefe: in, windungen : in)
decl real radius, schrittweite, tiefe
DECL frame hfmitte,startpos
DECL INT windungen,i,w
DECL FRAME ziele[12]


if (windungen < 1) then
  return
endif


wait sec 0
hfmitte=$POS_ACT
startpos=hfmitte
schrittweite=tiefe/windungen


  for w = 1 to windungen 
    for i = 1 to 12 
      ziele[i]=hfmitte
      ziele[i].z=hfmitte.z+((schrittweite / 12)*i)
      ziele[i].x=hfmitte.x+(sin((360/12)*i)*radius)
      ziele[i].y=hfmitte.y+(cos((360/12)*i)*radius)
    endfor
    lin ziele[1] C_DIS
    lin ziele[2] C_DIS
    lin ziele[3] C_DIS
    lin ziele[4] C_DIS
    lin ziele[5] C_DIS
    lin ziele[6] C_DIS
    lin ziele[7] C_DIS
    lin ziele[8] C_DIS
    lin ziele[9] C_DIS
    lin ziele[10] C_DIS
    lin ziele[11] C_DIS
    lin ziele[12] C_DIS
    hfmitte.z=startpos.z+schrittweite*w
  ENDFOR
  hfmitte.z=startpos.z+schrittweite*(w-1)
  lin hfmitte C_DIS

END

Der programmiertechnische "Luxus", die Punkte innerhalb einer Umdrehung hintereinander auszuschreiben, statt sie ihrerseits wieder in eine Schleife zu fassen, dient einerseits der Vorlaufberechnung und andererseits der Visualisierung.

Grüße,
Michael