Vorposition über Greifposition berechnen

cando_o · 10. November 2012

Guten Abend!
Ich habe gerade ein Problem, dass mich fast in den Wahnsinn treibt .

Ablauf der funktioniert:
- Eine Werkstückbasis (Base[4]) wird bei jedem Robotertakt über den Geometrischen Operator neu berechnet (Kamerasystem).
- In dieser Base sind eine Vorposition und eine Nachposition fest geteacht.
- Bei jedem Robotertakt ändert sich die Werkstückbasis und somit auch die geteachten Punkte.
- Der Roboter kann das Werkstück greifen.

Da ich das Werkstück je nach Orientierung mit 0 bzw. 180 Grad aufnehmen muss, gibt es diesen Ablauf 2 mal.

Mein Problem ist, dass ich nur noch Greifposition teachen und die anderen in abhängigkeit von der Greifpos berechnen möchte.
(20 unterschiedliche Werkstücke mal oben genannten Ablauf = 80 Punkte zu teachen bei Inbetriebnahme => Mein Grund)

Wie kann ich also eine Greifposition, die aufgrund des Kamerasysstems in E6POS geteacht ist, mit 0 oder 180 Grad genau anfahren und eine Vorposition und Nachposition
in Abhängigkeit dieser berechnen?

Mein Versuch:

Code

;in der .dat-File
DECL INT err_status
DECL E6AXIS GREIFEN={XYZABC.fest geteacht.}
DECL E6POS Greifen2
DECL FRAME Vorpos
DECL FRAME Nachpos
-----------------------------
in der .src file


goto xy
PTP Greifen ....                      ;muss getetacht werden
xy:


$BASE=BASE_DATA[14]
$TOOL=TOOL_DATA[2]


if (Teil_0Grd==TRUE) then


PTP P1_Grundpos C_PTP           ;Ausgangsposition
P1_Grundpos.A6 = 0
Greifen.A6 = 0                         ;Greifen mit 0 Grad


else


PTP P1_Grundpos C_PTP
P1_Grundpos.A6 = 180
Greifen.A6 = 180                      ;Greifen mit 180 Grad


endif




Greifen2 = Forward(Greifen, err_status)  ;E6POS zu E6AXIS machen
if (err_status==0) THEN               


Vorpos = Greifen2                                  ;Vorpos berechnen
Vorpos.x = Greifen2.x - 100
LIN Vorpos                                             ;Vorpos anfahren


LIN Greifen2                                           ;Greifpos2 mit A6 = 0 oder 180 Grad anfahren


WerkzeugZu ()


;Nachpos berechnen ....


else
LOOP
;Fehler
ENDLOOP

Alles anzeigen

Die Rechnerrei funktioniert soweit, aber im 2 Roboterzyklus wird der selbe Greifpunkt angefahren,
obwohl die Basis [4] (Werkstück) verschoben wurde.

Oder gibt es eine einfachere Möglichkeit???
Problem ist halt, dass Greifpos als E6POS geteacht ist und diese mit 0 oder 180 Grad angefahren werden muss.

Danke schon mal!

WolfHenk · 10. November 2012

Achspositionen sind nicht von Tool oder Base Abhängig. Da wird NUR die geforderte Achsstellung erreicht. Fertig.

Dein Freund ist der Inhalt von T in der E6Pos: Bit 5 stellt die Stellung der sechsten Achse dar.
A6>=0 wird Bit5 auf 0 setzen, A6<0 ergibt dort ne 1.

Es hilft, diese Variable binär darzustellen:

Ich hab sowas mal so gemacht:

Code

IF DI_rechtsrum == true THEN
  ;rechtsrum
  ;konfigbits Erste Achse rechtsschreiben

  P040100.t = 'B111110' B_AND P040100.t
  P040150.t = 'B111110' B_AND P040150.t
  P040151.t = 'B111110' B_AND P040151.t
  P040152.t = 'B111110' B_AND P040152.t
  P040153.t = 'B111110' B_AND P040153.t
  P040154.t = 'B111110' B_AND P040154.t
  P040155.t = 'B111110' B_AND P040155.t
  P040156.t = 'B111110' B_AND P040156.t
  P040157.t = 'B111110' B_AND P040157.t
  P040158.t = 'B111110' B_AND P040158.t
  P040159.t = 'B111110' B_AND P040159.t
  P040169.t = 'B111110' B_AND P040169.t 
  P040161.t = 'B111110' B_AND P040161.t
 
ENDIF
IF DI_linksrum THEN
  ;linksrum
  ;konfigbits Erste Achse linksschreiben
  P040100.t = 1 B_OR P040100.t      
  P040150.t = 1 B_OR P040150.t
  P040151.t = 1 B_OR P040151.t
  P040152.t = 1 B_OR P040152.t
  P040153.t = 1 B_OR P040153.t
  P040154.t = 1 B_OR P040154.t
  P040155.t = 1 B_OR P040155.t
  P040156.t = 1 B_OR P040156.t
  P040157.t = 1 B_OR P040157.t
  P040158.t = 1 B_OR P040158.t
  P040159.t = 1 B_OR P040159.t
  P040169.t = 1 B_OR P040169.t
  P040161.t = 1 B_OR P040161.t
ENDIF

Alles anzeigen

Hier wird Bit 1 jeweils IMMER auf 0 oder 1 geschoben. Das ging halt auf die erste Achse

Bei Dir wärs
XP1.t = 'B011111' B_AND XP1.t um die sechste Achse immer auf ne Zahl >=0° zu fahren und
XP1.t = 'B100000' B_OR XP1.t um sie immer auf eine negative Gradzahl zu fahren.
Musst möglicherweise Deinen Greifer anders montieren.

ALLES OHNE GEWÄHR

WH

Hermann · 11. November 2012

WolfHenk hat auf alle Fälle schon mal Recht: ein mit E6AXIS geteachter Punkt ist im Raum gesehen immer der selbe, da kann man hin und herrechnen wie man will.

Keine Ahnung warum der geteachte Punkt als E6AXIS deklariert ist, das wird so nie funktionieren.
Wenn eine Kamera im Spiel ist, dann darf man Punkte, die sich auf die Kameraergebnisse beziehen nur als FRAME, POS oder E6POS verwenden.
hier mal ein Konzept, wie ich das lösen würde:

Code

;in der .dat-File
DECL INT err_status
DECL POS GREIFEN = {X 0, Y 0, Z 0, A 0, B 0, C 0 , S 0, T 0}   ; die Nullen hier nur vor dem Teach-In
DECL POS GREFPOS
DECL Pos Vorpos
DECL Pos Nachpos
-----------------------------
in der .src file


goto xy
 $BASE=BASE_DATA[14]    ; Was wird jetzt verschoben ?? [4] (wie im Text) oder [14] (wie hier im code) 
 $TOOL=TOOL_DATA[2] 
 PTP Greifen ....                      ;muss getetacht werden
xy:


$BASE=BASE_DATA[14]    ; Was wird jetzt verschoben ?? [4] (wie im Text) oder [14] (wie hier im code)
$TOOL=TOOL_DATA[2]


GREIFPOS = GREIFEN
if (Teil_0Grd==FALSE) then
 GREIFPOS=GREIFPOS:{X 0, Y 0, Z 0, A 180, B 0, C 0}   ; Drehung um 180 Grad
endif


VORPOS = {X 100, Y 0, Z 0, A 0, B 0, C 0}:GREIFPOS
NACHPOS = {X 0, Y 0, Z 100, A 0, B 0, C 0} : GREIFPOS


PTP  GRUNDPOS 
LIN Vorpos                                             ;Vorpos anfahren
LIN Greifpos
WerkzeugZu ()
LIN NACHPOS

Alles anzeigen

Aber Achtung: Wenn GRUNDPOS genau 180 Grad zu einer der Greifpositionen steht, dann fährt der Roboter mit ziemlicher Wahrscheinlichkeit eine sehr seltsame Bewegung auf dem Weg zur Vorpos. In dem Fall entweder aus LIN Vorpos ein PTP Vorpos machen, oder die GRUNDPOS etwas verdrehen. (Diesen seltsamen Bahnverlauf bei 180-Grad Drehungen beim Linearfahren halte ich für einen eklatanten Fehler in der Bahnplanung seitens KUKA, der aber scheinbar niemanden interessiert, denn den gibt's schon immer).

Das ganze kann überhaupt nur funktionieren, wenn der Greifer symmetrisch ist und das Tool auch genau symmetrisch eingerichtet ist (würde auch für die Version mit E6AXIS.A6 + 180 gelten). Mir ist nicht ganz klar, warum das Base über die Kamera verschoben wird, und nicht gleich der Greifpunkt komplett mit Winkel ermittelt wird

cando_o · 11. November 2012

Guten Abend!

Tool und Werkstück sind symetrisch. Und das mit der Berechnung mit der ständigen verschiebung der Base wurde so von einem KUKA-Programmierer gelöst.

(Greifpos war ursprünglich eine E6POS habe, habe mir aber gedacht ich kann daraus eine AXIS machen, A6 auf 0 oder 180 Grad rechnen und die Vorpos durch den Forwardbefehl
über die dann erhaltene E6 Greif POS berechnen.

Aber... Dann werde ich morgen den unten stehenden Code probieren.

Code

goto xy
 $BASE=BASE_DATA[14]    ;14 wird verschoben ;)
 $TOOL=TOOL_DATA[2] 
 PTP Greifen ....                 ;Greifpos wird wie vorher von mir geteacht ?
xy:


$BASE=BASE_DATA[14]    
$TOOL=TOOL_DATA[2]


GREIFPOS = GREIFEN     


if (Teil_0Grd==FALSE) then
 GREIFPOS=GREIFPOS:{X 0, Y 0, Z 0, A 180, B 0, C 0}   ; Drehung um 180 Grad
endif


;Und hier wird Greifpos fest X = 100 zugewiesen??
;(Da das mit dem Doppelpunkt mir nichts sagt und ich das mit der Rechnung Vorpos = Greifpos ------> Vorpos.x = 100 gemacht hätte)
;Das da unten sieht aber schöner aus


VORPOS = {X 100, Y 0, Z 0, A 0, B 0, C 0} : GREIFPOS
NACHPOS = {X 0, Y 0, Z 100, A 0, B 0, C 0} : GREIFPOS


PTP GRUNDPOS C_PTP
LIN Vorpos C_LIN                                             
LIN Greifpos


WerkzeugZu ()


LIN NACHPOS C_LIN

Alles anzeigen

Und noch was:

Was haltet Ihr von dem Befehl?

lin $pos_act: {x 0,y 0,z 190,a 0,b 0,c 0} c_dis

Bei Programm-Abbruch und Wiedereinstieg werden, doch die 190 wieder von vorne begonnen, obwohl (sagen wir mal) 50 schon gefahren wurden?

Danke schon mal!

Vorposition über Greifposition berechnen

Erstelle ein Benutzerkonto oder melde dich an um zu kommentieren

Gebrauchtroboter kaufen - Was ist zu beachten. Die Checkliste zum kauf von gebrauchten Robotern

Was macht ein Roboterprogrammierer genau und was verdient er?

Vernetzen, referenzieren, kollaborieren: Das B2B Portal für die Produktionsautomatisierung

Sie wollen Ihr Stellenangebot im Roboterforum schalten? Ab 149€

Werde Roboterprogrammierer bei ROBTEC GmbH in Mainburg / Bayern

Teilen

Wieviele Mitglieder waren heute eingeloggt?