Beiträge von chip

chip · 20. Juli 2021

Hallo Hermann,

der Name für den Mount-Punkt ist bei mir "ProtTrans", den hatte ich ja vergeben.

Nur wenn der Pfad mehrere Unterverzeichnisse hat, dann verbindet der KUKA nicht, warum auch immer. Naja, jetzt läuft es ja und ist auf der Todo-Liste abgehakt.

Danke nochmal für die Unterstützung.

chip · 19. Juli 2021

Hallo zusammen,

ich habe es jetzt geschafft, vielleicht möchte ja später jemand mit dem Befehl arbeiten.

Code: KRC Doku

Um sich aus KRL heraus mit einem freigegebenen Netzlaufwerk zu verbinden, muss ein Name für den Mount-Punkt vergeben werden und der vollständige Pfad zum freigegebenen Verzeichnis bekannt sein. Außerdem wird ein Benutzername und das verschlüsselte Passwort des Benutzers benötigt, unter dem eine Verbindung zum Netzlaufwerk hergestellt werden soll

Bei dem Befehl krl_mount darf nur ein Unterverzeichnis angegeben werde, ansonsten kann der KUKA nicht Mounten. Das steht aber so nicht in der Doku.

chip · 19. Juli 2021

Hallo Hermann,

die Freigabe ist auf einem Synology NAS.

Deshalb verstehe ich nicht, das es mit dem Mounten nicht funktioniert.

Wenn ich das Netzlaufwerk über Windows anspreche, geht es.

Nur halt mit dem KRL Befehl nicht.

chip · 19. Juli 2021

Hallo Herman,

das ist der Freigegebene Pfad wo ich die Datei speichern möchte.

Ich habe schon alles versucht, mit Backslash, Slash, in Kombination, ohne Unterverzeichnis, anderer User, anderes Passwort. Egal was ich mache, es kommt immer die Fehlermeldung -2.

Zitat von chip

wenn ich Backslash nehme, gibt es eine Fehlermeldung.

Da habe ich mich vertan, da kommt keine Fehlermeldung, wenn ich bei dem Mountnamen den Backslash benutze, erhalte ich eine Fehlermeldung.

chip · 18. Juli 2021

Hallo Ottosieben,

wenn ich Backslash nehme, gibt es eine Fehlermeldung.

Im Handbuch steht auch das man Slash benutzen soll.

chip · 16. Juli 2021

Hallo zusammen,

ich Versuche momentan Krampfhaft ein Netzlaufwerk mit einem KRC 4 Version 8.3.40 zu verbinden.

Der Roboter und das Laufwerk sind im gleichen Netzwerk.

Die Archivierung und der Zugriff über Windows funktioniert.

Wenn ich den KUKA Befehl krl_mount benutze, bekomme ich immer die Fehlermeldung -2 (Operation fehlgeschlagen: Ungültiger Benutzer, falsches Passwort, Mount-Punkt nicht vorhanden, Datei nicht vorhanden,etc).

Ohne krl_mount ist mir die Datei, in die ich Schreibe, zu sehr versteckt.

Code: Code

&ACCESS RVO2
&REL 156
&PARAM DISKPATH = KRC:\R1\Program\WeldBrazingShift
DEF protokol( )
; ***********************************************
; *       TouchSens Messung speichern           *
; * Version: 1.0                                *
; * Author:                                     *
; * DATE:                                       *
; * KRC4                                        *
; ***********************************************
END
GLOBAL DEF SAVE_MESURE (BASE_SHIFT:IN, DOOR_TYPE:IN)
DECL FRAME BASE_SHIFT
DECL CHAR DOOR_TYPE
OFFSET = 0
OFFSET_MSG = 0
MAX_MESURES = 100
MODE = #SYNC
HANDLE = 0



  ON_ERROR_PROCEED
  MODEL_TYPE = DOOR_TYPE
  SWITCH $ERR.NUMBER
    CASE 0
    
    CASE 1422
      OFFSET_MSG = 0
      SWRITE (MSG_TEXT[], STATE_MSG, OFFSET_MSG, "Tuer Parameter fehlt (3, 5 oder H angeben).")
      SWRITE (MSG_TEXT[], STATE_MSG, OFFSET_MSG, " Es kann kein Protokol angelegt werde")
      MsgQuit(MSG_TEXT[], "Protokol")
      Return
    DEFAULT
      ERR_RAISE ($ERR)
  ENDSWITCH    

  IF VARSTATE("count_proto_3") <> #INITIALIZED THEN
    count_proto_3 = 0
  ENDIF

  IF VARSTATE("count_proto_5") <> #INITIALIZED THEN
    count_proto_5 = 0
  ENDIF

  IF VARSTATE("count_proto_5_rear") <> #INITIALIZED THEN
    count_proto_5_rear = 0
  ENDIF
  
  CWRITE ($FCT_CALL, STAT, MODE, "krl_mount", "/ProtTrans","//136.129.1.14/Loeten/85R3", "KUKA","049D6ED2384375B8F543419D36DA9E4E18")

  IF stat.msg_no < 0 then
    halt
  ENDIF
  
  SWRITE(END_STR[], STAT, OFFSET, "%02d.%02d %02d:%02d%s%f%s%f%s%f", $DATE.DAY, $DATE.MONTH, $DATE.HOUR, $DATE.MIN, ", DIFF X : ",  BASE_SHIFT.X, ", DIFF Y : ", BASE_SHIFT.Y, ", DIFF Z : ", BASE_SHIFT.Z)

  SWITCH MODEL_TYPE  ; Select Door Type

    CASE "3"
    
      count_proto_3 = count_proto_3 + 1

      ;TXT_STR_AKT[] = "TouchSens_Protokol_3_Akt.TXT  "
      ;TXT_STR_ALT[] = "TouchSens_Protokol_3_Alt.TXT  "
      TXT_STR_AKT[] = "/ProtTrans/TouchSens_Protokol_3_Akt.TXT  "
      TXT_STR_ALT[] = "/ProtTrans/TouchSens_Protokol_3_Alt.TXT  "

      IF (count_proto_3 > MAX_MESURES) THEN
        count_proto_3 = 1
        CWRITE($FCT_CALL, STAT, MODE, "krl_remove", TXT_STR_ALT[])
        CWRITE($FCT_CALL, STAT, MODE, "krl_rename", TXT_STR_AKT[], TXT_STR_ALT[])
        CWRITE($FCT_CALL, STAT, MODE, "krl_remove", TXT_STR_AKT[])
      ENDIF

    CASE "5"
    
      count_proto_5 = count_proto_5 + 1

      ;TXT_STR_AKT[] = "TouchSens_Protokol_5_Akt.TXT  "
      ;TXT_STR_ALT[] = "TouchSens_Protokol_5_Alt.TXT  "
      TXT_STR_AKT[] = "/ProtTrans/TouchSens_Protokol_5_Akt.TXT  "
      TXT_STR_ALT[] = "/ProtTrans/TouchSens_Protokol_5_Alt.TXT  "

      IF (count_proto_5 > MAX_MESURES) THEN
        count_proto_5 = 1
        CWRITE($FCT_CALL, STAT, MODE, "krl_remove", TXT_STR_ALT[])
        CWRITE($FCT_CALL, STAT, MODE, "krl_rename", TXT_STR_AKT[], TXT_STR_ALT[])
        CWRITE($FCT_CALL, STAT, MODE, "krl_remove", TXT_STR_AKT[])
      ENDIF

    CASE "H"
    
      count_proto_5_rear = count_proto_5_rear + 1

      ;TXT_STR_AKT[] = "TouchSens_Protokol_5_R_Akt.TXT"
      ;TXT_STR_ALT[] = "TouchSens_Protokol_5_R_Alt.TXT"
      TXT_STR_AKT[] = "/ProtTrans/TouchSens_Protokol_5_R_Akt.TXT"
      TXT_STR_ALT[] = "/ProtTrans/TouchSens_Protokol_5_R_Alt.TXT"

      IF (count_proto_5_rear > MAX_MESURES) THEN
        count_proto_5_rear = 1
        CWRITE($FCT_CALL, STAT, MODE, "krl_remove", TXT_STR_ALT[])
        CWRITE($FCT_CALL, STAT, MODE, "krl_rename", TXT_STR_AKT[], TXT_STR_ALT[])
        CWRITE($FCT_CALL, STAT, MODE, "krl_remove", TXT_STR_AKT[])
      ENDIF

    DEFAULT

      OFFSET_MSG = 0
      SWRITE (MSG_TEXT[], STATE_MSG, OFFSET_MSG, "Falscher Parameter (nur 3, 5 oder H erlaubt.)")
      SWRITE (MSG_TEXT[], STATE_MSG, OFFSET_MSG, " Es kann kein Protokol angelegt werde")
      MsgQuit(MSG_TEXT[], "Protokol")
      Return
  ENDSWITCH


  ;Datei erstellen und oeffnen
  CWRITE ($FCT_CALL, STAT, MODE, "krl_fopen", TXT_STR_AKT[], "a", HANDLE)
  CWRITE ($FCT_CALL, STAT, MODE, "krl_fwriteln", HANDLE, END_STR[])
  ;inhalt in datei schreiben
  CWRITE ($FCT_CALL, STAT, MODE, "krl_fflush", HANDLE)
  ;Datei schliessen
  CWRITE ($FCT_CALL, STAT, MODE, "krl_fclose", HANDLE)
  CWRITE ($FCT_CALL, STAT, MODE, "krl_unmount", "/ProtTrans")

END

Alles anzeigen

Wieviele Mitglieder waren heute eingeloggt?