Vorraussetzungen/problemlösung gesucht für Rückzugsstrategie KRC2

EmaliaEluchiel · 28. Juli 2017

Hallo zusammen,

bisher habe ich zu gewissen Themen hier eine Lösung finden können, nun folgendes Problem.
Wir haben eine KRC2 Steuerung mit einem KR150 ohne SafeOP. In der Anlage ist eine Abholposition Eingerichtet welche berechnet wird da sie beweglich ist und zwei Ablage Positionen. Nun da ich leider erst den Grundlehrgang Programmierung für KRC2 absolvieren konnte, weis ich nicht welche Vorraussetzungen gegeben sein müssen um Eine Rückzugsstrategie für diese Anlage einzurichten.

Ich selbst möchte dies nicht Programmieren jedoch folgende Aussage von unserem in der Firma beauftragten Roboterprogrammierer Das Zu Programmieren wäre zu unsicher.

Momentan ist das ganze wie folgt gelöst. Ich betätige im AUTEXT einen Taster auf welchem Home Steht Schalte nach einer Störung die Antriebe über ein OP Aus und wieder ein muss nun einen Schlüsselschalter betätigen und der Roboter fährt 5 von 10 mal auf seine Home Position zurück jedoch auf direktem weg. Wenn er ganz Ungünstig über der 2. Ablage Position ganz Rechts steht Reist mir ein Greiferfinger ab bei der Homefahrt.

Wenn ich vor der Anlage stehe und auf den Roboter schaue habe ich Links die Abhol Position in der Mitte eine Ablage Position ungefähr in der selben höhe wie die bewegliche Entnahme Position und rechts daneben höher gelegen eine zweite Ablageposition.

Da der Roboter über Softwareendschalter begrenzt ist und über dem Roboter sich keine Teile befinden habe ich mir gedacht das es doch möglich sein muss den Roboter über betätigen des Schlüsselschalters(Halten bis in Home pos) in Beobachtiung und langsamer Geschwindigkeit über eine Sichere Bahn zurück auf die Homeoposition zu Fahren und eventuell dabei noch ein Teil abzulegen in der Ablage für den Ausschuss.

Somit war mein Ansatz zuerst eine Linearbewegung nach oben zu machen dann die Position nach vorne oder nach hinten zu Korrigieren auf einen vorgegebenen Wert, dann eine Kontrolle der E1(Dreifingergreifer) wenn diese Achse einen kleineren wert als Offen hat das Teil noch abzulegen wenn nicht von diesem Korrigierten Wert direkt Zur Homeposition.
(Die Möglichkeit Linear nach oben zu Fahren besteht in dieser Anlage immer da der Greifer seine position immer mit dem TCP nach unten hat.)

Leider ist das ganze doch ganz schön viel geworden Ich hoffe das ich es einigermaßen verständlich beschrieben habe wenn nicht könnt Ihr ja nachfragen.

Also zur Frage was wären die Vorraussetzungen für eine Rückzugsstragtegie und wie würdet ihr dies Lösen?

Ich würde mich sehr Über Unterstützung bei diesem Problem Freuen
VLG Emalia

RapidlyStupid · 9. August 2017

Hallo,
das kommt immer darauf an wie das Programm und die zugehörige Hardware aufgebaut ist. Die Integration einer Strategie die den Roboter aus nahezu jeder Position wieder kollisionsfrei auf eine Homeposition führt, kann schon mit etwas Zeitaufwand verbunden sein.
Jedoch ist natürlich so gut wie alles machbar
Dir jedoch eine Antwort zu geben fällt ohne genauere Betrachtung der Rahmenbedingungen natürlich schwer.
So als kleiner Tipp :
Merk dir doch über welche Punkte du die Aktualposition angefahren hast!
Im Rückzugsfall fährst dann halt diese Punkte in umgekehrter Reihenfolge wieder ab. Zumindest soweit das du sicher eine deiner Homepositionen wieder anfahren kannst.
VG

KoNo · 16. August 2017

Code

&ACCESS RVO4
&REL 1
&PARAM DISKPATH = KRC:\R1\Program\C00
DEF c00_v_r_GET( )
;FOLD INI;%{PE}
  ;FOLD BASISTECH INI
    GLOBAL INTERRUPT DECL 3 WHEN $STOPMESS==TRUE DO IR_STOPM ( )
    INTERRUPT ON 3 
    BAS (#INITMOV,0 )
INTERRUPT DECL 8 WHEN $IN[68] DO ABBRUCH()
INTERRUPT ON 8
  ;ENDFOLD (BASISTECH INI)
;FOLD SPOTTECH INI
USERSPOT(#INIT)
;ENDFOLD (SPOTTECH INI)
;FOLD GRIPPERTECH INI
USER_GRP(0,DUMMY,DUMMY,GDEFAULT)
;ENDFOLD (GRIPPERTECH INI)
  ;FOLD USER INI
    ;Make your modifications here


  ;ENDFOLD (USER INI)
;ENDFOLD (INI)


BEWEGUNG()


IF MSTOP==TRUE THEN
  RUE_RAUS()
  INTERRUPT ON 8
ENDIF


END
DEF BEWEGUNG()


;FOLD PTP HOME  Vel= 100 % DEFAULT;%{PE}%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:HOME, 3:, 5:100, 7:DEFAULT
$BWDSTART = FALSE
PDAT_ACT=PDEFAULT
FDAT_ACT=FHOME
BAS (#PTP_PARAMS,100 )
$H_POS=XHOME
PTP  XHOME
;ENDFOLD
TRIGGER WHEN DISTANCE=0 DELAY=0 DO ZRR=1
GRIP_VX_UNCLAMP()
;FOLD SPTP P1 Vel=100 % PDAT1 Tool[1]:GREIFER VX Base[1]:C00_120GRAD;%{PE}%R 8.3.40,%MKUKATPBASIS,%CSPLINE,%VSPTP_SB,%P 1:SPTP_SB, 2:P1, 3:, 5:100, 7:PDAT1
SPTP XP1 WITH $VEL_AXIS[1]= SVEL_JOINT( 100), $TOOL= STOOL2( FP1), $BASE= SBASE( FP1.BASE_NO),$IPO_MODE= SIPO_MODE( FP1.IPO_FRAME), $LOAD= SLOAD( FP1.TOOL_NO), $ACC_AXIS[1]= SACC_JOINT( PPDAT1), $GEAR_JERK[1]= SGEAR_JERK( PPDAT1)
;ENDFOLD
TRIGGER WHEN DISTANCE=0 DELAY=0 DO ZRR=10
; ABFRAGE TOR AUF
;FOLD WAIT FOR ( IN 112 'C00_Tor_ist_auf' );%{PE}%R 8.3.40,%MKUKATPBASIS,%CEXT_WAIT_FOR,%VEXT_WAIT_FOR,%P 2:, 4:, 5:$IN, 6:112, 7:C00_Tor_ist_auf, 9:
WAIT FOR  ( $IN[112] ) 
;ENDFOLD
;FOLD WAIT FOR ( IN 124 'Spanner_C00_V_R_zu' );%{PE}%R 8.3.40,%MKUKATPBASIS,%CEXT_WAIT_FOR,%VEXT_WAIT_FOR,%P 2:, 4:, 5:$IN, 6:124, 7:Spanner_C00_V_R_zu, 9:
WAIT FOR  ( $IN[124] ) 
;ENDFOLD
;########################################
;FOLD SLIN OBEN CONT Vel=2 m/s CPDAT1 ADAT0 Tool[1]:GREIFER VX Base[1]:C00_120GRAD;%{PE}%R 8.3.40,%MKUKATPBASIS,%CSPLINE,%VSLIN_SB,%P 1:SLIN_SB, 2:OBEN, 3:C_SPL, 5:2, 7:CPDAT1, 8:ADAT0
SLIN XOBEN WITH $VEL=SVEL_CP( 2, , LCPDAT1), $TOOL=STOOL2( FOBEN), $BASE= SBASE( FOBEN.BASE_NO),$IPO_MODE=SIPO_MODE( FOBEN.IPO_FRAME), $LOAD=SLOAD( FOBEN.TOOL_NO), $ACC=SACC_CP( LCPDAT1), $APO=SAPO( LCPDAT1), $ORI_TYPE=SORI_TYP( LCPDAT1), $JERK=SJERK( LCPDAT1) C_SPL
;ENDFOLD
TRIGGER WHEN DISTANCE=0 DELAY=0 DO ZRR=20
;FOLD LIN M_P Vel=0.1 m/s CPDAT8 Tool[1]:GREIFER VX Base[2]:C02_105GRAD;%{PE}%R 8.3.40,%MKUKATPBASIS,%CMOVE,%VLIN,%P 1:LIN, 2:M_P, 3:, 5:0.1, 7:CPDAT8
$BWDSTART=FALSE
LDAT_ACT=LCPDAT8
FDAT_ACT=FM_P
BAS(#CP_PARAMS,0.1)
LIN XM_P 
;ENDFOLD
;########################################
;FOLD LIN MITTE CONT Vel=0.1 m/s CPDAT2 Tool[1]:GREIFER VX Base[1]:C00_120GRAD;%{PE}%R 8.3.40,%MKUKATPBASIS,%CMOVE,%VLIN,%P 1:LIN, 2:MITTE, 3:C_DIS C_DIS, 5:0.1, 7:CPDAT2
$BWDSTART=FALSE
LDAT_ACT=LCPDAT2
FDAT_ACT=FMITTE
BAS(#CP_PARAMS,0.1)
LIN XMITTE C_DIS C_DIS
;ENDFOLD
TRIGGER WHEN DISTANCE=0 DELAY=0 DO ZRR=30
;########################################
;FOLD LIN UNTEN Vel=0.04 m/s CPDAT3 Tool[1]:GREIFER VX Base[1]:C00_120GRAD;%{PE}%R 8.3.40,%MKUKATPBASIS,%CMOVE,%VLIN,%P 1:LIN, 2:UNTEN, 3:, 5:0.04, 7:CPDAT3
$BWDSTART=FALSE
LDAT_ACT=LCPDAT3
FDAT_ACT=FUNTEN
BAS(#CP_PARAMS,0.04)
LIN XUNTEN 
;ENDFOLD
;FOLD WAIT Time=0 sec;%{PE}%R 8.3.40,%MKUKATPBASIS,%CWAIT,%VWAIT,%P 3:0
WAIT SEC 0
;ENDFOLD
;aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa
; GREIFER ZU UND SPANNER OEFFNEN
;FOLD WAIT FOR ( IN 50 'GRE_VX_R_BTK' );%{PE}%R 8.3.40,%MKUKATPBASIS,%CEXT_WAIT_FOR,%VEXT_WAIT_FOR,%P 2:, 4:, 5:$IN, 6:50, 7:GRE_VX_R_BTK, 9:
WAIT FOR  ( $IN[50] ) 
;ENDFOLD
    GRIP_VX_R_CLAMP()
;FOLD OUT 112 'C00 ROB IN POS' State=TRUE CONT;%{PE}%R 8.3.40,%MKUKATPBASIS,%COUT,%VOUTX,%P 2:112, 3:C00 ROB IN POS, 5:TRUE, 6:CONTINUE
CONTINUE
$OUT[112]=TRUE
;ENDFOLD
;FOLD WAIT FOR ( IN 123 'Spanner_C00_V_R_auf' );%{PE}%R 8.3.40,%MKUKATPBASIS,%CEXT_WAIT_FOR,%VEXT_WAIT_FOR,%P 2:, 4:, 5:$IN, 6:123, 7:Spanner_C00_V_R_auf, 9:
WAIT FOR  ( $IN[123] ) 
;ENDFOLD
;FOLD OUT 112 'C00 ROB IN POS' State=FALSE CONT;%{PE}%R 8.3.40,%MKUKATPBASIS,%COUT,%VOUTX,%P 2:112, 3:C00 ROB IN POS, 5:FALSE, 6:CONTINUE
CONTINUE
$OUT[112]=FALSE
;ENDFOLD
;eeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee
;FOLD LIN MITTE Vel=0.2 m/s CPDAT4 Tool[1]:GREIFER VX Base[1]:C00_120GRAD;%{PE}%R 8.3.40,%MKUKATPBASIS,%CMOVE,%VLIN,%P 1:LIN, 2:MITTE, 3:, 5:0.2, 7:CPDAT4
$BWDSTART=FALSE
LDAT_ACT=LCPDAT4
FDAT_ACT=FMITTE
BAS(#CP_PARAMS,0.2)
LIN XMITTE 
;ENDFOLD
;########################################
TRIGGER WHEN DISTANCE=0 DELAY=0 DO ZRR=20
;FOLD LIN OBEN Vel=2 m/s CPDAT5 Tool[1]:GREIFER VX Base[1]:C00_120GRAD;%{PE}%R 8.3.40,%MKUKATPBASIS,%CMOVE,%VLIN,%P 1:LIN, 2:OBEN, 3:, 5:2, 7:CPDAT5
$BWDSTART=FALSE
LDAT_ACT=LCPDAT5
FDAT_ACT=FOBEN
BAS(#CP_PARAMS,2)
LIN XOBEN 
;ENDFOLD
;########################################
TRIGGER WHEN DISTANCE=0 DELAY=0 DO ZRR=10
;FOLD SLIN P1 Vel=2 m/s CPDAT6 ADAT0 Tool[1]:GREIFER VX Base[1]:C00_120GRAD;%{PE}%R 8.3.40,%MKUKATPBASIS,%CSPLINE,%VSLIN_SB,%P 1:SLIN_SB, 2:P1, 3:, 5:2, 7:CPDAT6, 8:ADAT0
SLIN XP1 WITH $VEL=SVEL_CP( 2, , LCPDAT6), $TOOL=STOOL2( FP1), $BASE= SBASE( FP1.BASE_NO),$IPO_MODE=SIPO_MODE( FP1.IPO_FRAME), $LOAD=SLOAD( FP1.TOOL_NO), $ACC=SACC_CP( LCPDAT6), $ORI_TYPE=SORI_TYP( LCPDAT6), $JERK=SJERK( LCPDAT6)
;ENDFOLD
;########################################
TRIGGER WHEN DISTANCE=0 DELAY=0 DO ZRR=1
;FOLD PTP HOME  Vel= 100 % DEFAULT;%{PE}%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:HOME, 3:, 5:100, 7:DEFAULT
$BWDSTART = FALSE
PDAT_ACT=PDEFAULT
FDAT_ACT=FHOME
BAS (#PTP_PARAMS,100 )
$H_POS=XHOME
PTP  XHOME
;ENDFOLD


END


DEF ABBRUCH()


INTERRUPT OFF 8; INTERRUPT AUSSCHALTEN
BRAKE;  BREMSEN
MSTOP = TRUE; STOPMERKER SETZEN
IF $IN[42] THEN
   TiG = TRUE
ENDIF
RESUME; ABBRECHEN DER INTERRUPTROUTINE


END




DEF RUE_RAUS()


$out[68]=TRUE
$OV_PRO = 10


WHILE ZRR > 0


IF ZRR== 30 THEN
  LIN XMITTE
  ZRR = 20
ENDIF


IF ZRR== 20 THEN
  LIN XOBEN
  ZRR = 10
ENDIF


IF ZRR== 10 THEN
  LIN XP1
  ZRR = 1
ENDIF


IF ZRR== 1 THEN
  PTP XHOME
  ZRR = 0
ENDIF


ENDWHILE


END

Alles anzeigen

Dies wäre eine mögliche Lösung. Hier muss ein Interrupt programmiert werden (hier: Interrupt 8), der den Abbruch in die Wege leitet. Im Hauptprogramm wird das Programm BEWEGUNG aufgerufen, in dem das normale Programm abläuft. Bei einer Störung oder einem Abbruch wird von der SPS der Eingang 68 geschaltet und damit das Programm ABBRUCH eingeleitet.
Im Programm ABBRUCH wird der Merker MSTOP gesetzt, der in der SPS.SUB wieder zurückgesetzt wird, wenn der Roboter in Home steht. Das Programm BEWEGUNG wird abgebrochen. In der nächsten Zeile steht die IF-Bedingung und das Programm RUE_RAUS wird aufgerufen und ausgeführt, bis der Roboter in Home steht.
Das Ganze must du natürlich spezifisch für dein eigenes Programm anpassen.
Viel Spass
OLDDRAGON

Vorraussetzungen/problemlösung gesucht für Rückzugsstrategie KRC2

Erstelle ein Benutzerkonto oder melde dich an um zu kommentieren

Gebrauchtroboter kaufen - Was ist zu beachten. Die Checkliste zum kauf von gebrauchten Robotern

Was macht ein Roboterprogrammierer genau und was verdient er?

Vernetzen, referenzieren, kollaborieren: Das B2B Portal für die Produktionsautomatisierung

Sie wollen Ihr Stellenangebot im Roboterforum schalten? Ab 149€

Werde Roboterprogrammierer bei ROBTEC GmbH in Mainburg / Bayern

Teilen

Wieviele Mitglieder waren heute eingeloggt?