ABB Roboterschulung von praxiserfahrenen Trainern
in unserem Schulungszentrum in Mainburg oder vor Ort bei Ihnen
Bediener und Expertenschulungen anfragen

Autor Thema:  Zirkulares Conveyor Trecking  (Gelesen 1688 mal)

0 Mitglieder und 1 Gast betrachten dieses Thema.

Offline chupete

  • Bekannter LV 2
  • *
  • Beiträge: 7
  • Bewertet: 0
Zirkulares Conveyor Trecking
« am: 30. August 2006, 18:00:45 »
Hallo
Bin gerade dabei einen Rundtisch von getaktet auf kontinuierlich umzustellen, an denen auch Roboter (ABB IRB6400 + IRB 2400) arbeiten.
Nun bin ich an einem Punkt in der Betriebsanleitung angekommen in der es nicht mehr
weitergeht.
Im Handbuch Cnv. Tracking unter Punkt 10.7 (Kalibrierung des Basis-Koordinatensystem des Zirkular-Förderers-Vermessungsmethode mit TCP
unter Punkt 4 steht -
über eine Hilfsfunktion UTL_cirCntp kann man aus den Punkten p_0, p_1, p_2 den Kreismittelpunkt p_center berechnen.
Hat jemand eine Ahnung wo ich diese kleine Hilfsfunktion UTL_cirCntp finde?
Vielleicht hat ja schon mal jemand so etwas gemacht.
Gruß chupete
  • finde ich gut    Danke, das hat mir geholfen    brauche Hilfe    da stimmt was nicht    Lesenswert


ABB Robotertraining
günstig und verständlich mit Zertifikat
ABB Roboterschulung

Online Sven Weyer

  • Global Moderator
  • Forum Legende LV 1
  • *
  • Beiträge: 1056
  • Bewertet: +17
Re: Zirkulares Conveyor Trecking
« am: 30. August 2006, 19:02:45 »
Hallöchen chupete,
es gibt bei ABB Funktionen wie z.B. RelTool etc. S etwas in der Art sollte dies auch sein. In anderen Abschnitten der Dokumentation habe ich nichts darüber gefunden. Es gibt aber auch noch die Möglichkeit das diese trotzdem vorhanden sind.
Gearbeitet habe ich mit dieser Funktion leider auch noch nicht. Habe mal den Adobe suchen lassen in allen pdf-datein die ich habe. Hat leider für diese Funktion nichts gefunden. Denke Du mußt dich an die Hotline wenden. +49 6031 85 307

Viel Glück

robotic74
  • finde ich gut    Danke, das hat mir geholfen    brauche Hilfe    da stimmt was nicht    Lesenswert
Wer nichts macht macht keine Fehler!
Wer keine Fehler macht kann nichts daraus lernen!
Wer nichts lernen kann kann sich nicht weiterentwickeln!
Wer sich nicht entwickelt geht unter!

Offline Micky

  • Forum Elite LV 3
  • *
  • Beiträge: 269
  • Bewertet: +40
Re: Zirkulares Conveyor Trecking
« am: 03. September 2006, 17:51:36 »
Halo chupete,

leider verweist das Handbuch auf eine Funktion die es im Rapid-Befehlssatz so nicht gibt. 

:aufsmaul:

Nachfolgend der Programcode für die Funktion UTL_cirCentp:


  !*********************************************************
  ! Function:  UTL_cirCntr
  ! Description:
  !   The centre of a circle  is calculated from three positions on
  !   the circumference.
  !
  !*********************************************************
  FUNC robtarget UTL_cirCntr(
    robtarget p1,
    robtarget p2,
    robtarget p3)

    VAR pos p12;
    VAR pos p13;
    VAR pos p23;
    VAR pos k2;
    VAR pos pn12;
    VAR pos pn13;
    VAR num a;
    VAR num b;
    VAR num ai;
    VAR num bi;
    VAR num c;
    VAR num d;
    VAR num s;
    VAR num r;
    VAR num kl;
    VAR robtarget p0;

    p12:=p2.trans-p1.trans;
    p13:=p3.trans-p1.trans;
    p23:=p3.trans-p2.trans;
    a:=Sqrt(p12.x*p12.x+p12.y*p12.y+p12.z*p12.z);
    b:=Sqrt(p13.x*p13.x+p13.y*p13.y+p13.z*p13.z);
    c:=Sqrt(p23.x*p23.x+p23.y*p23.y+p23.z*p23.z);
    s:=(a+b+c)/2;
    ai:=1/a;
    bi:=1/b;
    r:=0.25*a*b*c/Sqrt(s*(s-a)*(s-b)*(s-c));
    IF a>b THEN
      p23:=p13;
      p13:=p12;
      p12:=p23;
      a:=b;
    ENDIF
    pn12:=p12*ai;
    pn13:=p13*bi;
    k2:=pn12*pn13*pn12;
    kl:=1/Sqrt(k2.x*k2.x+k2.y*k2.y+k2.z*k2.z);
    k2:=kl*k2;
    d:=Sqrt(r*r-a*a/4);
    p0:=p1;
    p0.trans:=p1.trans+0.5*p12+d*k2;
    RETURN p0;
  ENDFUNC


An die Funktion musst Du die drei Umfangs-Positionen die Du für die Kreisbestimmung geteacht hast übergeben und erhälst dann die Mittelpunktposition zurück.

z.B.
 
   pMitte:=UTL_cirCntr(p1,p2,p3);



Gruß
Micky
« Letzte Änderung: 03. September 2006, 17:53:30 von Micky »
  • finde ich gut    Danke, das hat mir geholfen    brauche Hilfe    da stimmt was nicht    Lesenswert


xx
SC4 Plus Conveyor Tracking

Begonnen von TD_DT

4 Antworten
737 Aufrufe
Letzter Beitrag 08. November 2014, 12:01:52
von stromer
xx
Conveyor Tracking Alternative

Begonnen von MartinK

1 Antworten
1455 Aufrufe
Letzter Beitrag 21. Januar 2008, 12:28:44
von stromer
xx
AB Bereich begrenzen Conveyor Tracking

Begonnen von chupete

9 Antworten
2143 Aufrufe
Letzter Beitrag 21. September 2009, 06:51:03
von Sven Weyer
xx
Conveyor Position aus Systemparametern ermitteln

Begonnen von Torsten

1 Antworten
1394 Aufrufe
Letzter Beitrag 14. Dezember 2006, 17:35:01
von Torsten
xx
Pickmaster und Conveyor vorwärts/rückwärts fahren

Begonnen von ck.poorboy

1 Antworten
318 Aufrufe
Letzter Beitrag 04. November 2016, 10:28:02
von stromer
 

über das Roboterforum

Nutzungsbedingungen Impressum
Sitemap