Interrupt zeitverzögert auslösen

Zitat von BauAnd01

Soweit ist die Lösung vmtl. noch relativ einfach.

Also das heißt bis dahin hast du schon etwas?

Mit der Unempfindlichkeit kannst du das ganze mit einem cycflag und Timer flag machen.

$CYCFLAG erfasst deine beiden Geräte am besten mit einer UND Verknüpfung.

Wenn CYCFLAG anspricht startest du den Timer. Nach Ablauf der eingestellten Zeit wertest du den $TIMER_FLAG aus per interrupt.

Grüsse

Bei solchen Fummeleien und wenn die zeitliche Vorgabe eben nicht so genau sein muss lasse ich Hintergrundtasks gerne im Takt arbeiten. Die ungebremste SPS.SUB kommt ja nicht beliebig oft durch, sondern recht zuverlässig in 12ms. Oder man bremst sie halt aus mit einer definierten Wartezeit.... jedenfalls hat man dann einen Taktgeber, den man in jedem Durchlauf einen Step hochzählen lassen kann, situationsabhängig, und zurücksetzen. Man kann Zähler ja auch kaskadieren, damit man nicht so schnell überläuft...

Beim Abfragen der Zählvariablen natürlich nie auf Gleichheit prüfen, ist klar.

Natürlich ist das zeitlich ungenauer als die Verwendung der Timer, aber in vielen Fällen bequemer und durchschaubarer. Allerdings: man wird öfter in Verlegenheit kommen, Flanken von Signalen abfragen zu müssen, d. h., dass man nicht das eigentliche Signal verwendet, sondern den Vergleich mit seinem Zustand im letzten Zyklus. Das kann man aber in zwei Funktionen schön auslagern. Bei kritischen Überschneidungen muss man auch die Signale, die man verwerten will, vorher in einem Rutsch in Variablen abbilden, sonst kann es während der Abarbeitung innerhalb eines Zyklus' zu Problemen kommen...

Naja, das klingt jetzt doch komplizierter als eigentlich gedacht, aber kommt halt drauf an, wie oft man das machen muss. Zwei, drei $Timer sind easy, da braucht man das Konzept eher nicht, aber bei mehr ist diese Taktlösung gar nicht so schlecht.

Grüße,

Michael

Hallo Andreas,

Idee in sps.sub über $Timer die Signale so aufzubereiten, dass Du sie "ganz normal" verwenden kannst im Programm, ist sicher eine gute Idee.

So als Ideenfindung mal ein paar Zeilen Code. Ist absolut ungetestet.

Digitale Signale hab ich aber gleich zusammengefasst und übergebe sie verzögert über boolesche Variablen.

Vielleicht nützt es Dir was als Ideenspender.

DEFDAT $CONFIG
SIGNAL di_RDY_001 $IN[456]
SIGNAL di_RDY_002 $IN[457]

DECL BOOL b_2x_RDY_DELAYED = FALSE
DECL INT n_DELAY_TIME_2X_RDY = -2000 ;Achtung Minuswert

DECL BOOL b_INTRPT_NOT_RDY_DELAYED = FALSE
DECL INT n_DELAY_TIME_NOT_RDY = -200 ;Achtung Minuswert
ENDDAT

DEF  SPS ( )
   ;....
   $TIMER[1] = n_DELAY_TIME_2X_RDY     ; -2000 ms
   $TIMER[2] = n_DELAY_TIME_NOT_RDY    ; -200  ms
   $TIMER_STOP[1]=FALSE
   $TIMER_STOP[2]=FALSE
   ;....
   LOOP
      ;....  
      
      ;BEIDE BEREIT VERZOEGERN UM X-MILLISEKUNDEN
      IF ((di_RDY_001 == TRUE) AND (di_RDY_002 == TRUE) AND ($TIMER_FLAG[1] == TRUE)) THEN
         b_2x_RDY_DELAYED = TRUE
         $TIMER[1] = 50                            ; VERHINDERN UEBERLAUF        
      ELSE
         b_2x_RDY_DELAYED = FALSE
         IF (di_RDY_001 == FALSE) OR (di_RDY_002 == FALSE) THEN
            $TIMER[1] = n_DELAY_TIME_2X_RDY
         ENDIF   
      ENDIF
      
      ;INTERRUPT ABFALL VERZOEGERN
      IF (((di_RDY_001 == TRUE) AND (di_RDY_002 == TRUE)) OR ($TIMER_FLAG[2] == FALSE)) THEN
         b_INTRPT_NOT_RDY_DELAYED = FALSE
         IF ((di_RDY_001 == TRUE) AND (di_RDY_002 == TRUE)) THEN
            $TIMER[2] = n_DELAY_TIME_NOT_RDY
         ENDIF            
      ELSE
         b_INTRPT_NOT_RDY_DELAYED = TRUE
         $TIMER[2] = 50                            ; VERHINDERN UEBERLAUF  
      ENDIF
      ;....
   ENDLOOP
END


DEF  SigVerzTest ( )
;....
INTERRUPT DECL 21 WHEN b_INTRPT_NOT_RDY_DELAYED == TRUE DO IR_WAIT()
;....
PTP $AXIS_ACT

WAIT FOR b_2x_RDY_DELAYED
INTERRUPT ON 21   
;....   
 
END

DEF IR_WAIT()
INTERRUPT OFF 21
;....
INTERRUPT ON 21
END