FOR i=1 to Anz_umdrehungen
LIN_REL {b 0, c winkel}
LIN_REL [b -winkel, c 0}
LIN_REL {b 0, c -winkel}
LIN_REL {b winkel, c 0}
ENDFOR
Genau das funktioniert eben nicht! Die Krone wird nicht am Rand langgeführt.
Ich glaube ich muß das wieder mit ner tollen Zeichnung untermauern! 
Mit einem Winkel von 25 Grad wirds deutlicher!
IMO muß de TCP in den Rand der Krone verschoben werden....
Ja, aber dann kannst Du doch mein Code-Fragment mit ner CIRC-Bewegung kombinieren, oder nicht?
Es gibt meine ich ne Möglichkeit, dem Roboter zu sagen, welche Orientierung er während der Bewegung haben soll. Ich meine da wäre auch so was wie "Orientierung relativ zu Bahn beibehalten" bei gewesen, ich such gleich mal.
Ist das hier nicht, was Du dann suchst?
nee, das klappt nicht mit $ORI_TYPE = #PATH. da liegt die werkzeugachse auf der ebene der kreisbewegung...
mit LIN gibt's ne eckige bewegung. fällt auch weg.
bei CIRC werden bei den hilfspunkten nur x,y,z ausgewertet, was dann ein kippen anstatt drehen bewirkt. das hab ich probiert mit vier punkten. das schraubt sich sogar schon in die tiefe 
die lösung ist wohl, den kreis in vier anstatt zwei kreisbewegungen zu unterteilen (8 punkte). das müsste klappen.
beispiel kommt nach dem essen, falls das dann noch nicht gelöst ist 
naja. das geht vielleicht etwas in die richtung:
DEF wankelbohren( )
REAL radius
REAL winkel
REAL vorschub ; pro umdrehung
REAL achtelvorschub
REAL tiefe
REAL versatz_90, versatz_45
FRAME vorpos, startpos
FRAME N,NO,O,SO,S,SW,W,NW
BAS( #INITMOV, 0 )
radius = 50.0
winkel = 5.0
vorschub = 0.8
tiefe = 10.0
achtelvorschub = vorschub / 8.0
versatz_90 = radius - ( COS( winkel ) * radius )
versatz_45 = COS( 45 ) * versatz_90
vorpos = $NULLFRAME
vorpos.z = -100.0
NO = $NULLFRAME
NO.x = -versatz_45
NO.y = versatz_45
NO.z = achtelvorschub
O = $NULLFRAME
O.c = winkel
O.y = versatz_90
O.z = 2.0 * achtelvorschub
SO = $NULLFRAME
SO.x = versatz_45
SO.y = versatz_45
SO.z = 3.0 * achtelvorschub
S = $NULLFRAME
S.b = -winkel
S.x = versatz_90
S.z = 4.0 * achtelvorschub
SW = $NULLFRAME
SW.x = versatz_45
SW.y = -versatz_45
SW.z = 5.0 * achtelvorschub
W = $NULLFRAME
W.c = -winkel
W.y = -versatz_90
W.z = 6.0 * achtelvorschub
NW = $NULLFRAME
NW.x = -versatz_45
NW.y = -versatz_45
NW.z = 7.0 * achtelvorschub
N = $NULLFRAME
N.b = winkel
N.x = -versatz_90
startpos = N
N.z = vorschub
PTP XHOME
$BASE = BASE_DATA[2]
$TOOL = TOOL_DATA[1]
PTP vorpos
LIN startpos
WHILE $POS_ACT.z < tiefe
CIRC NO,O
LIN O
NO.z = NO.z + vorschub
O.z = O.z + vorschub
CIRC SO,S
LIN S
SO.z = SO.z + vorschub
S.z = S.z + vorschub
CIRC SW,W
LIN W
SW.z = SW.z + vorschub
W.z = W.z + vorschub
CIRC NW,N
LIN N
NW.z = NW.z + vorschub
N.z = N.z + vorschub
ENDWHILE
LIN vorpos
PTP XHOME
END
probleme:
- LIN nach jedem CIRC nötig, weil sonst die winkel "falsch" berechnet werden. der KUKA nimmt nur cos(45), also 0.7 als grundlage. komischerweise tut er das nicht, wenn jeweils ein LIN davor steht (?).
- das ZETT ist immer schon beim hilfspunkt auf dem wert des endpunktes. auch hier (?!?).
- oder beim endpunkt erst auf dem wert des hilfspunktes? jedenfalls fährt er bei den LINs immer noch im ZETT etwas runter.
vielleicht könnte man das mit $ADVANCE = 0 lösen, aber dann wird's nix mit überschleifen...
oder wenn die achteckige bewegung nicht stört -> einfach alles LINs anstatt der CIRCs... (dann müssten aber bei NO, SO, SW und NW unbedingt die winkel angegeben werden (winkel/2).
gruss in die runde
naja. das geht vielleicht etwas in die richtung:
Jaaaaaaa, Rob, das kommt der Lösung ziemlich nahe. Zumindest kann ich damit wohl leben! Habe das mal im Office ausprobiert, 'n bischen angepasst und täteretäääääääääääää, scheint zu klappen. Gleich mal in die Halle gehen und auf den Robi aufspielen.
juhuu
hab's auch im office lite gemacht.
kannst ja dann den video hochladen 
fett!
dann noch'n schönen feierabend 
:ylsuper: :ylsuper:
rob, gut gemacht !
Du musst ein Benutzerkonto haben um einen Kommentar hinterlassen zu können
