Programmänderungen bei mehreren Programmen

Dodo · 21. Februar 2006

Hallo,
hab mal wieder eine Frage:

Hab bei einem Kunden mehrere Handlings-Roboter stehen.
Die Roboter nehmen Teile von einem Band und legen es in die Maschine ein, bzw. umgekehrt.
Auf jeder Anlage laufen verschiedene Bauteile. Für jedes Bauteil haben wir ein Programm, da die Positionen sich immer etwas unterscheiden. Ein Cell Programm verwaltet die Programmauswahl.
Soweit also Standard :angel:

Nun hat aber der Kunde dauernd Änderungswünsche
so dass sich die Programme öfter mal verändern.
Dann müssen alle Typprogramme "angefasst" werden

Ich würde daher die Typverwaltung gerne anders machen.
Also nur ein Programm und die Positionen anders verwalten.
Hat jemand eine Idee, wie man das machen kann?
Ideen von uns waren u.a
- Positions-Arrays mit Index (geht nicht, weil im Inlineformular nicht eingebbar)
- Umkopieren der Dat-Files (keine Ahnung, wie das gehen könnte)

Hat jemand eine Idee, wie sich das sonst realisieren lässt?

rob · 21. Februar 2006

ich seh da zwei möglichkeiten:

- für jedes teil separate teachpunkte, die im programm übersprungen werden. nur der auserwählte wird per switch einem frame zugewiesen. von diesem punkt aus dann die "vor"-positionen berechnen.

- eine tabelle die die werte beinhaltet, welche sich von typ zu typ ändern. wenn nur die länge anders ist, reicht das zett. auch das wird auf den typ geswitcht.

der typ kann per dialog beim programmstart festgelegt werden.

zu knapp? :angel:

naja. wenn das programm immer das gleiche macht, find ich es wirklich umständlich, nicht standard, für jeden typ, nur wegen der unterschiedlichen geometrie, ein eigenes zu hinterlegen...

gruss, rob

Dodo · 21. Februar 2006

Zitat von rob

wenn das programm immer das gleiche macht, find ich es wirklich umständlich, nicht standard, für jeden typ, nur wegen der unterschiedlichen geometrie, ein eigenes zu hinterlegen...

Hmmm, haben mir nette Leute in Augsburg so beigebracht!

mal ne blöde Frage. Was verstehst Du in diesem Kontext unter einem "Frame" ?

Das mit dem Überspringen hört sich ganz gut an. Das könnte man entsprechend "falten".

rob · 21. Februar 2006

ein frame ist eine position ohne status und turn. also nur { x y z a b c }.
man könnte auch sagen ein punkt im raum mit ausrichtung.
ich mach ein kleines beispiel. brauch aber etwa ne halbe stunde...

rob · 21. Februar 2006

also. so könnte das mit inline teachpunkten aussehen. das dat ist unübersichtlich wie immer. ich hab's trotzdem dazugetan. bei einem 5.2er sollte das laufen, wenn du das INI mit deinem ersetzt (wegen der techpacks) (erst teachen ;))

das src:

Code

&ACCESS RV
&REL 1
&PARAM TEMPLATE = C:\KRC\Roboter\Template\vorgabe
&PARAM EDITMASK = *
DEF beispiel( )


;_____variablen____________________


INT typ


FRAME fliessband
FRAME maschine


FRAME vor_fliessband
FRAME vor_maschine


;FOLD INI
  ;FOLD BASISTECH INI
    GLOBAL INTERRUPT DECL 3 WHEN $STOPMESS==TRUE DO IR_STOPM ( )
    INTERRUPT ON 3 
    BAS (#INITMOV,0 )
  ;ENDFOLD (BASISTECH INI)
;FOLD SPOTTECH INI
USERSPOT(#INIT)
;ENDFOLD (SPOTTECH INI)
;FOLD GRIPPERTECH INI
USER_GRP(0,DUMMY,DUMMY,GDEFAULT)
;ENDFOLD (GRIPPERTECH INI)
  ;FOLD USER INI
    ;Make your modifications here


  ;ENDFOLD (USER INI)
;ENDFOLD (INI)


;FOLD PTP HOME  Vel= 100 % DEFAULT;%{PE}%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:HOME, 3:, 5:100, 7:DEFAULT
$BWDSTART = FALSE
PDAT_ACT=PDEFAULT
FDAT_ACT=FHOME
BAS (#PTP_PARAMS,100 )
$H_POS=XHOME
PTP  XHOME
;ENDFOLD


;_____typ festlegen________________
typ = 1 ; ( besser noch: dialog / ENUM )


;_____die teachpunkte______________
GOTO TEACHPKT


;FOLD PTP FLIESSBAND_1  Vel= 100 % PDAT1 Tool[0] Base[0];%{PE}%R 5.2.26,%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:FLIESSBAND_1, 3:, 5:100, 7:PDAT1
$BWDSTART = FALSE
PDAT_ACT=PPDAT1
FDAT_ACT=FFLIESSBAND_1
BAS(#PTP_PARAMS,100)
PTP XFLIESSBAND_1 
;ENDFOLD
;FOLD PTP FLIESSBAND_2  Vel= 100 % PDAT2 Tool[0] Base[0];%{PE}%R 5.2.26,%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:FLIESSBAND_2, 3:, 5:100, 7:PDAT2
$BWDSTART = FALSE
PDAT_ACT=PPDAT2
FDAT_ACT=FFLIESSBAND_2
BAS(#PTP_PARAMS,100)
PTP XFLIESSBAND_2 
;ENDFOLD


;FOLD PTP MASCHINE_1  Vel= 100 % PDAT3 Tool[0] Base[0];%{PE}%R 5.2.26,%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:MASCHINE_1, 3:, 5:100, 7:PDAT3
$BWDSTART = FALSE
PDAT_ACT=PPDAT3
FDAT_ACT=FMASCHINE_1
BAS(#PTP_PARAMS,100)
PTP XMASCHINE_1 
;ENDFOLD
;FOLD PTP MASCHINE_2  Vel= 100 % PDAT4 Tool[0] Base[0];%{PE}%R 5.2.26,%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:MASCHINE_2, 3:, 5:100, 7:PDAT4
$BWDSTART = FALSE
PDAT_ACT=PPDAT4
FDAT_ACT=FMASCHINE_2
BAS(#PTP_PARAMS,100)
PTP XMASCHINE_2 
;ENDFOLD


TEACHPKT:


;_____punkte zuweisen______________
SWITCH typ


CASE 1
  fliessband = XFLIESSBAND_1 ; das "X" jeweils ist wichtig
  maschine   = XMASCHINE_1
CASE 2
  fliessband = XFLIESSBAND_2
  maschine   = XMASCHINE_2
ENDSWITCH


;_____berechnungen_________________
vor_fliessband = fliessband
vor_fliessband.z = vor_fliessband.z - 100.0


vor_maschine = maschine
vor_maschine.z = vor_maschine.z - 100.0


;_____ablauf_______________________
LOOP


$TOOL = TOOL_DATA[0] ; den teachpunkten entsprechend (!)
$BASE = BASE_DATA[0] ; auch hier...


PTP vor_fliessband
LIN fliessband
; greifer schliessen
LIN vor_fliessband


; tool/base eventuell setzten...
PTP vor_maschine
LIN maschine
; greifer oeffnen
LIN vor_maschine


ENDLOOP


;FOLD PTP HOME  Vel= 100 % DEFAULT;%{PE}%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:HOME, 3:, 5:100, 7:DEFAULT
$BWDSTART = FALSE
PDAT_ACT=PDEFAULT
FDAT_ACT=FHOME
BAS (#PTP_PARAMS,100 )
$H_POS=XHOME
PTP  XHOME
;ENDFOLD


END

Alles anzeigen

...und das dat:

Code

&ACCESS RV
&REL 1
&PARAM TEMPLATE = C:\KRC\Roboter\Template\vorgabe
&PARAM EDITMASK = *
DEFDAT  BEISPIEL
;FOLD EXTERNAL DECLARATIONS;%{PE}%MKUKATPBASIS,%CEXT,%VCOMMON,%P
;FOLD GRIPPERTECH EXT
EXT  H50 (INT  :IN,INT  :IN,INT  :IN,GRP_TYP  :IN )
;ENDFOLD (GRIPPERTECH EXT)
;FOLD SPOTTECH EXT
EXT  USERSPOT (S_COMMAND  :IN,SPOT_TYPE  :IN )
;ENDFOLD (SPOTTECH EXT)
;FOLD BASISTECH EXT;%{PE}%MKUKATPBASIS,%CEXT,%VEXT,%P
EXT  BAS (BAS_COMMAND  :IN,REAL  :IN )
DECL INT SUCCESS
;ENDFOLD (BASISTECH EXT)
;FOLD USER EXT;%{E}%MKUKATPUSER,%CEXT,%VEXT,%P
;Make here your modifications


;ENDFOLD (USER EXT)
;ENDFOLD (EXTERNAL DECLERATIONS)
DECL BASIS_SUGG_T LAST_BASIS={POINT1[] "MASCHINE_2              ",POINT2[] "MASCHINE_2              ",CP_PARAMS[] "CPDAT0                  ",PTP_PARAMS[] "PDAT4                   ",CONT[] "                        ",CP_VEL[] "2.0                     ",PTP_VEL[] "100                     "}
DECL E6POS XFLIESSBAND_1={x 823.565308,y 6.46427424E-14,z 1360.85498,a -180.0,b 45.0000496,c -180.0,s 2,t 3,e1 0.0,e2 0.0,e3 0.0,e4 0.0,e5 0.0,e6 0.0}
DECL FDAT FFLIESSBAND_1={TOOL_NO 0,BASE_NO 0,IPO_FRAME #BASE,POINT2[] " "}
DECL PDAT PPDAT1={VEL 100.0,ACC 100.0,APO_DIST 100.0}
DECL E6POS XFLIESSBAND_2={x 823.565308,y 6.46427424E-14,z 1360.85498,a -180.0,b 45.0000496,c -180.0,s 2,t 3,e1 0.0,e2 0.0,e3 0.0,e4 0.0,e5 0.0,e6 0.0}
DECL FDAT FFLIESSBAND_2={TOOL_NO 0,BASE_NO 0,IPO_FRAME #BASE,POINT2[] " "}
DECL PDAT PPDAT2={VEL 100.0,ACC 100.0,APO_DIST 100.0}
DECL E6POS XMASCHINE_1={x 823.565308,y 6.46427424E-14,z 1360.85498,a -180.0,b 45.0000496,c -180.0,s 2,t 3,e1 0.0,e2 0.0,e3 0.0,e4 0.0,e5 0.0,e6 0.0}
DECL FDAT FMASCHINE_1={TOOL_NO 0,BASE_NO 0,IPO_FRAME #BASE,POINT2[] " "}
DECL PDAT PPDAT3={VEL 100.0,ACC 100.0,APO_DIST 100.0}
DECL E6POS XMASCHINE_2={x 823.565308,y 6.46427424E-14,z 1360.85498,a -180.0,b 45.0000496,c -180.0,s 2,t 3,e1 0.0,e2 0.0,e3 0.0,e4 0.0,e5 0.0,e6 0.0}
DECL FDAT FMASCHINE_2={TOOL_NO 0,BASE_NO 0,IPO_FRAME #BASE,POINT2[] " "}
DECL PDAT PPDAT4={VEL 100.0,ACC 100.0,APO_DIST 100.0}
ENDDAT

Alles anzeigen

ich verwend normal keine inline formulare. dann lässt sich das auch mit nem normalen editor anschauen... sonst kannst du den roboter verwenden, oder den von KUKA schweisstechnik(freeware): http://www.roboterforum.de/rob…um/index.php?topic=1455.0

ich muss jetzt nochmal in die halle und kann erst am abend wieder reinschauen...

SyncMa · 22. Februar 2006

Hallo.

Ich möchte mal meine Vorgehensweise darlegen, wenn ich eine Bearbeitungszelle mit mehreren Typen zu programmieren habe.
Ich lege für jedes Teil Datensätze in der config.dat an (arrays) die die erforderlichen Abmessungen des Werkstücks enthalten.
Mit diesen Werten berechne ich mir die Aufnahme und Ablegepositionen mitsammt den Anfahrten.
Voraussetzung dafür ist, das ich mir Base-Koordinatensysteme an den Ablagen oder Aufnahmen vermessen habe, die einen Bezug zu den Berechnungen bilden.
In den Unterprogrammen (in denen die Bewegungen stattfinden) berechne ich mir erst alle Positionen, und fahre sie dann an.
Durch die Verwendung der Datensätze, kann das Typenspektrum auch leicht erweitert werden.

rob · 22. Februar 2006

...und das teil am besten als STRUCtur auslegen:

$config.dat :
--------------

Code

CONST INT langes_teil = 1
CONST INT kurzes_teil = 2


STRUC TEIL_TYP REAL durchmesser, REAL laenge ; das zweite REAL koennte man weglassen...


DECL TEIL_TYP teil[2]


teil[1] = { durchmesser 20.0, laenge 200.0 } ; langes_teil
teil[2] = { durchmesser 20.0, laenge 100.0 } ; kurzes_teil
; ...

Alles anzeigen

...dann lässt sich in den programmen so darauf zugreifen...

Code

DEF arbeit (akt_teil :IN )
INT akt_teil
FRAME position
;...
position = $NULLFRAME
position.x = position.x - teil[akt_teil].laenge / 2.0 ; geht auch wenns vorher keine null ist
;...

...und so wird das programm aufgerufen...

Code

arbeit( langes_teil ) ; oder
arbeit( kurzes_teil )

Dodo · 22. Februar 2006

Zitat von SyncMa

Ich lege für jedes Teil Datensätze in der config.dat an (arrays) die die erforderlichen Abmessungen des Werkstücks enthalten.
Mit diesen Werten berechne ich mir die Aufnahme und Ablegepositionen mitsammt den Anfahrten.

Mit was für Teilen arbeitest Du?
Wenn ich mir das mit unseren Teilen (Gussteile Automobiltechnik) vorstelle...

rob: Ich guck mir das mal näher an, sieht gut aus!

rob · 22. Februar 2006

hmm... gussteile... OK.
wenn die teile komplett verschieden sind, ist die lösung mit "teachpunkte switchen" wohl am sinnvollsten. wenn du mir zwei beispielprogramme mailst, kann ich dir einen vorschlag machen. am besten mit $config.dat und cell.src.

rkarmann ät rego-fix punkt ch

SyncMa · 23. Februar 2006

Also wir haben es mit allen möglichen verschiedenen Teilen zu tun.
Gußteile unter anderem auch,
das fängt bei kleinen Teilen wie Fittings an und hört bei 2 t schweren Motorblöcken auf.
Die Datenverwaltung im Roboter wird bei uns aber nur im Notfall benutzt, da meistens eine SPS die Datenverwaltung übernimmt.
Die Daten werden bei einem Typwechsel über Profibus an den Roboter übermittelt.
Ich kann dir aber mal ein Programmbeispiel zukommen lassen in dem die Verwaltung im Roboter liegt.
Die Daten werden mit Hilfe der Configmon.ini eingegeben und auch abgerufen.

Programmänderungen bei mehreren Programmen

Erstelle ein Benutzerkonto oder melde dich an um zu kommentieren

Gebrauchtroboter kaufen - Was ist zu beachten. Die Checkliste zum kauf von gebrauchten Robotern

Was macht ein Roboterprogrammierer genau und was verdient er?

Vernetzen, referenzieren, kollaborieren: Das B2B Portal für die Produktionsautomatisierung

Sie wollen Ihr Stellenangebot im Roboterforum schalten? Ab 149€

Werde Roboterprogrammierer bei ROBTEC GmbH in Mainburg / Bayern

Teilen

Wieviele Mitglieder waren heute eingeloggt?