Aufrufhierarchie von Routinen einsehbar?

module Main()


  proc tuWas_1()
    if diFehler then
      ausgabeFehler;
    endif
  endproc


  proc tuWas_2()
    if diFehler then
      ausgabeFehler;
    endif
  endproc


  proc tuWas_3()
    if diFehler then
      ausgabeFehler;
    endif
  endproc


  proc ausgabeFehler()
    if not diFehler then
      ! Wie kam ich hierher? Über tuWas_1, tuWas_2 oder tuWas_3?
    endif
  endprog
endmodule

MODULE modCallStack(NOSTEPIN)
    !****************************************************************************
    !* modCallStack                                                             *
    !*                                                                          *
    !* Description:                                                             *
    !*  A FIFO stack for storing programm names, i.e. a call stack for all      *
    !*  programms.                                                              *
    !*                                                                          *
    !* Usage:                                                                   *
    !*  Add push at the very beginning of a programm. Add pull at the very end  *
    !*  of a programm and before each RETURN. If you like to add some extra     *
    !*  information you may use the optional input parameters:                  *
    !*                                                                          *
    !*     PROC main()                                                          *
    !*        clearCallStack;                                                   *
    !*        CallStack \push \sName := "PROC main()";                          *
    !*        ...                                                               *
    !*        CallStack \pull;                                                  *
    !*     ENDPROC                                                              *
    !*                                                                          *
    !*     FUNC num calculation(num aNumber)                                    *
    !*        VAR num result := 0;                                              *
    !*        CallStack \push \sName := "FUNC num calculation(num aNumber)" \sInput1 := NumToStr(aNumber, 3);
    !*        ...                                                               *
    !*        CallStack \pull;                                                  *
    !*        RETURN result;                                                    *
    !*     ERROR                                                                *
    !*        ...                                                               *
    !*     ENDPROC                                                              *
    !*                                                                          *
    !* Date:          Version:  Programmer:       Reason:                       *
    !* 16.12.2021     1.0       J. Eckhoff        Created                       *
    !****************************************************************************

    RECORD recStack
        num    nEntry;
        string sProgrammName;
        string sInputPar1;
        string sInputPar2;
        string sInputPar3;
    ENDRECORD

    PERS num nStackPointer := 5;
    
    PERS recStack arrStack{32} :=
    [
        [ 1, "PROC main()", "", "", ""],
        [ 2, "PROC Init()", "", "", ""],
        [ 3, "PROC GreiferTest()", "", "", ""],
        [ 4, "FUNC bool IstVKAmGreifer()", "", "", ""],
        [ 5, "", "", "", ""],
        [ 6, "", "", "", ""],
        [ 7, "", "", "", ""],
        [ 8, "", "", "", ""],
        [ 9, "", "", "", ""],
        [10, "", "", "", ""],
        [11, "", "", "", ""],
        [12, "", "", "", ""],
        [13, "", "", "", ""],
        [14, "", "", "", ""],
        [15, "", "", "", ""],
        [16, "", "", "", ""],
        [17, "", "", "", ""],
        [18, "", "", "", ""],
        [19, "", "", "", ""],
        [20, "", "", "", ""],
        [21, "", "", "", ""],
        [22, "", "", "", ""],
        [23, "", "", "", ""],
        [24, "", "", "", ""],
        [25, "", "", "", ""],
        [26, "", "", "", ""],
        [27, "", "", "", ""],
        [28, "", "", "", ""],
        [29, "", "", "", ""],
        [30, "", "", "", ""],
        [31, "", "", "", ""],
        [32, "", "", "", ""]
    ];
    
    
    !**********************************************************
    !*  Procedure CallStack                                   *
    !*                                                        *
    !*  Push or pull a programmes name to or from the stack.  *
    !*                                                        *
    !*  Date:          Version:    Programmer:    Reason:     *
    !*  16.12.2021      1.0        J. Eckhoff     Created     *
    !**********************************************************
    PROC CallStack(\switch push | switch pull, \string sName, \string sInput1, \string sInput2, \string sInput3)

        IF Present(push) THEN
            ! Add new entry to the stack
            
            IF (nStackPointer = 32) THEN
                ! Stack is already full
                Stop;
                RETURN;
            ENDIF
            
            IF Present(sName) THEN
                arrStack{nStackPointer}.sProgrammName := sName;
            ENDIF
            
            IF Present(sInput1) THEN
                arrStack{nStackPointer}.sInputPar1 := sInput1;
            ENDIF
            
            IF Present(sInput2) THEN
                arrStack{nStackPointer}.sInputPar2 := sInput2;
            ENDIF
            
            IF Present(sInput3) THEN
                arrStack{nStackPointer}.sInputPar3 := sInput3;
            ENDIF
            
            nStackPointer := nStackPointer + 1;
        ENDIF
        
        IF Present(pull) THEN
            ! Delete last entry
            
            IF (nStackPointer = 0) THEN
                ! Stack already emtpy
                Stop;
                RETURN;
            ENDIF
            
            arrStack{nStackPointer-1}.sProgrammName := "";
            arrStack{nStackPointer-1}.sInputPar1    := "";
            arrStack{nStackPointer-1}.sInputPar2    := "";
            arrStack{nStackPointer-1}.sInputPar3    := "";
            
            nStackPointer := nStackPointer - 1;
        ENDIF
        
        !
    ENDPROC
    
    
    !**********************************************************
    !*  Procedure clearCallStack                              *
    !*                                                        *
    !*  Delete all entries in the call stack array            *
    !*                                                        *
    !*  Date:          Version:    Programmer:    Reason:     *
    !*  16.12.2021      1.0        J. Eckhoff     Created     *
    !**********************************************************
    PROC clearCallStack()
        
        FOR i FROM 1 TO Dim(arrStack, 1) DO
            arrStack{nStackPointer}.sProgrammName := "";
            arrStack{nStackPointer}.sInputPar1    := "";
            arrStack{nStackPointer}.sInputPar2    := "";
            arrStack{nStackPointer}.sInputPar3    := "";
        ENDFOR

        nStackPointer := 1;

        !
    ENDPROC
ENDMODULE