Position speichern wenn der Bedienerschutz unterbrochen wird

Du könntest die negative Flanke der Systemvariablen für Bedienerschutz im Submit-Interpreter auswerten.
So beispielweise:

IF $Flag[1] AND (NOT $User_Saf) THEN
PosMerker = $PosAct
$FLAG[1] = FALSE
ENDIF

IF (NOT $Flag[1]) AND $User_Saf THEN
$FLAG[1] = TRUE
ENDIF

Gruß Stefan

dann nimm doch $AXIS_ACT

$PRO_ACT geht auch im Submit, wenn vorher ein Programm angewählt und die INI-Zeile durchlaufen wurde. Deshalb erweitere ich mal den Vorschlag von zsteve.

$Flag[2] wird nach der INI-Zeile und SAK auf True gesetzt, um die Überwachung zu starten.

Müsste eigentlich so gehen:

IF ($PRO_STATE1=#P_FREE) OR ($PRO_STATE1==#P_RESET) THEN
 $FLAG[2]=FALSE
ENDIF


IF  ($FLAG[2]) THEN
  IF $Flag[1] AND (NOT $User_Saf) THEN
     PosMerker = $PosAct
     $FLAG[1] = FALSE
  ENDIF


  IF (NOT $Flag[1]) AND $User_Saf THEN
     $FLAG[1] = TRUE
  ENDIF
ENDIF

Aber $AXIS_ACT ist einfacher, wenn's reicht.

Zitat von skyflyer

Fehlermeldung "1419 Absender sps.sub XYZABC Tool nicht programmiert". Liegt wahrscheinlich daran das im submit nicht bekannt ist welches Tool und auch base aktiv ist.

Macht Sinn

Für die Übersetzung von AXIS in kartesisch gäb's die Funktion Forward ()

Gruß Stefan

Forward() ... das ist das unkomplizierte was es gibt.
Du aktivierst ein Tool, eine Base, übergibst eine Koordinate in Axis oder E6AXIS und bekommst eine E6POS zurück...

ich würde das Ganze im Submit lösen. Es kommt noch ein wenig darauf an, was du genau mit der gespeicherten Position machen willst. Aber ich würde das in etwa so programmieren:

savePos.dat

DEFDAT savePos PUBLIC
  DECL GLOBAL E6POS POS_Brake = {X 0.0, Y 0.0, Z 0.0, A 0.0, B 0.0, C 0.0, S 0, T 0, E1 0.0, E2 0.0, E3 0.0, E4 0.0, E5 0.0, E6 0.0}
  DECL GLOBAL E6AXIS AXIS_Brake = {A1 0.0, A2 0.0, A3 0.0, A4 0.0, A5 0.0, A6 0.0, E1 0.0, E2 0.0, E3 0.0, E4 0.0, E5 0.0, E6 0.0}

  GLOBAL ENUM ValidPos_T NONE AXIS CARTESIAN
  DECL GLOBAL ValidPos_T PosType
  DECL BOOL bLastState
  DECL GLOBAL INT iTool, iBase
ENDDAT

savePos.sub

DEF savePos()
  ;Wenn sich der Status des Bedienerschutzes geändert hat
  IF bLastState<>$USER_SAF THEN
    ;Dann übernimm den Status in die Speichervariable
    bLastState = $USER_SAF
    PosType = #NONE
    ;Wenn zusätzlich der Bedienerschutz unterbrochen ist
    IF NOT $USER_SAF THEN
      ;Dann speichere die Position, wo der Roboter gebremst wurde
      ;Wenn Tool und Base gesetzt sind
      IF (VARSTATE("$TOOL")==#INITIALIZED) THEN
        IF (VARSTATE("$BASE")==#INITIALIZED) THEN
          ;Wenn eine programmierte Bahn abgefahren wurde
          IF (VARSTATE("$POS_RET")==#INITIALIZED) THEN            
            POS_Brake = $POS_RET
          ELSE
            POS_Brake = $POS_ACT
          ENDIF
          iTool = $ACT_TOOL
          iBase = $ACT_BASE
          PosType = #CARTESIAN
        ENDIF
      ENDIF
      ;Wenn nicht kartesisch gespeichert werden konnte
      IF PosType<>#CARTESIAN THEN
        AXIS_Brake = $AXIS_ACT
        PosType = #AXIS
      ENDIF      
    ENDIF
  ENDIF
END


GLOBAL DEF savePos_INIT()
  ;Falls sinnvoll BrakePos auf Standardwert setzten
  POS_Brake = {X 0.0, Y 0.0, Z 0.0, A 0.0, B 0.0, C 0.0, S 0, T 0, E1 0.0, E2 0.0, E3 0.0, E4 0.0, E5 0.0, E6 0.0}
  AXIS_Brake = {A1 0.0, A2 0.0, A3 0.0, A4 0.0, A5 0.0, A6 0.0, E1 0.0, E2 0.0, E3 0.0, E4 0.0, E5 0.0, E6 0.0}
  PosType = #NONE ;in was für einem Datentyp ist die Position gespeichert
  bLastState = $USER_SAF  ;TRUE = Bedienerschutz geschlossen
END

lg drudge

Zitat von drudge

IF (VARSTATE("$TOOL")==#INITIALIZED) THEN
IF (VARSTATE("$BASE")==#INITIALIZED) THEN
;Wenn eine programmierte Bahn abgefahren wurde
IF (VARSTATE("$POS_RET")==#INITIALIZED) THEN

Alles anzeigen

Sofern ich mich errinnere, bremsen die Varstate-Funktion den Submit fürchtlerlich aus. irgendwo hatten wir diese Diskussion hier auch schon mal.
Ausserdem weiß der Submit manchmal niocht wirklich was im Interpreter so läuft. Gerade Varstate arbeitet dort nicht immer zuverlässig.
IMO wird im o.g. Code mit Kanonen auf Spatzen geschossen.

Ja das ist so, Varstate bremst den Submit aus. Doch wird das Varstate hier nur einmal kurz durchgeführt, wenn der Bedienerschutz geöffnet oder geschlossen wird. Das ist nach meiner Erfahrung unproblematisch

Zitat von drudge

Warum?

Bleibt immer noch das Problem, dass VARSTATE im Submit nicht immer reibungslos funktioniert. Wobei sich das bei neueren Softwareständen evtl. verbessert hat.
Schön ist natürlich, dass man bei dem Code anschließend alles zur Verfügung hat.
Die richtige Methode bestimmt die Aufgabe und die geht nicht so ganz aus der Beschreibing des TS vor.

Jetzt mal ganz blöd gefragt: Wenn ich das ganze im Programm per Interrupt abzufragen, welcher ausgelöst wird, wenn $USER_SAF false wird, kann die Routine nicht abgeschlossen werden, weil das Programm vorher beendet wurde. Würde der Interrupt nach erneutem Programmstart dann ausgelöst werden? Irgendsowas komisches hatte ich nämlich schon mal...

Zitat von IrrerPolterer

$Flag[2] wird nach der INI-Zeile und SAK auf True gesetzt, um die Überwachung zu starten.

ich würde es auch so programmieren da es unkomplizierter ist als die anderen Beispiele

MFG Thomas