ABB S4c Steuerung und ISRA VISION KAMERA SYSTEM

swagner3 · 29. August 2005

Hallo,
ich verwende einen ABB Roboter mit S4C Steuerung mit einem Visionsystem der Firma "Isra Vision Oris Version 3.4".
Ich habe folgendes Problem:
Das Kamerasystem ist über eine Serielle Schnitstelle mit dem Roboter verbunden.
Wenn ich über mein Programm (multitasking Betrieb, Task 0 VisionProgramm, Task 1 MainProgramm) zuerst eine Typverifikation und anschließend die Koordinatenrückgabe für das erkannte Teil durchführe habe ich eine Prozesszeit von ca. 10s (gemessen vom drücken der Starttaste bis zu dem Punkt an dem der Roboter gerade die Position anfahren will); wenn ich aber das Programm ohne Typverifikation starte sondern ich sage Ihm z.B. Teil 3 liegt unter der Kamera und er soll mir nur die Koordinaten zurückgeben und das anfahren, dann dauert es nur ca. 1.5s.
Kann dies an einer vielleicht geschlossenen seriellen Schnittstelle liegen?
Wenn ja wie kann ich diese die ganze Zeit offen halten?

Vielen Dank im voraus
swagner3

rmac · 30. August 2005

Hallo,
ich habe im Laufe des letzten Jahres mal zwei Vision-Systeme (einmal Matsushita und einmal Eigenbau) seriell mit der S4C gekoppelt, allerdings nicht mit Multitasking, sondern in der Main-Task.
Ich hatte da auch so meinen "Spaß" mit, aber irgendwann funktionierte es....

Prinzipiell kann man den seriellen Kanal schon offen lassen indem man die entsprechende iodev Variable in einem globalem Modul deklariert, beim Start des Programms einmal initialisiert usw.
Ich habe damit aber keine guten Erfahrungen gemacht (mangelnde Stabilität) und könnte mir auch vorstellen, dass das nicht die Lösung des Problems ist. Um die Problematik einzugrenzen und herauszufinden was wann passiert, sollten Sie versuchen den zeitlichen Ablauf zu analysieren, indem Sie den Prozeß in kleinere logische "Häppchen" zerlegen und nach jedem (Teil-)Schritt eine Meldung mit Zeitangabe auf dem TeachPanel oder in eine Logdatei ausgeben. Dann kann man weitersehen....

Wenn die Koordinatenübergabe reproduzierbar(!) bei 1,5 Sekunden und die Objekterkennung bzw. -verifikation bei 8,5 Sekunden liegt, dann würde ich mich zunächst mal mit dem Vision-System beschäftigen... :wink:

Gruß
Rainer

swagner3 · 30. August 2005

Hallo Rainer,

Am Anfang dachte ich auch das es an dem Vision System liegt; ich habe dann aber den Roboter (als Master) durch einen anderen Computer ersetzt und über das Programm "Digitest" die Befehle (die sonst der Roboter abschickt) zur Typverifiaktion und zur Koordinatenrückgabe eingegeben und siehe da es dauerte noch nicht mal 800 ms für alles. Allso kann es nicht am Vision System liegen.
Die leute von Isra sagten mir es könnte daran liegen das ABB die schnittstelle z.B. 2 sek. geöffnet hält und danach schließt und diese nach einer gewissen Zeit wieder öffnet. Kann das sein ?

Wie muß ich denn in meinem Programm den Code eingeben um die Schnittstelle offen zu halten; ich habs folgendermaßen probiert

Code

VAR iodev Kamera;


Open "Sio1:",Kamera\Bin;

hat aber leider nicht funktioniert Fehlermeldung war: 40505 Kann nicht öffnen Sio1: Raise Code: Err_Fileopen=1015

War der Code überhaupt richtig?

Vielen Dank im voraus.

Gruß Stefan

rmac · 30. August 2005

Hallo Stefan,

Zitat

Die leute von Isra sagten mir es könnte daran liegen das ABB die schnittstelle z.B. 2 sek. geöffnet hält und danach schließt und diese nach einer gewissen Zeit wieder öffnet. Kann das sein ?

Klingt für mich zwar nicht unbedigt logisch, unmöglich ist aber (fast) nichts. (Ich habe es auch geschafft die S4C mit serieller IO "bluescreen-mäßig" abzuballern)

Hier ein bisschen Code aus einem damaligem Projekt:

Code

VAR iodev A100;
    Open "com1:",A100\Bin;
    ! Buffer löschen kann nicht schaden
    ClearIOBuff A100;
    ! Vision triggern
    WriteStrBin A100,"%S\0D";
    ! Koordinaten lesen
    sX:=ReadStrBin(A100,4\Time:=5);
    sY:=ReadStrBin(A100,4\Time:=5);
    Close A100;
  ERROR
    IF ERRNO=ERR_DEV_MAXTIME THEN
      Close A100;
      RAISE;
    ELSEIF ERRNO=ERR_FILEOPEN THEN
      RAISE;
    ENDIF

Alles anzeigen

Insbesondere das Löschen des SIO-Buffers (ClearIOBuff) kann manchmal Wunder wirken.
Auch das Schließen des Kanals im (Timeout-)Fehlerfall nicht vergessen! (=sonst böse Falle).
Je nachdem in welchem Format das VisionSystem die Kommandos/Parameter erwartet, könnte man ggfls. auch mit angehängten CR und/oder LFs experimentieren.

Zitat

hat aber leider nicht funktioniert Fehlermeldung war: 40505 Kann nicht öffnen Sio1: Raise Code: Err_Fileopen=1015

Das würde auf einen generellen Fehler bei den SIO-Parametern (Baudrate, Handshake, etc) hindeuten, ist aber auszuschließen wenn die ser. Kommunikation über diesen Kanal sonst prinzipiell funktioniert. Möglicherweise ist der Kanal aber auch schon geöffnet, allerdings weiß ich nicht ob das doppelte Öffnen diese Fehlermeldung provozieren würde. Am besten die komplette Kommunikation zw. Roboter und Vision erstmal in einer Proc isolieren (Kapseln mit Open/Close) und testweise in der Maintask laufen lassen (also alle anderen Tasks beenden um Multitasking Probleme auszuschließen). Vielleicht bringt das mehr Hinweise.

Gruß
Rainer

Nachtrag:
Eine weitere Fehlerquelle könnte die Baudrate sein, deshalb erstmal langsam starten (z.B.: 9600 Baud) und wenns funktioniert langsam steigern.

swagner3 · 1. September 2005

Hallo,
habe jetz alles versucht.
Der Rob vertrödelt immer an der gleichen Stelle seine Zeit. Siehe Proc Home zeile mit Fahrbefehl im HAuptprogramm (TAsk1 WMAIN). Dort bleibt er ca 5 sec. stehen

Ich habe keine Ahnung was da los ist.
Vielleicht habe ich ja auch irgendwo im Prog einen fehler.
Es wäre nett wenn sich mal jemand die Progs ansieht.

Vielen Dank im Voraus

Gruß Stefan

Code

%%%
  VERSION:1
  LANGUAGE:ENGLISH
%%%


MODULE WMAIN
  ! HAUPTPROGRAMM
  PERS wobjdata wobjKAMERA:=[FALSE,TRUE,"",[[1628.09,1549.75,919.078],[0.794128,0.000376,0.001796,0.607748]],[[0.006795,-0.001192,0.006318],[1,-2.4E-05,2E-06,1.3E-05]]];
  !Koordinatensystem von Kalibrierplatte Kamera 1
  PERS wobjdata wobjSAEGE:=[FALSE,TRUE,"",[[31.7882,1722.08,863.18],[0.794556,-0.000796,-0.001472,0.607189]],[[0.012159,6E-05,0],[1,-2E-06,5E-06,5E-06]]];
  !Koordinatensystem von Säge
  CONST robtarget HOMEPOS:=[[1187.69,1527.51,1114.04],[7.9E-05,0.991045,-0.133531,-8.9E-05],[0,0,-2,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]];
  ! Ausgangs anfahr Position des roboters
  VAR num DX:=0;
  VAR num DY:=0;
  VAR num RotationZ:=0;
  VAR num xwert1:=0;
  VAR num ywert1:=0;
  VAR num XFAHR:=0;
  VAR num YFAHR:=0;
  VAR bool FIRSTLOOP:=TRUE;
  PERS bool FindItem:=FALSE;
  PERS num XWERT:=3;
  PERS num YWERT:=1;
  PERS num ZWERT:=1;
  PERS num XROT:=0.83;
  PERS num yROT:=0;
  PERS num ZROT:=0;
  PERS num TeileNr:=3;


  ! PERS Variablen werden zum Austausch mit anderen Tasks verwendet z.B. Vision TAsk
  PROC Anheben()
    ! Funktion zum Anheben des Teils 
    MoveL [[XFAHR,YFAHR,80],[0.000395,0.965035,-0.262121,-6.1E-05],[0,0,-1,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]],vmax,fine,Greifer1\WObj:=wobjKAMERA;
  ENDPROC


  PROC Saegevorgang()
    ! Hier findet der eigentliche Sägevorghang statt
    ! die Teile Nr. entspricht der SPS Nr. vom Oris Vision System
    WaitTime 0;
    Greifer1.tframe.rot:=[1,0,0,0];
    MoveL HOMEPOS,vmax,fine,Greifer1\WObj:=wobj0;
    FindItem:=TRUE;
    TEST TeileNr
    CASE 1:
    CASE 2:
    CASE 3:
      MoveJ [[389.3+DX,1564.12+DY,1006.22],[0.019226,0.150344,0.988422,-0.006999],[0,-1,-4,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]],vmax,z50,Greifer1\WObj:=wobj0;
      MoveL [[97.39+DX,-340.7+DY,-520.86],[0.009427,0.719588,0.694138,-0.016667],[0,-1,-4,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]],v1000,fine,Greifer1\WObj:=wobjSAEGE;
      MoveL [[156.37+DX,-101.61+DY,-520.92],[0.011257,0.79563,0.605482,-0.015467],[0,-1,-3,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]],v1000,fine,Greifer1\WObj:=wobjSAEGE;
      MoveL [[230.42+DX,-103.49+DY,-547.18],[0.011172,0.795627,0.605487,-0.015472],[0,-1,-3,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]],v1000,fine,Greifer1\WObj:=wobjSAEGE;
      MoveL [[364.59+DX,-103.5+DY,-548.72],[0.011219,0.795623,0.605491,-0.015478],[0,-1,-3,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]],v30,fine,Greifer1\WObj:=wobjSAEGE;
      MoveL [[364.58+DX,-195.1+DY,-536.27],[0.011221,0.795625,0.605489,-0.015479],[0,-1,-3,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]],v1000,fine,Greifer1\WObj:=wobjSAEGE;
      MoveL [[195.09+DX,-195.1+DY,-536.27],[0.011223,0.795623,0.605492,-0.015472],[0,-1,-3,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]],vmax,fine,Greifer1\WObj:=wobjSAEGE;
      MoveL [[182.49+DX,5.26+DY,-536.32],[0.009347,0.722675,0.690925,-0.016631],[0,-1,-3,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]],vmax,fine,Greifer1\WObj:=wobjSAEGE;
      MoveL [[282.14+DX,5.25+DY,-558.31],[0.00932,0.722664,0.690937,-0.016638],[0,-1,-3,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]],vmax,fine,Greifer1\WObj:=wobjSAEGE;
      MoveL [[411.05+DX,5.26+DY,-558.33],[0.009306,0.722664,0.690937,-0.016636],[0,-1,-3,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]],v40,fine,Greifer1\WObj:=wobjSAEGE;
      MoveL [[411.02+DX,-217.61+DY,-552.35],[0.009297,0.72265,0.690953,-0.016623],[0,-1,-3,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]],vmax,fine,Greifer1\WObj:=wobjSAEGE;
    CASE 4:
    CASE 5:
    CASE 6:
    CASE 7:
    CASE 8:
    CASE 9:
    CASE 10:
    CASE 11:
    CASE 12:
    CASE 13:
    CASE 14:
    CASE 15:
    CASE 16:
    CASE 17:
    CASE 18:
    CASE 19:
    CASE 20:
    ENDTEST
    GreiferAuf;
    MoveL HOMEPOS,vmax,fine,Greifer1\WObj:=wobj0;
  ENDPROC


  PROC GreifposAnfahren()
    ! Funktion um Greifposition anzufahren
    ConfJ\Off;
    ConfL\Off;
    Greifer1.tframe.rot:=OrientZYX(RotationZ,0,0);
    ! mit obigem Befehl wird die Orientierung um Z eingestellt mit aktuellem Wert 
    MoveL [[XFAHR,YFAHR,80],[0.000395,0.965035,-0.262121,-6.1E-05],[0,0,-1,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]],vmax,fine,Greifer1\WObj:=wobjKAMERA;
    WaitTime\InPos,0;
    MoveL [[XFAHR,YFAHR,-30],[0.000395,0.965035,-0.262121,-6.1E-05],[0,0,-1,0],[9E+09,9E+09,9E+09,9E+09,9E+09,9E+09]],v50,fine,Greifer1\WObj:=wobjKAMERA;
    ! Der erste MoveL BEfehl fährt über das Teil und der zweite bewegt den greifer senkrecht nach unten   
  ENDPROC


  
  PROC HOME()
    ! Funktion für die Homeposition anzufahren
     !WaitTime\inpos,0;
     Greifer1.tframe.rot:=[1,0,0,0];  
    !Orientierung des Greifers parallel zum Tisch
    MoveL HOMEPOS,vmax,fine,Greifer1\WObj:=wobj0;
     
  ENDPROC


  PROC GreiferAuf()
    ! Funktion um Greifer zu öffnen
    WaitDO Greifer,1;
    Set Greifer;
  ENDPROC


  PROC GreiferZu()
    ! Funktion um Greifer zu schließen
    WaitDO Greifer,0;
    Reset Greifer;
    TPReadNum DX,"Zustellung in X";
    TPReadNum DY,"Zustellung in Y";
    !DX un DY sind variablen um die Koordinaten in X und Y zu korrigieren (nur für Technikum) 
    !WaitTime 0.1;
  ENDPROC


  PROC haupt()
    ! Hauptprogramm
NEU:
    GreiferAuf;
    HOME;
    XFAHR:=XWERT;
    YFAHR:=YWERT;
    RotationZ:=ZROT+30;
    IF FIRSTLOOP THEN
      XWERT:=0;
      YWERT:=0;
      XFAHR:=0;
      YFAHR:=0;
      FIRSTLOOP:=FALSE;
      FindItem:=TRUE;
    ENDIF
    IF XFAHR<>0 AND YFAHR<>0 THEN
      GreifposAnfahren;
    ELSE
      GOTO NEU;
    ENDIF
    GreiferZu;
    Anheben;
    Saegevorgang;
    GreiferAuf;
    XFAHR:=0;
    YFAHR:=0;
    DX:=0;
    DX:=0;
    HOME;
  ENDPROC
ENDMODULE

Alles anzeigen

Und hier nun das VisionProgramm WVISION im Task0

Code

%%%
  VERSION:1
  LANGUAGE:ENGLISH
%%%


MODULE SHORVI
  PERS bool FindItem:=FALSE;
  PERS num XWERT:=0;
  PERS num YWERT:=0;
  PERS num ZWERT:=0;
  PERS num XROT:=0;
  PERS num yROT:=0;
  PERS num ZROT:=0;
  PERS num TeileNr:=0;


  PROC haupt()
 
    VAR bool bMeasure:=TRUE;
    VAR num nStep:=1;
    
    WaitUntil FindItem;
    XWERT:=0;
    YWERT:=0;
    ZWERT:=0;
    ZROT:=0;
    yROT:=0;
    XROT:=0;
  


Oris_open;


WHILE bMeasure DO
      TEST nStep
      CASE 1:
        ! run mode to auto
        ORISCom_RunMode\Auto;
      CASE 2:
        ORISRep_RunMode;
      CASE 3:
        ! type 0, subtype 1, camera 1 TYPVERIFIKATION
        ORISCom_MeaData 0,1,1;
       CASE 4:
        ORISRep_GetReslt;


TeileNr:=Oris_PosX;  


     ! CASE 5:
        ! run mode to auto
      !  ORISCom_RunMode\Auto;
      !CASE 6:
       ! ORISRep_RunMode;
      CASE 5:
        ! type , subtype , camera 1 KOORDINATENERMITTLUNG
        ORISCom_MeaData ORIS_PosX,ORIS_PosY,ORIS_PosZ;
      CASE 6:
         ORISRep_GetReslt;


    ! XWERT:=ORIS_PosX*cos(15.7)-ORIS_PosY*sin(15.7);
    ! YWERT:=1549.7+ORIS_PosY*cos(15.7)+ORIS_PosX*sin(15.7);


      ENDTEST
      IF Status=ORIS_OK THEN
        Incr nStep;
        IF nStep>6 THEN
          bMeasure:=FALSE;
        ENDIF
      ELSE
        bMeasure:=FALSE;
      ENDIF
    ENDWHILE


 
    ORIS_Close;
    
    XWERT:=ORIS_PosX;
    YWERT:=ORIS_PosY;
    ZWERT:=ORIS_PosZ;
    ZROT:=ORIS_RotZ;
    yROT:=ORIS_RotY;
    XROT:=ORIS_RotX;
    
    


 FindItem:=FALSE;


  ENDPROC
ENDMODULE

Alles anzeigen

rmac · 1. September 2005

Tach auch,

also:
was du da in den GreiferAuf() bzw. GreiferZu() Routinen mit WaitDO machst, ist bestimmt nicht im Sinne des Erfinders. WaitDO wartet so lange bis das entsprechende Signal (Greifer) gesetzt bzw. rückgesetzt wird (oder bis TimeOut), was aber erst im nächsten Befehl ausgelöst wird (!), das kann, glaub ich, so nicht funktionieren. Einfach mal die Reihenfolge der Instruktionen tauschen....

Bei welcher Zeile der Rob die Zeit vertrödelt habe ich aber jetzt nicht wirklich geblickt
Beschreibe bitte die Stelle etwas genauer. Wie hast du denn gemessen wieviel Zeit er wofür braucht ?

Noch was:
Greifer1 ist doch das Werkzeug (tool). Ich würde die Orientierung des Greifer nicht über die Manipulation der Strukturdaten machen, ist nicht so elegant (vielleicht ist es aber auch völlig genial und ich habe nur das Programm nicht geblickt ). Das Verfahren über berechnete Robtargets halte ich für besser (und nachvollziehbarer).

Gruß
Rainer

swagner3 · 1. September 2005

Hallo Rainer,

die Zeit wurde gemessen vom drücken der Start Taste bis zum ersten losfahren des Roboters.

Wenn ich während der Awrtezeit den Totmaschalter los lasse, dann befindert er sich bei folgender Zeile im Proc HOME

Code

MoveL HOMEPOS,vmax,fine,Greifer1\WObj:=wobj0;

Code

PROC HOME()
    ! Funktion für die Homeposition anzufahren
     !WaitTime\inpos,0;
     Greifer1.tframe.rot:=[1,0,0,0];  
    !Orientierung des Greifers parallel zum Tisch
    MoveL HOMEPOS,vmax,fine,Greifer1\WObj:=wobj0;

Ich habe aber leider keine Ahnung warum?

Gruß Stefan

rmac · 1. September 2005

Hallo Stefan,

also ich glaube das Problem ist das WaitDO in der GreiferAuf() Proc.
In Haupt() wird zuerst GreiferAuf() und dann Home() aufgerufen.
Wenn du die Zustimmtaste losläßt, dann ist der Rob noch im Wartezustand (WaitDO), zeigt aber schon den nächsten auszuführenden Befehl an (MoveL in Home()) könnte ich mir vorstellen (?). Probiers mal mit vertauschen der Befehle in GreiferAuf().

Gruß
Rainer

swagner3 · 1. September 2005

Hallo Rainer,

ich habe mal die von Dir angesprochenen Befehle getauscht nur leider Ohne erfolg er steht wie vorher auf dem Fahre Befehl "MoveL.... "

Was könnte ich denn noch probieren?

Gruß Stefan

rmac · 1. September 2005

Hallo,

habe mir dein Programm jetzt mal was genauer angesehen.
Gib doch in der NEU Schleife (am besten direkt hinter dem Label "NEU") einen Text (oder besser (Schleifen-)Zählerwert) auf dem Teachpanel aus, dann kann man wenigstens feststellen ob der ProgramCounter steht oder in der Schleife kreist.

Bis gleich
Rainer

swagner3 · 1. September 2005

Hallo Rainer,
ja Du hast recht der kreist ungefähr 15 mal in der Schleife bis er losfährt.

Wie kann ich denn hier abhilfe schaffen ?

Gruß Stefan

rmac · 1. September 2005

Hallo Stefan

bau mal in die (NEU-)Schleife in der MainTask folgendes ein:
TPWrite "Main: " + NumToStr(Schleifenzähler,0) + " " + CTime();

und in der While Schleife in der VisonTask
TPWrite "Vision: " + NumToStr(nStep,0) + " " + CTime();

schau dann mal auf dem TPanel was wann gemacht wird.

Rainer

swagner3 · 1. September 2005

HAllo Rainer,
habs mal ausprobiert mit dem Ergebnis das er in beide Tasks mehrmals durchläuft.

Gruß Stefan

rmac · 1. September 2005

Stefan,

übernehme mal die folgende Log-Routine in die Tasks

Code

PROC logWrite(string Text)
    CONST string logFileName := "HOME:run.log";
    VAR iodev AFile;
    Open logFileName, AFile \Append;
    Write AFile, Text + CDate() + " " + CTime();
    Close AFile;
  ERROR
    Return;
  ENDPROC

und bau diese (wie vorher) in die entsprechenden Schleifen ein, also
in der MainTask Schleife:

Code

logWrite("Main: " + NumToStr(Schleifenzähler,0));

und in der While Schleife in der VisonTask

Code

logWrite("Vision: " + NumToStr(nStep,0));

Nach dem Ausführen steht das Ergebnislog dann in der Datei "run.log".
Kopier das mal aus der Steuerung und poste den Inhalt hier als Antwort. Mich würde mal interessieren was dabei so rauskommt.....

Gruß
Rainer

swagner3 · 1. September 2005

Hallo Rainer,
hier das Log File. Beim Anfahren habe ich das Programm gestoppt.

Code

Main: 02005-09-01 16:37:25
Main: 02005-09-01 16:37:26
Main: 02005-09-01 16:37:26
Main: 02005-09-01 16:37:26
Vision: 12005-09-01 16:37:28
Main: 02005-09-01 16:37:28
Vision: 22005-09-01 16:37:28
Main: 02005-09-01 16:37:28
Main: 02005-09-01 16:37:28
Main: 02005-09-01 16:37:28
Vision: 32005-09-01 16:37:28
Main: 02005-09-01 16:37:28
Vision: 42005-09-01 16:37:29
Main: 02005-09-01 16:37:29
Main: 02005-09-01 16:37:29
Main: 02005-09-01 16:37:29
Main: 02005-09-01 16:37:29
Main: 02005-09-01 16:37:29
Main: 02005-09-01 16:37:29
Main: 02005-09-01 16:37:30
Main: 02005-09-01 16:37:30
Main: 02005-09-01 16:37:30
Main: 02005-09-01 16:37:30
Main: 02005-09-01 16:37:30
Main: 02005-09-01 16:37:30
Main: 02005-09-01 16:37:30
Main: 02005-09-01 16:37:31
Vision: 52005-09-01 16:37:31
Main: 02005-09-01 16:37:31
Vision: 62005-09-01 16:37:31
Main: 02005-09-01 16:37:31
Main: 02005-09-01 16:37:32
Main: 02005-09-01 16:37:32
Main: 02005-09-01 16:37:32
Main: 02005-09-01 16:37:32
Main: 02005-09-01 16:37:32
Main: 02005-09-01 16:37:32
Main: 02005-09-01 16:37:32
Main: 02005-09-01 16:37:33
Main: 02005-09-01 16:37:33
Main: 02005-09-01 16:37:33
Main: 02005-09-01 16:37:33
Main: 02005-09-01 16:37:33
Main: 02005-09-01 16:37:33

Alles anzeigen

rmac · 1. September 2005

Stefan,

scheint ja zumindest vom Ablauf wie gewünscht zu funktionieren.
Wenn ich das richtig sehe, scheint der Step 4 (ORISRep_GetReslt = Teileerkennung?) des VisionSystems () länger zu brauchen (> 2 Sek.). Das würde auch zu deiner Aussage am Anfang des Threads passen, nämlich das der Ablauf mit vorgegebener Teile-Nr. wesentlich schneller funktioniert. Da läßt sich aber wahrscheinlich von deiner Warte aus nicht viel dran drehen....

Wie sieht es denn bei den weiteren/folgenden Durchläufen aus?
Hängt er dann auch genau so lange an der gleichen Stelle ?

Gruß
Rainer

rmac · 2. September 2005

Hallo Stefan,

noch ein Nachtrag:
Man könnte die VisionTask dahingehend optimieren, dass die Initialisierung nur einmal beim Systemstart und nicht bei jeder Messung ausgeführt wird, aber wenn du sonst keine Möglichkeiten zur Anpassung/Parametrierung des Erkennungsprozesses auf dem VisionSystems hast, kannst du zeitlich nicht viel dran machen....

An dem Programm insgesamt ließe sich schon durchaus einiges ändern
Hier z.B. ein Vorschlag für haupt() in der MainTask:
(ACHTUNG: alles ungetestet und OHNE Gewähr !!!!)

Code

PROC haupt()
    XWERT:=0;
    YWERT:=0;
    GreiferAuf;
    HOME;
    FindItem:=TRUE;
    
    WHILE True DO
      WaitUntil (XWERT<>0) AND (YWERT<>0);
      XFAHR:=XWERT;
      YFAHR:=YWERT;
      RotationZ:=ZROT+30;
      XWERT:=0;
      YWERT:=0;


      GreifposAnfahren;
      GreiferZu;
      Anheben;
      Saegevorgang;
      GreiferAuf;
      HOME;
    ENDWHILE
  ENDPROC

Alles anzeigen

Man könnte noch andere Dinge weiter vereinfachen und besser strukturieren, nur dafür müsste man natürlich die anderen Procedures entsprechend anpassen.

Noch ein Tip zum Ablegen der verschiedenen Teile:
Du benutzt zum Aufruf der unterschiedlichen Ablagebewegungen diesen großen Case-Konstrukt (TEST/ENDTEST). Ich würde für jedes Teil eine Ablageroutine schreiben und diese dann über den Namen aufrufen. Ist viel übersichtlicher und pflegbarer.....
Beispiel:

Code

CONST num CAblageMax:=20;
CONST string CAblage_Procs {CAblageMax} := ["AblageTeil1","AblageTeil2","AblageDummy", ... ,"AblageDummy"];


PROC AblageTeil1()
   MoveJ ...
   ...
   MoveL ...
ENDPROC


PROC AblageTeil2()
   MoveJ ...
   ...
   MoveL ...
ENDPROC


PROC AblageDummy()
   ! Dummy = nix machen
ENDPROC

Alles anzeigen

Der Aufruf der Ablage in Saegevorgang() könnte dann in etwa so aussehen:

Code

PROC Saegevorgang()
    WaitTime 0;
    Greifer1.tframe.rot:=[1,0,0,0];
    MoveL HOMEPOS,vmax,fine,Greifer1\WObj:=wobj0;
    FindItem:=TRUE;
    %CAblage_Procs{TeileNr}%;
    GreiferAuf;
    MoveL HOMEPOS,vmax,fine,Greifer1\WObj:=wobj0;
 ENDPROC

Gruß
Rainer

swagner3 · 5. September 2005

Hallo Rainer,
vielen vielen Dank für Deine Hilfe.
Ich habe mal die von Dir angesprochenen Änderungen durchgeführt.
Ich versuche mal am Vision Programm noch irgendwie was zu drehen.
Mal sehen was da noch alles so möglich ist

Gruß Stefan

rmac · 5. September 2005

Hallo Stefan,

bitte, bitte, gern geschehen.

Ich hätte noch ein paar andere Anregungen zu deinem Projekt, aber ich will mich nicht aufdrängen...
Also wenn du noch Bedarf/Fragen hast, dann sag Bescheid.

Grüße und ansonsten noch viel Spaß beim Basteln...
Rainer

swagner3 · 6. September 2005

Hallo Rainer,

ich bin für jeden Vorschlag / Anregung dankbar.
Welche Anregungen kannst Du mir denn noch mit auf den Weg geben?
Am Donnerstag habe ich einen Termin bei der Fa. ISRA Vision zwecks Benutzung einer zweiten Kamera zur Feinvermessung mal sehen was dabei rauskommt.

Gruß Stefan

ABB S4c Steuerung und ISRA VISION KAMERA SYSTEM

Erstelle ein Benutzerkonto oder melde dich an um zu kommentieren

Gebrauchtroboter kaufen - Was ist zu beachten. Die Checkliste zum kauf von gebrauchten Robotern

Was macht ein Roboterprogrammierer genau und was verdient er?

Vernetzen, referenzieren, kollaborieren: Das B2B Portal für die Produktionsautomatisierung

Sie wollen Ihr Stellenangebot im Roboterforum schalten? Ab 149€

Werde Roboterprogrammierer bei ROBTEC GmbH in Mainburg / Bayern

Teilen

Wieviele Mitglieder waren heute eingeloggt?