Robtarget auf ein anderes Werkobjekt übertragen

also wenn der Roboter da steht wo du das Werkobjekt ändern möchtest fällt mit da mal CRobT ein
p1 := CRobT(\Tool:=toolXY\WObj:=newWorkobject);
ist zwar kein richtiges umrechnen, sollt aber in diesen Fall ja auch funktionieren

probier das mal.

hab ich grad mal zusammengeschrieben. sollte funktionieren wenn nicht schau ich nochmal drüber

PROC ChangeBase(INOUT robtarget p,wobjdata wobjAlt, wobjdata wobjNeu)
    VAR pose Po:=[[0,0,0],[1,0,0,0]];
    VAR pose Ret:=[[0,0,0],[1,0,0,0]];
    !
    po.trans:=p.trans;
    po.rot  :=p.rot;
    !
    Ret:=PoseMult(PoseInv(PoseMult(wobjNeu.uframe,wobjneu.oframe)),PoseMult(PoseMult(wobjAlt.uframe,wobjAlt.oframe),po));
    !
    p.trans:=Ret.trans;
    p.rot  :=Ret.rot;
    !
ENDPROC

Moin,
es ist mit zwei Funktionen möglich. Die aktuelle Position in der aktuellen Konstellation in Achsdaten, CalcJointT - Berechnen der Achsenwinkel vom Roboterziel. umrechnen un die Achsdaten kann man dann beliebig auf andere Koordinatensysteme umlegen, CalcRobT.

Schreib dir einen Funktion mit welcher du die Daten übergibst und die Positon zurück bekommst.

Somit kannst Du ohne die Position anzufahren auf ein anderes Koordinatensystem umrechnen.

Gruß

Wenn es eine einmalige Sache ist, kann man das Werkobjekt doch über Robotstudio transformieren (sofern Premium)?

Rapid --> Roboterpostionen anpassen

Hi,
ich glaube die folgende Funktion "RecalcRobT" hilft dir weiter:

Beispiel:  p20:=ReCalRobT(p10,tool1,tool1,wobj1,wobj2)


FUNC robtarget ReCalcRobT(
    robtarget point,
    PERS tooldata told,
    PERS tooldata tnew,
    PERS wobjdata wold,
    PERS wobjdata wnew)


    VAR pose ppnt:=[[0,0,0],[1,0,0,0]];
    VAR pose ppntnew:=[[0,0,0],[1,0,0,0]];
    VAR pose pb:=[[0,0,0],[1,0,0,0]];
    VAR pose pa:=[[0,0,0],[1,0,0,0]];


    ppnt:=[point.trans,point.rot];
    pa:=PoseMult(PoseInv(PoseMult(wnew.uframe,wnew.oframe)),PoseMult(wold.uframe,wold.oframe));
    pb:=PoseMult(ppnt,PoseMult(PoseInv(told.tframe),tnew.tframe));
    ppntnew:=PoseMult(pa,pb);
    RETURN [ppntnew.trans,ppntnew.rot,point.robconf,point.extax];
ENDFUNC

Gruß
Micky

Zitat von Sven Weyer

es ist mit zwei Funktionen möglich. Die aktuelle Position in der aktuellen Konstellation in Achsdaten, CalcJointT - Berechnen der Achsenwinkel vom Roboterziel. umrechnen un die Achsdaten kann man dann beliebig auf andere Koordinatensysteme umlegen, CalcRobT.

Moin,
genau die Info habe ich gesucht. :kiss:

FUNC robtarget TranslateRobtarget(robtarget rSource, PERS tooldata tSource, PERS tooldata tTarget, PERS wobjdata wSource, PERS wobjdata wTarget)
  var jointtarget jBuffer;
  var robtarget   rTarget;

  jBuffer := CalcJointT(rSource, tSource \wobj:=wSource);
  rTarget := CalcRobT(jBuffer, tTarget \wobj:=wTarget);

  RETURN rTarget;
ENDFUNC

Gruß
Jörn