Dialogmeldung quittieren in KRC4

Hallo mlstefan,

ja kann man.

mit dieser Zeile gibst Du ja die Meldung ab. (Bsp.:)
nHandle = Set_KrlDlg (Msg, Par[],SK[], Opt)
Kriegst ja dann eine Nummer zurück, Interpreter springt weiter im Prog.

Fragst ja dann normalerweise ab, was gedrückt wurde:
If (nHandle > 0) Then
While ( Exists_KrlDlg(nHandle, nAnswer) ) ;Warten bis der Dialog beantwortet
Wait Sec 0.1
Endwhile
Switch nAnswer
case 1
; ......................
case 2
; ...................
; ....

Endswitch
Endif

Die Schleife kannst Du ja jetzt locker ergänzen mit einer Verknüpfung auf einen Eingang oder eine boolsche Variable, die Du handelst im Submit.

Danach halt noch ein Clear_KrlMsg (nHandle) nachschieben.

Ist rein ein ausprog in KRL.

Gruss SJX

Hallo mlstefan,

def Dialog()
Decl KrlMsg_T Msg
Decl KrlMsgPar_T Par[3]
Decl KrlMsgOpt_T Opt
Decl KrlMsgDlgSK_T SK[7]
INT nHandle, nAnswer
BOOL retVal

Msg = { Modul[] "mlstefan", Nr 1234, Msg_txt[] "Wollen Sie weiterfahren?"}
SK[1] = { Sk_Type #Value, Sk_txt[] "JA" }
SK[2] = { Sk_Type #Value, Sk_txt[] "NEIN" }
SK[3] = { Sk_Type #Value, Sk_txt[] "ABBRUCH" }
Opt = { VL_Stop True, Clear_P_Reset True, Log_To_DB False }
nHandle = Set_KrlDlg (Msg, Par[],SK[], Opt)
If (nHandle > 0) Then
While ( Exists_KrlDlg(nHandle, nAnswer) ) ;Warten bis der Dialog beantwortet
If bQuitt==TRUE Then
retVal = Clear_KrlMsg (nHandle)
If retVal Then
bQuitt==FALSE
Endif
Endif
Wait Sec 0.1
Endwhile
Switch nAnswer
case 1
; Softkey "JA" gedrueckt
case 2
; Softkey "Nein" gedrueckt
; ....
case 0
; Der Dialog wurde abgebrochen via bQuitt!!!!!
Endswitch
Endif

End

Ist in Doku auch beschrieben, "Dialogmeldung prüfen", abbruch z.B. via interrupt oder anderer Prozess.

Gruss SJX