Frage zu dem : Operant mit Turn und Status

Hallo zusammen,

das Ergebnis des : Operators hat immer den Typ der rechten Seite, d.h.

<E6POS> : <POS> = <POS>

Als Beispiel einfach mal unter Anzeige->Variable->Einzeln z.B.
={E6POS: X -1293.20398,Y 785.216187,Z 491.908112,A 89.2432938,B -0.0642487183,C -0.0885750279,S 6,T 19,E1 0.0,E2 0.0,E3 0.0,E4 0.0,E5 0.0,E6 0.0} : {POS: X 0,Y 0,Z 200,A 0, B 0, C 0}
eingeben. Als Ergebnis erhält man dann
{POS: X -1293.516, Y 784.9960, Z 691.9078, A 89.24329, B -6.424872E-02, C -8.857503E-02}

Damit sind insbesondere nach Ausführung des : die Komponenten S und T im Ergebnis nicht gültig. Zur Ausführungszeit deiner Bewegung bedeutet das es kommt die normale Lückenfüllung zum Einsatz, d.h. fehlende Komponenten werden mit den Werten am Zielpunkt der Vorgängerbewegung aufgefüllt.

Gruß
Fubini

..vielleicht a bissi spät die Antwort aber wie wäre es denn wenn du angenommen deine T und S kennst
und dann einfach auch so festschreibst wie etwa so

....

IF VARSTATE("Offset.t")<>#INITIALIZED THEN
Offset.t=29 ; was auch immer deine Position an T hat ...
ENDIF

.....

und alle als E6POS deklarierst ...in der Funktion

und oder einfach dann oben zuvor in deine Bewegung reinsetzen

$APO.CPTP=50
BAS(#VEL_PTP,100)
BAS(#TOOL,2)
BAS(#BASE,0)
;--------------------
XPufferLinks.t=29
;--------------------
PTP PosOffs(XPufferLinks,{Z 50},#BASE) C_PTP

...vielleicht dilettantisch und wird evtl bei zu grossen Offs nicht passend ...
man könnte ja immer noch eine User MSG rausschicken und klären wenn ein Turn verlassen ( t>29, ect ...) wird
ob man das auch zulässt und eben KEINEN Crash riskiert ...

Grüße

Patch

Der optimale Turn (=der mit der geringsten Achswinkeländerung) ist aber nicht unmittelbar bekannt, das ist ja gerade das Problem.

Es gibt dazu eine universale Lösung mit INVERSE(), kann ich bei Bedarf posten.

...gerne!

DEF MAIN()


DECL FRAME verschiebung
DECL E6POS position
DECL INT retVal
DECL E6AXIS achsstellungVerschoben


verschiebung = $Nullframe
verschiebung.x=200
;usw...


;xPunkt is geteachter Punkt (E6POS) der verschoben werden soll
position = xPunkt : verschiebung


retVal = calcAchsen(position, achsstellungVerschoben)


switch retVal

    case -1
      ;Nicht alle wesentlichen Komponenten der Variablen POSITION (X, Y, Z, A, B, C, ggf. E1,      E2..) sind definiert. 
      ;(S und T müssen nicht unbedingt definiert sein.) oder:
      ;wenn der STATUS von POSITION ungültig ist, waren nicht alle Komponenten von START_AXIS gültig.
      halt

    case -2
      ;ERR_STATUS besitzt noch keinen gültigen Wert.
      halt

    case -3
      ;$BASE (Vorlaufvariable) ungültig.
      halt

    case -4
      ;$TOOL (Vorlaufvariable) ungültig.
      halt


    case 1
      ;SW-Endschalter bei den Achswinkel von START_AXIS verletzt. 
      ;(Nur möglich, wenn ERR_STATUS beim Aufruf den Wert 0 besaß und START_AXIS wegen fehlendem Turn von POSITION überhaupt benötigt wird.)
      halt


    case 2
      ;Arbeitsraum-Fehler bei der math. Trafo-Funktion, 
      ;d.h. es gibt keine Achswinkel, mit denen die kartesische Zielposition erreicht werden kann. 
      halt


    case 3
      ;Es gibt zwar Lösungswinkel, aber mit dem gegebenem Turn werden SW-Endschalter verletzt.
      halt


    case 0
      ;Kein Fehler, d.h. Berechnung war erfolgreich.
      ptp achsstellungVerschoben


endswitch


END

DEFFCT calcAchsen(position: IN, achsstellungVerschoben:OUT)


DECL E6POS position
DECL E6POS calc_position
DECL INT err_status
DECL E6AXIS achsstellungVerschoben
DECL E6AXIS startaxes


;calc_position ohne status und turn
calc_position.x = position.x
calc_position.y = position.y
calc_position.z = position.z
calc_position.a = position.a
calc_position.b = position.b
calc_position.c = position.c
calc_position.E1 = position.E1


$TOOL = $nullframe
$BASE = $nullframe
$target_status = #best
startaxes = $axis_act
err_status = 0
achsstellungVerschoben = INVERSE(calc_position,startaxes,err_status)


return err_status


ENDFCT

Damit ist gewährleistet (Auszug DOKU "INVERSE()"):
1)(b) $TARGET_STATUS = #BEST, d.h. der Zielpunkt erhält, denjenigen Status, so daß die Bewegung von Startpunkt zu Zielpunkt im Achsraum einen möglichst kurzen Weg zurücklegen muß.
In diesem Fall wird für alle 8 möglichen Status-Werte eine Rücktransformation durchgerechnet, und dann unter allen zulässigen Lösungen diejenige ausgewählt, die im Achsraum am „nächsten“ zum Startpunkt liegt.
(Gegenwärtig wir als Abstandsmaß im Achsraum die euklidische Norm verwendet. Denkbar wäre z.B. auch die Maximumsnorm).

2)Der Zielpunkt besitzt keinen TURN-Wert:
In diesem Fall wird für jede Achse der zulässige TURN-Wert berechnet, mit dem der Zielpunkt den kürzesten Weg zum Startpunkt besitzt. („Zulässig“ heißt in diesem Fall, daß falls bei der Wahl des näher gelegenen Achswinkel ein Softwareendschalter verletzt würde, wird der weiter entfernte gewählt.)

PS:
Falls sich jemand fragt was das:
calc_position.x = position.x
soll.
Damit das ganze auch mit externen Achsen klappt kann man keinen FRAME verwenden und muss Status und Turn aus der E6POS loswerden. Dazu füll ich einfach eine neue E6POS mit allem aus der alten bis auf S&T.

PPS:
Damit das klappt sollte man bei der Ausführung der Funktion schon auf dem Punkt, von dem aus man den verschobenen Anfahren will, stehen, wegen $axis_act.
Wenn mans woanders berechnen will, kann man startaxes auch übergeben.