Überschleifen nicht möglich SPTP

Fuchsa · 25. Januar 2017

Hallo Leute,

zur mir kurz:
ich bin in den Genuss gekommen eine Automatisierung mit einem KR6 R900 sixx KRC4 smallsize zu Programmieren. Bis jetzt habe ich bei uns nur Programme ändern, oder Nachteachen dürfen. Dies ist mein erstes Projekt mit einer kompletten Neuprogrammierung des Kukas und so gibt es leider auch die ein oder anderen Problemchen. Bis jetzt konnte ich mich ganz gut hier in der großen Auswahl der Problemsituationen bedienen und habe auch schon viele Probleme lösen können. Jetzt komme ich leider nicht weiter.

Zum Problem:
Ich habe ein Hauptprogramm, von dem ich meine Unterprogramme aufrufe. (meist über if Anweisungen) Der Programmablauf funktioniert soweit ohne Probleme, allerdings gibt es oft Probleme beim Verschleifen von Fahrbewegungen.
Wenn ich z.B. in das Programm Teil_links_ablegen_1570 springe:

[size=3]Hier bleibt der Roboter kurz vor dem Erreichen der Endposition stehen (könnte die Entfernung der eingegeben Überschleifdistanz sein) und sagt mir,[/size][size=3][size=3] dass die Position SPTP frei_Ablage_klt nicht überschliffen werden kann. [/size]Fehlermeldung: Überschleifen nicht möglich (Modul Teil_links_ablegen_1570, Satz 101 (=> 1442)
[/size]

Code

CONTINUE
 INTERRUPT ON 10
 
 ;FOLD SPTP frei_Ablage_klt CONT Vel=80 % PDAT1 Tool[2]:1570/1571/1794 Base[3]:KLT_links;%{PE}%R 8.3.40,%MKUKATPBASIS,%CSPLINE,%VSPTP_SB,%P 1:SPTP_SB, 2:frei_Ablage_klt, 3:C_DIS, 5:80, 7:PDAT1
 SPTP Xfrei_Ablage_klt WITH $VEL_AXIS[1]= SVEL_JOINT( 80), $TOOL= STOOL2( Ffrei_Ablage_klt), $BASE= SBASE( Ffrei_Ablage_klt.BASE_NO),$IPO_MODE= SIPO_MODE( Ffrei_Ablage_klt.IPO_FRAME), $LOAD= SLOAD( Ffrei_Ablage_klt.TOOL_NO), $ACC_AXIS[1]= SACC_JOINT( PPDAT1), $APO= SAPO_PTP( PPDAT1), $GEAR_JERK[1]= SGEAR_JERK( PPDAT1) C_SPL
 ;ENDFOLD
 CONTINUE
 SWITCH Verpackung
 
    CASE #KLT
    CONTINUE
    KLT()
 
    CASE #Karton
    CONTINUE
    ; Karton() ;Noch nicht fertig!
    HALT

    CASE #KEINE
 
    ;Fold Quittiermeldung kein Verpackungstyp von SPS gewählt
    VP_NIO={modul[] "KUKA_SGM90", NR 1010, msg_txt[] "Kein Verpackungstyp von SPS"}
    Option= {VL_STOP TRUE, Clear_P_Reset TRUE, Clear_P_SAW FALSE, Log_to_DB TRUE}
    Parameter[1] = {Par_Type #EMPTY}
    Parameter[2] = {Par_Type #EMPTY}
    Parameter[3] = {Par_Type #EMPTY}
    handle = SET_KRLMSG(#QUIT, VP_NIO, Parameter [] , Option)

    REPEAT
    present = EXISTS_KRLMSG(handle)
    UNTIL NOT (present)
    ;ENDFOLD
       Halt

    DEFAULT
 
    ;Fold Quittiermeldung kein Verpackungstyp von SPS gewählt
    VP_NIO={modul[] "KUKA_SGM90", NR 1010, msg_txt[] "Fehler Verpackungstyp von SPS"}
    Option= {VL_STOP TRUE, Clear_P_Reset TRUE, Clear_P_SAW FALSE, Log_to_DB TRUE}
    Parameter[1] = {Par_Type #EMPTY}
    Parameter[2] = {Par_Type #EMPTY}
    Parameter[3] = {Par_Type #EMPTY}
    handle = SET_KRLMSG(#QUIT, VP_NIO, Parameter [] , Option)

    REPEAT
    present = EXISTS_KRLMSG(handle)
    UNTIL NOT (present)
    ;ENDFOLD
       Halt
 
 ENDSWITCH

Alles anzeigen

Hat hier jemand ne Idee woran es liegen könnte?
Ich bin um jede Hilfe dankbar. =)

MfG,
Fuchsa

fubini · 26. Januar 2017

Hallo Fuchsa,

Da ist wohl irgendwo eine nicht überschleiffähige Anweisung versteckt. Versuch mal $STOPNOAPROX auf TRUE zu setzen. Dann bleibt der Roboter wenn nicht überschliffen werden kann an der Stelle stehen.

Ferner einfach hier und/oder im englischen Partnerforum die Suche mit "STOPNOAPROX" bemühen, da findest du auch einige Erklärungen.

Fubini

Fuchsa · 27. Januar 2017

Hallo Fubini,

danke für den Hinweis. Das habe ich durchgeführt und hierbei bleibt er eben genau bei:

Code

;FOLD SPTP frei_Ablage_klt CONT Vel=80 % PDAT1 Tool[2]:1570/1571/1794 Base[3]:KLT_links;%{PE}%R 8.3.40,%MKUKATPBASIS,%CSPLINE,%VSPTP_SB,%P 1:SPTP_SB, 2:frei_Ablage_klt, 3:C_DIS, 5:80, 7:PDAT1
 SPTP Xfrei_Ablage_klt WITH $VEL_AXIS[1]= SVEL_JOINT( 80), $TOOL= STOOL2( Ffrei_Ablage_klt), $BASE= SBASE( Ffrei_Ablage_klt.BASE_NO),$IPO_MODE= SIPO_MODE( Ffrei_Ablage_klt.IPO_FRAME), $LOAD= SLOAD( Ffrei_Ablage_klt.TOOL_NO), $ACC_AXIS[1]= SACC_JOINT( PPDAT1), $APO= SAPO_PTP( PPDAT1), $GEAR_JERK[1]= SGEAR_JERK( PPDAT1) C_SPL
 ;ENDFOLD

stehen.
Ich kann es nicht nachvollziehen, da die Bewegung ja mit CONT programmiert wurde.

MfG, Fuchsa

ASK_ROBOTER · 27. Januar 2017

Hi,
welchen Wert hat Verpackung? Geht es mit KLT() weiter? Vielleicht ist da irgendwo ein Vorlaufstop?

Toud · 27. Januar 2017

Servus,
mich würd intressieren was am Anfang im Unterprogramm KLT() passiert.

Code

CASE #KLT
    CONTINUE
    KLT()

beim Switch steht auch #KLT schon 3 bewegungen vor erreichen an? (Wegen $Advance und so)
Dann ist noch zu beachten, das im Unterprogramm was du aufrufst, auch S-Bewegungen her nimmst.
wenn du ein wechsel drinn hast von z.B SPTP zu PTP, bleibt der Robi auch kurz stehen.

Gru?,
Toud

Fuchsa · 27. Januar 2017

Hallo,
danke schonmal für die vielen Antworten.
Der Wert Verpackung steht auf #KLT. #Karton gibt es noch nicht.(Ist aber vom Ablauf identisch nur etwas verschobene Ablagepositionen.)
Hier das Programm #KLT:

Code

DEF KLT ()


CONTINUE
$VEL.CP = 1.5
CONTINUE
PTP vpos_KLT_L[Lage_L, Spalte_L, Reihe_L] c_ptp c_dis
TRIGGER WHEN PATH=0 ONSTART DELAY=0 DO Posnr_akt = 320




$VEL.CP = 0.2
SLIN apos_KLT_L[Lage_L, Spalte_L, Reihe_L]
TRIGGER WHEN PATH=-30 ONSTART DELAY=0 DO Posnr_akt = 330


;FOLD Ablegen
INTERRUPT OFF 10
wait sec 0.1
o_Vak1_ein = FALSE
o_Vak1_aus = TRUE
WAIT FOR NOT i_Vakuum_ok
Wait sec 0.2
o_Teil_angesaugt = FALSE
Teil_bereit.Seite = #KEINE
;ENDFOLD


$VEL.CP = 1.8
SLIN vpos_KLT_L[Lage_L, Spalte_L, Reihe_L] c_dis
TRIGGER WHEN PATH=0 ONSTART DELAY=0 DO Posnr_akt = 320


CONTINUE
END

Alles anzeigen

Toud: Wenn ich aus PTP vpos_KLT_L[Lage_L, Spalte_L, Reihe_L] c_ptp c_dis

SPTP vpos_KLT_L[Lage_L, Spalte_L, Reihe_L] c_ptp c_dis mach sollte es funktionieren? Das muss ich gleich mal testen.

Danke und Gruß,
Fuchsa

fubini · 27. Januar 2017

Hallo,

also du versuchst z.B. schon mal einen PTP in einen SLIN zu Überschleifen. Das geht sicher nicht und wird auch mit einem "Überschleifen nicht möglich" bestraft. Versuch doch einfach statt dem PTP einen SPTP.
Übrigens die ganzen CONTINUE (z.B. vor $VEL.CP und den Bewegungen) kannst du dir auch sparen. Das sind immer Anweisungen an den Vorlauf und auch nicht Vorlaufstoppend.

Fubini

d4nuu8 · 27. Januar 2017

Selbst beim Übergang von SPTP zu SLIN kann es zu kleinen Stopps kommen, auch wenn das nicht sollte. Soll wohl mit einer der nächsten KSS Versionen behoben werden.

fubini · 30. Januar 2017

Zitat

Selbst beim Übergang von SPTP zu SLIN kann es zu kleinen Stopps kommen, auch wenn das nicht sollte. Soll wohl mit einer der nächsten KSS Versionen behoben werden.

Weist du da näheres dazu. In welchen Konstellationen? Ab welcher SW-Version soll da eine Behebung passieren.
Danke,
Fubini

Fuchsa · 31. Januar 2017

Hallo und Danke schon für die Antworten.

Ich habe die Bewegung jetzt in SPTP geändert und siehe da, es funktioniert!
Die vielen CONTINUE waren mehr ein Verzweiflungsakt.

MfG,
Fuchsa

d4nuu8 · 1. Februar 2017

Zitat von fubini

Weist du da näheres dazu. In welchen Konstellationen? Ab welcher SW-Version soll da eine Behebung passieren.
Danke,
Fubini

Müsste das letzte Mal bei KSS 8.3.27 getestet worden sein.

Überschleifen nicht möglich SPTP

Erstelle ein Benutzerkonto oder melde dich an um zu kommentieren

Gebrauchtroboter kaufen - Was ist zu beachten. Die Checkliste zum kauf von gebrauchten Robotern

Was macht ein Roboterprogrammierer genau und was verdient er?

Vernetzen, referenzieren, kollaborieren: Das B2B Portal für die Produktionsautomatisierung

Sie wollen Ihr Stellenangebot im Roboterforum schalten? Ab 149€

Werde Roboterprogrammierer bei ROBTEC GmbH in Mainburg / Bayern

Teilen

Tags

Wieviele Mitglieder waren heute eingeloggt?