Automatischer Programmaufruf wenn sich einen Variable im Hintergrund ändert?

Philip1993 · 26. April 2013

Hallo nochmal

Wisst ihr ob es möglich ist, dass automatisch (bspw. im T1) wenn sich eine Variable ändert dadurch ein Programm automatisch anzuwählen bzw. zu starten? (bei gedrücktem Zustimmer)

Habe nun nämlich einen Softkey mit dem ein Programm aufgerufen werden soll. Programmaufrufe im KFD sind ja nicht möglich

Eine IF Anweißung im LOOP des sps.sub ist auch unzulässig.

Gibt es da noch andere Möglichkeiten?

Einzige Lösung die mir sonst noch bleibt ist ist ein LOOP SRC dass ich dazu eigens anwählen müsste

Stups · 26. April 2013

Hallo,

warum soll ein IF im Submit- Loop unzulässig sein?
Habe selbst sehr viele in verwendung.
Der Submit soll ja u.a. eine (kleine)Background- SPS für einfache Logistiken darstellen. Das geht ja ohne IF nicht wirklich oder nur umständlich...

Welche Steuerung bzw. KSS hast du denn?

LG
Stups

verbogener · 26. April 2013

Das Zauberwort heisst: CWRITE (Doku-PDF gibt's hier im Forum).

Damit kannst du auch via Submit-Interpreter ein Programm abwählen, und ein anderes anwählen. Dabei immer den Interpreterstatus ($PRO_STATE1) auswerten. Du musst dir eine kleine Schrittkette machen, weil das Abwählen u. U. ein paar Submit-Zyklen dauert, du kannst ein neues Prog erst anwählen wenn der Interpreter frei ist.
Keine WAIT Anweisungen im Submit-Code!

Grüsse, APT

Philip1993 · 26. April 2013

Okay stimmt IF im SPS.Sub geht doch nur leider ist dann der Submit angehalten bei einem Aufruf. :-|

Möchte ja eigentlich im T1 dass das Programm angewählt und im Vordergrund automatisch mit zustimmer und Start abgefahren werden kann. Tut sich aber nichts.

Hab mich jetzt gerade in die Doku CWRITE etwas eingelesen jedoch erkenne ich leider nicht ganz wie ich damit ein Programm aufrufen kann.
Bin leider kompletter Anfänger.

Stups · 26. April 2013

Hier mal ein paar snippets aus meinem Submit...

Code

;Declarations
decl char progname[50], robint_name[50]
decl int Offset
decl bool dummy, out_cell_angewaehlt


robint_name[] = "CELL"
offset = 0


;Prüfen, ob im Roboterinterpreter "Cell" angewählt ist
if ((varstate("$pro_name1[]") == #initialized) and (StrLen($pro_name1[]) <> 0) and ($PRO_STATE1 <> #P_FREE)) then
	ON_ERROR_PROCEED
	dummy = StrComp($pro_name1[], robint_name[], #NOT_CASE_SENS)
	if $err.number == 0 then
		if dummy == true then
			out_cell_angewaehlt = TRUE
		else
			out_cell_angewaehlt = FALSE
		endif
	else
		err_clear($err)
	endif
else
	out_cell_angewaehlt = FALSE
endif




;Roboterinterpreter abwählen
strclear = strClear(progname[])
swrite(progname[], stat, offset, "CANCEL /R1/%s()",$Pro_NAME1[])
cwrite($cmd, stat, mode, progname[])



;Cell Anwählen
strclear = strClear(progname[])
progname[] = "RUN /R1/cell()"
cwrite($cmd, stat, mode, progname[])

Alles anzeigen

Natürlich ohne Gewähr

Philip1993 · 30. April 2013

Danke für die Tipps. Habe es nun hinbekommen

Code mit Beispielprogramm A6 habe es nun so gelöst!

Code

DECL STATE_T STAT
DECL MODUS_T MODE
MODE=#SYNC
...
LOOP
;select program A6()
;to start the program the START-button or
;an external start-signal is needed
IF $FLAG[1]==TRUE THEN
CWRITE($CMD,STAT,MODE,"RUN/R1/A6()")
$FLAG[1]=FALSE
ENDIF
;stop program A6()
IF $FLAG[2]==TRUE THEN
CWRITE($CMD,STAT,MODE,"STOP 1")
$FLAG[2]=FALSE
ENDIF
;cancel program A6()
IF $FLAG[3]==TRUE THEN
CWRITE($CMD,STAT,MODE,"CANCEL 1")
$FLAG[3]=FALSE
ENDIF
ENDLOOP

Alles anzeigen

Funktioniert Perfekt! Programm wird automatisch gestartet wenn FLAG True

atw12az5 · 13. Mai 2013

Zitat von RoboKiller93
Code
IF $FLAG[1]==TRUE THEN

Kleiner Tipp am Rande:
$FLAG[1] ist schon bool, kann also nur TRUE oder FALSE sein, es ist kein Vergleich im if nötig.

also:

Code

IF $FLAG[1] THEN

Automatischer Programmaufruf wenn sich einen Variable im Hintergrund ändert?

Erstelle ein Benutzerkonto oder melde dich an um zu kommentieren

Gebrauchtroboter kaufen - Was ist zu beachten. Die Checkliste zum kauf von gebrauchten Robotern

Was macht ein Roboterprogrammierer genau und was verdient er?

Vernetzen, referenzieren, kollaborieren: Das B2B Portal für die Produktionsautomatisierung

Sie wollen Ihr Stellenangebot im Roboterforum schalten? Ab 149€

Werde Roboterprogrammierer bei ROBTEC GmbH in Mainburg / Bayern

Teilen

Wieviele Mitglieder waren heute eingeloggt?