Langtext anzeigen im Meldungsfenster

Tach auch

also Langtext anzeigen, geht, aber find grad kein beispiel dafür. Aber vielleicht hilft dir das Beispielprogramm weiter. Das müsste dann fehlerfall aufgerufen werden. z.B.

WHILE (FEHLER==TRUE) OR ($IN[4]==FALSE)
MSG_DEMO ()
ENDWHILE

BEISPIELPROGRAMM
&ACCESS R
&COMMENT Example on user messages
DEF MSG_DEMO ( )

; To run program -> change first line "&ACCESS R"
; into "&ACCESS RVP" and select program again !!!

DECL INT ANSWER
DECL INT OFFSET
DECL STATE_T STATE
DECL MSG_T EMPTY_MSG

EMPTY_MSG={MSG_T: VALID FALSE,RELEASE FALSE,TYP #NOTIFY,MODUL[] " ",KEY[] " ",PARAM_TYP #VALUE,PARAM[] " ",DLG_FORMAT[] " ",ANSWER 0}

;---------------------QUITTIERUNGSMELDUNG----------

$MSG_T=EMPTY_MSG
$MSG_T.MODUL[]=" "
$MSG_T.KEY[]="DEMO: QUIT-MESSAGE + %1"
$MSG_T.PARAM[]="PARAM"
$MSG_T.PARAM_TYP=#VALUE
$MSG_T.TYP=#QUIT

$MSG_T.VALID=TRUE

WHILE $MSG_T.VALID
WAIT SEC 0.05
ENDWHILE
WAIT SEC 0.2

;------------------DIALOGANFRAGE----------------

$MSG_T=EMPTY_MSG
$MSG_T.MODUL[]=" "
$MSG_T.KEY[]="DEMO: DIALOG + %1"
$MSG_T.PARAM[]="PARAM"
$MSG_T.RELEASE=FALSE
$MSG_T.PARAM_TYP=#KEY
$MSG_T.TYP=#DIALOG
$MSG_T.DLG_FORMAT[]="A|B|C"

$MSG_T.VALID=TRUE

WHILE $MSG_T.VALID
WAIT SEC 0.05
ENDWHILE
WAIT SEC 0.2
ANSWER=$MSG_T.ANSWER

;------------------HINWEISMELDUNG------------------

$MSG_T=EMPTY_MSG
$MSG_T.MODUL[]=" "
$MSG_T.KEY[]="DEMO: DIALOG ANSWER = %1"
OFFSET=0
SWRITE($MSG_T.PARAM[],STATE,OFFSET,"%d",ANSWER)
$MSG_T.PARAM_TYP=#VALUE

$MSG_T.VALID=TRUE

WHILE $MSG_T.VALID
WAIT SEC 0.05
ENDWHILE
WAIT SEC 0.2

;------------------- SIMULATION-----------------------

$LOOP_CONT=TRUE
WHILE $LOOP_CONT
$LOOP_MSG[]="S|HALLO ich die SIMULATION eines Schleifenabbruchs!"
; S| erzeugt die Simuliere-Taste !!!!!
ENDWHILE
$LOOP_MSG[]=" "
END

Zitat von ah_robotics

Code

DECL INT i_eingang=15  ;IN $CONFIG.DAT

Code

WAIT FOR $IN[i_eingang]

Es gab eine Softwareänderung (ab welcher Version ???)
Bei obiger Schreibweise wird bei einer V5.4.11 der Langtext angezeigt